800949_zh-TW

liliconcom

變更多重變異圖的標記大小和框架大小

大家好，

有沒有一種簡單的方法可以使用“sendtoreport”和“dispatch”函數來更改：高度和：重量變異性圖表的框架大小和標記大小？

下面是使用 Big Class.jmp 的範例。我找不到更改標記大小和框架大小以在兩個變異性圖表中工作的方法。不確定是否有一種無需使用 for 迴圈的簡單方法。

謝謝，

霸王龍

Open( "$SAMPLE_DATA/Big Class.jmp" );
Variability Chart(
		Y( :Height ,:Weight),
		X(:sex),
		Analysis Type( "Choose best analysis (EMS REML Bayesian)" ),
		Std Dev Chart( 0 ),
		Points Jittered( 1 ),
		Show Box Plots( 0 ),
		Show range bars(0),
		Connect cell means(0),
		Show cell means(0),
		SendToReport(
				Dispatch(
					{},
					"variability chart",
					FrameBox,
					{Frame Size( 800, 240 ), Marker Size( 2 )}
				)
		)
	);

自動化和腳本編寫基礎資料分析與建模數據探索和視覺化視窗回覆：更改多重變異性圖的標記大小和框架大小

您可以使用 XPath 取得框架框的參考列表，然後將訊息傳送到該列表

Names Default To Here(1);

dt = Open("$SAMPLE_DATA/Big Class.jmp");
var = dt << Variability Chart(
	Y(:Height, :Weight),
	X(:sex),
	Analysis Type("Choose best analysis (EMS REML Bayesian)"),
	Std Dev Chart(0),
	Points Jittered(1),
	Show Box Plots(0),
	Show range bars(0),
	Connect cell means(0),
	Show cell means(0)
);

fbs = Report(var) << XPath("//FrameBox[@helpKey = 'Variability Chart']");

fbs[1::N Items(fbs)::2] << Frame Size(300, 300) << Marker Size(10);

我使用 1,3 索引 (1::N Items(fbs)::2) 因為 stddev 圖表在報告中，它們只是隱藏的（在本例中為 2 和 4 索引），但很可能更新就可以了這些尺寸也是如此。

回覆：更改多重變異性圖的標記大小和框架大小

-賈莫，

我在此範例腳本中遇到的另一個問題是“顯示箱線圖（0）”不會關閉箱線圖。您能告訴我如何關閉此範例中的箱線圖嗎？

謝謝，

霸王龍

回覆：更改多重變異性圖的標記大小和框架大小

對我來說，它們在我的示例中被禁用。如果這不起作用，您可以將訊息單獨發送到每個輪廓變異性分析（或平台）

Names Default To Here(1);

dt = Open("$SAMPLE_DATA/Big Class.jmp");
var = dt << Variability Chart(
	Y(:Height, :Weight),
	X(:sex),
	Analysis Type("Choose best analysis (EMS REML Bayesian)"),
	Std Dev Chart(0),
	Points Jittered(1),
	Show Box Plots(0),
	Show range bars(0),
	Connect cell means(0),
	Show cell means(0)
);

fbs = Report(var) << XPath("//FrameBox[@helpKey = 'Variability Chart']");

fbs[1::N Items(fbs)::2] << Frame Size(300, 300) << Marker Size(10);

obs_varanalysis = Report(var) << XPath("//OutlineBox[@helpKey = 'Variability' and contains(text(), 'Variability Gauge Analysis for')]");
(obs_varanalysis << Get Scriptable Object) << show box plots(1); // change to 0

腳本索引也有一個範例，但這可能需要循環

或者如果您有 JMP18 << 廣播應該可以工作

Names Default To Here(1);

dt = Open("$SAMPLE_DATA/Big Class.jmp");
var = dt << Variability Chart(
	Y(:Height, :Weight),
	X(:sex),
	Analysis Type("Choose best analysis (EMS REML Bayesian)"),
	Std Dev Chart(0),
	Points Jittered(1),
	Show Box Plots(0),
	Show range bars(0),
	Connect cell means(0),
	Show cell means(0)
);

fbs = Report(var) << XPath("//FrameBox[@helpKey = 'Variability Chart']");
fbs[1::N Items(fbs)::2] << Frame Size(300, 300) << Marker Size(10);

var << (Variability Analysis[1] << Broadcast(Show Box Plots(1)));