809192_zh-TW

liliconcom

聚類後如何在散佈圖矩陣中記錄橢圓內資料點的分類？

以下 JSL 程式碼可用於顯示聚類後的散佈圖矩陣。

dt = Open("$SAMPLE_DATA/Big Class.jmp");

Normal Mixtures(
	Y( :height, :weight ),
	{Mixtures Tolerance( 0.00000001 ), Mixtures MaxIter( 300 ),
	Mixtures N Starts( 30 ), Outlier Cluster( 0 ), Diagonal Variance( 0 ),
	Number of Clusters( 2 ), Go( Scatterplot Matrix( Ellipse Alpha( 0.1 ) ) )},
	SendToReport(
		Dispatch( {"Normal Mixtures NCluster=2"}, "Correlations for Normal Mixtures",
			OutlineBox,
			{Close( 0 )}
		),
		Dispatch( {"Normal Mixtures NCluster=2", "Scatterplot Matrix"}, "101",
			ScaleBox,
			{Min( 59.68 ), Max( 179.498666666667 ), Inc( 20 ), Minor Ticks( 0 )}
		)
	)
);

我需要以下兩個問題的幫助：
(1) 如何在JSL程式碼中將橢圓α設定為0.4？

（2）我想記錄α為0.4的橢圓中包含的點，其中紅色橢圓內的點標記為1，綠色橢圓內的點標記為-1，兩個橢圓外的點為標記為0。將簇保存在表中，但相反，我想記錄橢圓中包含的點。如何將此功能新增至 JSL 程式碼？

基礎資料分析與建模回覆：聚類後如何在散佈圖矩陣中記錄橢圓內資料點的分類？

看起來正常的混合物平台可能使用它自己的散點圖矩陣，這並不容易訪問或操作。您可以將聚類儲存到表中，然後使用散點圖矩陣建立繪圖

Scatterplot Matrix(
	Y(:height, :weight),
	Group(:Cluster),
	Matrix Format("Lower Triangular"),
	Density Ellipses(1),
	Ellipses Coverage(0.4),
	Group By(:Cluster)
);

但這不會讓你獲得積分。為此，您可以使用 Fit Y by X 平台（使用簇作為按列）。

我知道您可以在此處選擇橢圓內的點

因為我不太確定你想要做什麼（你只是想選擇點還是還有某種報告），下面的腳本可以做很多事情

Names Default To Here(1);
dt = Open("$SAMPLE_DATA/Big Class.jmp");

nw = New Window("",
	vlb = V List Box(
		nm = dt << Normal Mixtures(
			Y(:height, :weight),
			{Mixtures Tolerance(0.00000001), Mixtures MaxIter(300), Mixtures N Starts(30),
			Outlier Cluster(0), Diagonal Variance(0), Number of Clusters(2), Go()}
		)
	)
);

cols = Associative Array(dt << Get Column Names("String"));
nm << Save Clusters;
cluster_col = Associative Array(dt << Get Column Names("String"));
cluster_col << Remove(cols);
cluster_col = (cluster_col << get keys)[1];

vlb << Append(
	sm = dt << Scatterplot Matrix(
		Y(:height, :weight),
		Group(:Cluster),
		Matrix Format("Lower Triangular"),
		Shaded Ellipses(1),
		Ellipses Coverage(0.4),
		Group By(Eval(cluster_col))
	);
);

biv = dt << Bivariate(Y(:weight), X(:height), By(:Cluster), Invisible);
biv << Density Ellipse(0.4, {Select Points Inside});

new_col = dt << New Column("Ellipse", Numeric, Nominal, Formula(
	If(Selected() & :Cluster == 1,
		1
	, Selected() & :Cluster == 2,
		-1
	,
		0
	)
));
dt << run formulas;
new_col << Delete Formula;
dt << clear select;

// Just for visualization purposes
gb = dt << Graph Builder(
	Size(653, 491),
	Show Control Panel(0),
	Variables(
		X(:height),
		Y(:weight),
		Overlay(:Cluster, Overlay Encoding("Style")),
		Color(:Ellipse)
	),
	Elements(Points(X, Y, Legend(3)))
);

For(i = 1, i <= 2, i++,
	ls = Report(biv[i])[FrameBox(1)] << Find Seg(LineSeg(1));
	xs = ls << Get X Values;
	ys = ls << Get y Values;
	Eval(EvalExpr(
		Report(gb)[FrameBox(1)] << Add Graphics Script(
			Line(Expr(xs), Expr(ys));
		)		
	));
);
//biv << close window;