806710_ko-KR

liliconcom

열 머리글 순서 지정

데이터 테이블을 전치한 후,

Data Table( "Overall" ) << Transpose(
	columns( :Value),
	By( :Department, :Resource, :Chart ),
	Label( :Date),
	Output Table( "report overall" )
);

날짜별로 제시된 내 헤더가 더 이상 순서대로 정렬되지 않았습니다. 그러면 수동으로 끌어서 놓아서 수정해야 합니다. 다행히도 7~8개의 열만 포함됩니다. 그럼에도 불구하고, 그렇게 하면 처음에는 필요하지 않은 시간을 낭비하게 됩니다.

그림과 같은 순서대로 만들 수 있는 방법이 있나요?

고정된 날짜 범위가 7일이므로 해당 날짜는 매일 변경됩니다.

set_date = Today();

date_min = (set_date - In Days(7));

Data Table("Overall") << Select where (:date < date_min) << Delete Rows;

자동화 및 스크립팅콘텐츠 구성Re: 열 머리글 순서 지정

요청하신 대로 열을 재정렬하는 스크립트는 다음과 같습니다.

Names Default To Here( 1 );

// Example table to use for illustration
New Table( "Example",
	Add Rows( 0 ),
	New Column( "Department", Character, "Nominal" ),
	New Column( "Resource", Character, "Nominal" ),
	New Column( "Chart", Character, "Nominal", Set Selected ),
	New Column( "17/10/2024", Numeric, "Continuous", Format( "Best", 12 ) ),
	New Column( "16/10/2024", Numeric, "Continuous", Format( "Best", 12 ) ),
	New Column( "15/10/2024", Numeric, "Continuous", Format( "Best", 12 ) ),
	New Column( "11/10/2024", Numeric, "Continuous", Format( "Best", 12 ) ),
	New Column( "14/10/2024", Numeric, "Continuous", Format( "Best", 12 ) ),
	New Column( "18/10/2024", Numeric, "Continuous", Format( "Best", 12 ) ),
	New Column( "13/10/2024", Numeric, "Continuous", Format( "Best", 12 ) ),
	New Column( "12/10/2024", Numeric, "Continuous", Format( "Best", 12 ) )
);
Wait( 5 );

// This JSL with properly reorder the data table
dt = Current Data Table();

colNames = dt << get column names( string );

For Each( {col}, colNames,
	If( Is Missing( Try( Num( Informat( col, "d/m/y" ) ) ) ) == 0,
		Column( dt, col ) << set name( Char( Num( Informat( col, "d/m/y" ) ) ) ),
		Column( dt, col ) << set name( "0" || col )
	)
);
// Reorder columns by name
dt << Reorder by Name;

colNames = dt << get column names( string );

For Each( {col}, colNames,
	If( Is Missing( Num( col ) ) == 0,
		Column( dt, col ) << set name( Format( Num( col ), "d/m/y" ) ),
		Column( dt, col ) << set name( Substr( col, 2 ) )
	)
);

Re: 열 머리글 순서 지정

잘 작동해요! 고맙습니다!