817109_fr-FR

liliconcom

JSL : la disposition ('Arrange in Rows') est perdue lors de la journalisation par script

Chère communauté JMP,

Je suis tombé sur le problème suivant lors de la création d'un script (exemple ci-joint) :

• Si j'utilise le script suivant, « jrn1 << Journal; » entraîne le transfert vers le journal, mais sans « Group Options( Layout( 'Arrange in Rows', N Across( 2 ) ) ), ».
• Si j'utilise l'option manuelle (Edition >> Journal ou Ctrl + J), la disposition à deux colonnes est conservée .

Existe-t-il une autre « syntaxe de journal » qui conserve la mise en page que je ne connais pas ou s’agit-il d’un bug ?

Ai-je une autre option que de formater la mise en page du journal via « H List Box () » ?

Meilleur,

Steffi

kin1 = current data table();<BR /><BR />jrn1 = kin1 << Bivariate(
	Y( :response ),
	X( :time),
	Size(400, 325),
	Fit Each Value( {Line Color( {212, 73, 88} )} ),
	By( :ID ),
	Group Options( Layout( "Arrange in Rows", N Across( 2 ) ) ),
);
Current Report()[OutlineBox(1)] << setTitle("Kinetics"); //Adjust the header retroperspectively 
jrn1 << Journal;

jrn

Automatisation et scriptsRe: JSL : la mise en page ('Arrange in Rows') est perdue lors de la journalisation par script

jrn1 contiendra plusieurs références de plateforme bivariée, vous ne souhaitez en utiliser qu'une seule (ou plutôt un niveau encore plus élevé). Vous pouvez modifier votre script comme ceci par exemple

Names Default To Here(1);

kin1 = Current Data Table();
jrn1 = kin1 << Bivariate(
	Y(:response),
	X(:time),
	Size(400, 325),
	Fit Each Value({Line Color({212, 73, 88})}),
	By(:ID),
	Group Options(Layout("Arrange in Rows", N Across(2))),

);
Current Report()[Outline Box(1)] << setTitle("Kinetics"); //Adjust the header retroperspectively 
(jrn1[1] << Top Parent)<< Journal;

Re: JSL : la mise en page ('Arrange in Rows') est perdue lors de la journalisation par script

Enregistrer le journal remplace les graphiques du groupe d'ajustement est un article similaire à celui-ci, mais si je me souviens bien, il existe une méthode encore meilleure MAIS elle est extrêmement difficile à trouver ou à mémoriser... si j'arrive à la trouver, je modifierai cette réponse.

Edit : J'ai finalement réussi à le trouver. C'est extrêmement difficile (à mon avis) à trouver mais le voici : utilisez Return Group(1) sur Group Options (je l'ai ajouté à mon fichier de trucs et astuces personnels, donc j'espère que je le trouverai plus facilement la prochaine fois que quelqu'un aura un problème similaire)

Names Default To Here(1);

kin1 = Current Data Table();
jrn1 = kin1 << Bivariate(
	Y(:response),
	X(:time),
	Size(400, 325),
	Fit Each Value({Line Color({212, 73, 88})}),
	By(:ID),
	Group Options(Layout("Arrange in Rows", N Across(2)), Return Group(1)),

);
Current Report()[Outline Box(1)] << setTitle("Kinetics"); //Adjust the header retroperspectively 
jrn1 << Journal;

Names Default To Here(1);
Open Help(
	"Scripting Index",
	Search(
		Term("Group Options"),
		Match(
				{"Contains Terms",
				"Match All Terms",
				"Ignore Case"}
		)
	),
	IndexContext(
		Category("All Categories"),
		Object("Search results"),
		Method("Group Options")
	)
);