800949_es-ES

liliconcom

Cambiar el tamaño del marcador y el tamaño del marco del gráfico de variabilidad múltiple

Hola a todos,

¿Existe una forma sencilla de utilizar las funciones "sendtoreport" y "dispatch" para cambiar el tamaño del marco y el tamaño del marcador de los gráficos de variabilidad :height y :weight?

A continuación se muestra un ejemplo que utiliza Big Class.jmp. No pude encontrar una manera de cambiar el tamaño del marcador y el tamaño del marco para que funcionen en ambos gráficos de variabilidad. No estoy seguro de si existe una manera fácil sin tener que usar el bucle for.

Gracias,

rex

Open( "$SAMPLE_DATA/Big Class.jmp" );
Variability Chart(
		Y( :Height ,:Weight),
		X(:sex),
		Analysis Type( "Choose best analysis (EMS REML Bayesian)" ),
		Std Dev Chart( 0 ),
		Points Jittered( 1 ),
		Show Box Plots( 0 ),
		Show range bars(0),
		Connect cell means(0),
		Show cell means(0),
		SendToReport(
				Dispatch(
					{},
					"variability chart",
					FrameBox,
					{Frame Size( 800, 240 ), Marker Size( 2 )}
				)
		)
	);

Automatización y scriptingAnálisis y modelado de datos básicosExploración y visualización de datosVentanasRe: Cambiar el tamaño del marcador y el tamaño del marco del gráfico de variabilidad múltiple

Puede utilizar XPath para obtener una lista de referencias a los cuadros de marco y luego enviar mensajes a esa lista

Names Default To Here(1);

dt = Open("$SAMPLE_DATA/Big Class.jmp");
var = dt << Variability Chart(
	Y(:Height, :Weight),
	X(:sex),
	Analysis Type("Choose best analysis (EMS REML Bayesian)"),
	Std Dev Chart(0),
	Points Jittered(1),
	Show Box Plots(0),
	Show range bars(0),
	Connect cell means(0),
	Show cell means(0)
);

fbs = Report(var) << XPath("//FrameBox[@helpKey = 'Variability Chart']");

fbs[1::N Items(fbs)::2] << Frame Size(300, 300) << Marker Size(10);

Utilizo índices 1,3 (1::N Items(fbs)::2) porque los gráficos de desviación estándar están en el informe, solo están ocultos (índices 2 y 4 en este caso), pero lo más probable es que esté bien actualizar esos tamaños también.

Re: Cambiar el tamaño del marcador y el tamaño del marco del gráfico de variabilidad múltiple

-Jarmo,

Otro problema que tengo en este script de ejemplo es que "Mostrar diagramas de caja (0)" no desactiva el diagrama de caja. ¿Puedes indicarme cómo desactivar el diagrama de caja en este ejemplo?

Gracias,

rex

Re: Cambiar el tamaño del marcador y el tamaño del marco del gráfico de variabilidad múltiple

En mi caso, están desactivados en mi ejemplo. Si eso no funciona, puedes enviar el mensaje por separado a cada uno de los análisis de variabilidad del esquema (o a la plataforma).

Names Default To Here(1);

dt = Open("$SAMPLE_DATA/Big Class.jmp");
var = dt << Variability Chart(
	Y(:Height, :Weight),
	X(:sex),
	Analysis Type("Choose best analysis (EMS REML Bayesian)"),
	Std Dev Chart(0),
	Points Jittered(1),
	Show Box Plots(0),
	Show range bars(0),
	Connect cell means(0),
	Show cell means(0)
);

fbs = Report(var) << XPath("//FrameBox[@helpKey = 'Variability Chart']");

fbs[1::N Items(fbs)::2] << Frame Size(300, 300) << Marker Size(10);

obs_varanalysis = Report(var) << XPath("//OutlineBox[@helpKey = 'Variability' and contains(text(), 'Variability Gauge Analysis for')]");
(obs_varanalysis << Get Scriptable Object) << show box plots(1); // change to 0

El índice de scripts también tiene un ejemplo, pero esto podría requerir un bucle.

o si tienes JMP18 << La transmisión debería funcionar

Names Default To Here(1);

dt = Open("$SAMPLE_DATA/Big Class.jmp");
var = dt << Variability Chart(
	Y(:Height, :Weight),
	X(:sex),
	Analysis Type("Choose best analysis (EMS REML Bayesian)"),
	Std Dev Chart(0),
	Points Jittered(1),
	Show Box Plots(0),
	Show range bars(0),
	Connect cell means(0),
	Show cell means(0)
);

fbs = Report(var) << XPath("//FrameBox[@helpKey = 'Variability Chart']");
fbs[1::N Items(fbs)::2] << Frame Size(300, 300) << Marker Size(10);

var << (Variability Analysis[1] << Broadcast(Show Box Plots(1)));