808365_zh-CN

liliconcom

从初始列列表中迭代创建包含所有减法排列的列

我有一个列表，我需要创建一系列新的列，其中包含所列列之间的差异的每次排列。列表中的列数可以变化，下面的非迭代示例涵盖 3 列（12 到 14）。

Current  Data Table() << New Column(Head Name( As Namespace( Column( 12 ) ) )||" - "||Head Name( As Namespace( Column( 13 ) ) )||" HSD Threshold Matrix", Numeric, "Continuous", Format("Best", 10), Formula(Col Maximum(If(Contains(:Level, Head Name(As Namespace(Column(13))), 1), As Column(12)), :Group, :Size)));

Current  Data Table() << New Column(Head Name( As Namespace( Column( 12 ) ) )||" - "||Head Name( As Namespace( Column( 14 ) ) )||" HSD Threshold Matrix", Numeric, "Continuous", Format("Best", 10), Formula(Col Maximum(If(Contains(:Level, Head Name(As Namespace(Column(14))), 1), As Column(12)), :Group, :Size)));

Current  Data Table() << New Column(Head Name( As Namespace( Column( 13 ) ) )||" - "||Head Name( As Namespace( Column( 14 ) ) )||" HSD Threshold Matrix", Numeric, "Continuous", Format("Best", 10), Formula(Col Maximum(If(Contains(:Level, Head Name(As Namespace(Column(14))), 1), As Column(13)), :Group, :Size)));

自动化和脚本回复：从初始列表迭代创建包含所有减法排列的列

例如，您可以使用NChooseK Matrix()来创建组合（或 DoE）

Names Default To Here(1);

mylist = {12, 13, 14};
possible_group_idx = NChooseK Matrix(3,2);

my_groups = Transform Each({idx}, possible_group_idx,
	mylist[idx]
);

[12 13, 12 14, 13 14]

• 如何为三个唯一 ID 随机分配一个值，同时为每个 ID 分配 6 个唯一值？
• 将列表组合成列
• JMP 可以生成 6 个数字一组的 40 个数字的所有可能组合，且不重复？

回复：从初始列表迭代创建包含所有减法排列的列

雅尔莫

谢谢，看起来可以。还没有时间研究细节，但想知道是否有一个如何使用它的例子？

回复：从初始列表迭代创建包含所有减法排列的列

循环矩阵（或将其转换为列表列表）并在执行此操作时创建列。

回复：从初始列表迭代创建包含所有减法排列的列

不确定这是否是您的本意，但我在这里找到了一些可行的方法。更棒的是，它不依赖于列号。

Names Default to Here(1);
dt = Current Data Table();

//Select X Variable ____________________________________________________________________________________________________________________________________________

cdb = Column Dialog("Add continuous variables you want to plot as X" ,
	colxx = ColList( "X", Min Col( 1 ) ),
);
show(cdb);
Eval List(cdb[1::N Items(cdb)-1]);

Summarize(dt, uniqNames = by(colxx[1]));
Show(uniqNames);
Num = NItems(uniqNames);



For( k = 1, k <= N Items( uniqNames ), k++,
	// Loop through all columns finding non NA values
	For( i = 2, i <= N Items( uniqNames ), i++,
		if (i > k, Current  Data Table() << New Column(Char(uniqNames[k])||" - "||Char(uniqNames[i])||" Matrix", Numeric, "Continuous", Format("Best", 10), Formula(Col Maximum(If(Contains(:Level, Char(uniqNames[i]), 1), As Column(uniqNames[k])), :Group, :Size)));
			)
		)
	)
;

已解决：使用循环获取列值 - JMP 用户社区

回复：从初始列表迭代创建包含所有减法排列的列

Names Default To Here(1);
dt = Open("$SAMPLE_DATA/Cities.jmp");

mycols = {"OZONE", "CO", "SO2", "NO", "PM10"};

possible_group_idx = NChooseK Matrix(N Items(mycols), 2);
my_groups = Transform Each({idx}, As List(possible_group_idx), Output("List"),
	mycols[idx]
);

For Each({cols}, my_groups,
	Eval(Substitute(
		Expr(dt << New Column(cols[1] ||"_"||cols[2], Numeric, Continuous,
			Formula(_col1_ + _col2_)
		)),
		Expr(_col1_), Name Expr(AsColumn(dt, cols[1])),
		Expr(_col2_), Name Expr(AsColumn(dt, cols[2]))
	));
);

Write();