806710_es-ES

liliconcom

Ordenación de encabezados de columnas

Después de transponer la tabla de datos,

Data Table( "Overall" ) << Transpose(
	columns( :Value),
	By( :Department, :Resource, :Chart ),
	Label( :Date),
	Output Table( "report overall" )
);

Los encabezados que se presentan por fecha ya no están en orden, por lo que tengo que arrastrarlos y soltarlos manualmente para solucionarlo. Por suerte, solo involucra 7 u 8 columnas. Sin embargo, hacerlo me quita tiempo, que inicialmente no necesito.

¿Hay alguna manera de hacerlo en orden como se muestra en la imagen?

Esas fechas cambiarán diariamente ya que mi rango de fechas fijo es de 7 días.

set_date = Today();

date_min = (set_date - In Days(7));

Data Table("Overall") << Select where (:date < date_min) << Delete Rows;

Automatización y scriptingOrganización de contenidoRe: Ordenación de encabezados de columnas

Aquí hay un script que reordenará las columnas como lo solicitó.

Names Default To Here( 1 );

// Example table to use for illustration
New Table( "Example",
	Add Rows( 0 ),
	New Column( "Department", Character, "Nominal" ),
	New Column( "Resource", Character, "Nominal" ),
	New Column( "Chart", Character, "Nominal", Set Selected ),
	New Column( "17/10/2024", Numeric, "Continuous", Format( "Best", 12 ) ),
	New Column( "16/10/2024", Numeric, "Continuous", Format( "Best", 12 ) ),
	New Column( "15/10/2024", Numeric, "Continuous", Format( "Best", 12 ) ),
	New Column( "11/10/2024", Numeric, "Continuous", Format( "Best", 12 ) ),
	New Column( "14/10/2024", Numeric, "Continuous", Format( "Best", 12 ) ),
	New Column( "18/10/2024", Numeric, "Continuous", Format( "Best", 12 ) ),
	New Column( "13/10/2024", Numeric, "Continuous", Format( "Best", 12 ) ),
	New Column( "12/10/2024", Numeric, "Continuous", Format( "Best", 12 ) )
);
Wait( 5 );

// This JSL with properly reorder the data table
dt = Current Data Table();

colNames = dt << get column names( string );

For Each( {col}, colNames,
	If( Is Missing( Try( Num( Informat( col, "d/m/y" ) ) ) ) == 0,
		Column( dt, col ) << set name( Char( Num( Informat( col, "d/m/y" ) ) ) ),
		Column( dt, col ) << set name( "0" || col )
	)
);
// Reorder columns by name
dt << Reorder by Name;

colNames = dt << get column names( string );

For Each( {col}, colNames,
	If( Is Missing( Num( col ) ) == 0,
		Column( dt, col ) << set name( Format( Num( col ), "d/m/y" ) ),
		Column( dt, col ) << set name( Substr( col, 2 ) )
	)
);

Re: Ordenación de encabezados de columnas

¡Funciona genial! ¡Gracias!