807412_zh-TW

liliconcom

降解數據分析平台自動產生報告？

你好，

在使用退化資料分析平台分析退化資料時，我想篩選各種模型，以便基於 AICc 選擇最佳模型。為此，我手動為給定路徑定義套用不同的分佈和轉換，並透過點擊「產生報告」按鈕為每個組合產生報告。有沒有辦法讓 JMP 自動產生所有組合的報告並將其添加到模型清單中？一個好處是讓 JMP 執行此操作，同時排除被認為不合適或產生缺失值的轉換（即，當時間因子包含零時，對其應用對數轉換）。

JMP 版本 17.2

提前致謝。

/JF

可靠度分析回覆：降解數據分析平台自動產生報告？

您可能必須透過編寫腳本來完成此操作。以下是一個選項（不是非常強大的腳本，但可以給出一些關於可以做什麼的想法）

Names Default To Here(1);
dt = Open("$SAMPLE_DATA/Reliability/Adhesive Bond.jmp");
obj = dt << Destructive Degradation(
	Y(:Strength),
	Time(:Weeks),
	X(:Degrees),
	Censor(:Censor),
	Censor Code("Right"),
	Control("Log10", "Sqrt", "Normal", "Individual Path with Intercept")
);

rep = Report(obj);

cb = (rep << XPath("//PanelBox[text() = 'Distribution']/ComboBox"))[1];
rb_transformations = (rep << XPath("//PanelBox[text() = 'Transformation']//RadioBox"));

cb_options = cb << get items;
rb_tr = rb_transformations << get items;
btn = (rep << XPath("//ButtonBox[text() = 'Generate Report']"))[1];
tb1 = rep[TextBox(3)];
tb2 = rep[TextBox(4)];

For Each({option, idx}, cb_options,
	cb << Set(idx);
	For Each({op1, idx1}, rb_tr[1],
		rb_transformations[1] << Set(idx1);
		For Each({op2, idx2}, rb_tr[2],
			rb_transformations[2] << Set(idx2);
			visibilities = {tb1, tb2} << get visibility;
			visibs = Loc(visibilities, "Visible");
			If(N Items(visibs) == 0,
				btn << Click(1);
			,
				skipped_txt = Eval insert("\[Skipped combination ^option^+^op1^+^op2^ due to ^Concat Items(({tb1, tb2} << get text)[Matrix(visibs)], ", ")^]\");
				Write("\!N", skipped_txt);		
			);
			wait(0);
		);
	);
);

Write();