804139_es-ES

liliconcom

Compartir un filtro de datos local entre constructores de gráficos para la visualización sincronizada de datos

Me gustaría compartir el mismo filtro de datos locales entre dos generadores de gráficos. Por ejemplo, al seleccionar F, ambos generadores de gráficos solo deben mostrar datos relacionados con F; y, al seleccionar M, ambos generadores de gráficos solo deben mostrar datos relacionados con M.
¿Cómo puedo lograr esto?

New Window( "Weight VS Height",
	outlineBoxA = Outline Box( "Weight VS Height",
		Graph Builder(
			Size( 528, 456 ),
			Show Control Panel( 0 ),
			Variables( X( :weight ), Y( :height ) ),
			Elements( Points( X, Y, Legend( 7 ) ) ),
			Local Data Filter( Add Filter( columns( :sex ), Where( :sex == "M" ) ) )
		);
		Graph Builder(
			Size( 534, 450 ),
			Show Control Panel( 0 ),
			Variables( X( :age ), Y( :weight ) ),
			Elements( Points( X, Y, Legend( 7 ) ) )
		);

	)
);

Automatización y scriptingRe: Cómo compartir un filtro de datos local entre generadores de gráficos para la visualización sincronizada de datos

Puede utilizar el cuadro de contexto del filtro de datos

Names Default To Here(1); 

dt = open("$SAMPLE_DATA/Big Class.jmp");


nw = New Window("Weight VS Height",
	Data Filter Context Box(
		outlineBoxA = Outline Box("Weight VS Height",
			H List Box(
				Data Filter Source Box(
					dt << Data Filter(
						Local,
						Add Filter(columns(:sex), Where(:sex == "M"))
					)
				),
				V List Box(
					dt << Graph Builder(
						Size(528, 456),
						Show Control Panel(0),
						Variables(X(:weight), Y(:height)),
						Elements(Points(X, Y, Legend(7)))
					),
					dt << Graph Builder(
						Size(534, 450),
						Show Control Panel(0),
						Variables(X(:age), Y(:weight)),
						Elements(Points(X, Y, Legend(7)))
					);
				)
			)
		)
	)
);


Write();

Construya cajas de exhibición para nuevas ventanas (jmp.com)