800949_zh-CN

liliconcom

更改多变异图的标记大小和框架大小

大家好，

是否有一种简单的方法可以使用“sendtoreport”和“dispatch”函数来更改：height 和：weight 变化图表的框架大小和标记大小？

下面是使用 Big Class.jmp 的示例。我找不到一种方法来更改标记大小和框架大小以在两个变异性图表中工作。不确定是否有一种简单的方法，而不必使用 for 循环。

谢谢，

雷克斯

Open( "$SAMPLE_DATA/Big Class.jmp" );
Variability Chart(
		Y( :Height ,:Weight),
		X(:sex),
		Analysis Type( "Choose best analysis (EMS REML Bayesian)" ),
		Std Dev Chart( 0 ),
		Points Jittered( 1 ),
		Show Box Plots( 0 ),
		Show range bars(0),
		Connect cell means(0),
		Show cell means(0),
		SendToReport(
				Dispatch(
					{},
					"variability chart",
					FrameBox,
					{Frame Size( 800, 240 ), Marker Size( 2 )}
				)
		)
	);

自动化和脚本基础数据分析与建模数据探索与可视化视窗回复：更改多重变异图的标记大小和框架大小

您可以使用 XPath 获取对框架框的引用列表，然后向该列表发送消息

Names Default To Here(1);

dt = Open("$SAMPLE_DATA/Big Class.jmp");
var = dt << Variability Chart(
	Y(:Height, :Weight),
	X(:sex),
	Analysis Type("Choose best analysis (EMS REML Bayesian)"),
	Std Dev Chart(0),
	Points Jittered(1),
	Show Box Plots(0),
	Show range bars(0),
	Connect cell means(0),
	Show cell means(0)
);

fbs = Report(var) << XPath("//FrameBox[@helpKey = 'Variability Chart']");

fbs[1::N Items(fbs)::2] << Frame Size(300, 300) << Marker Size(10);

我使用 1,3 索引（1::N Items(fbs)::2），因为标准差图表在报告中，它们只是被隐藏了（在这种情况下是 2 和 4 个索引），但很可能更新这些大小也是可以的。

回复：更改多变异图的标记大小和框架大小

-贾莫，

我在这个示例脚本中遇到的另一个问题是“显示箱线图（0）”不会关闭箱线图。您能否建议如何关闭此示例中的箱线图？

谢谢，

雷克斯

回复：更改多重变异图的标记大小和框架大小

在我的示例中，它们被禁用。如果这不起作用，您可以将消息分别发送到每个轮廓变异性分析（或平台）

Names Default To Here(1);

dt = Open("$SAMPLE_DATA/Big Class.jmp");
var = dt << Variability Chart(
	Y(:Height, :Weight),
	X(:sex),
	Analysis Type("Choose best analysis (EMS REML Bayesian)"),
	Std Dev Chart(0),
	Points Jittered(1),
	Show Box Plots(0),
	Show range bars(0),
	Connect cell means(0),
	Show cell means(0)
);

fbs = Report(var) << XPath("//FrameBox[@helpKey = 'Variability Chart']");

fbs[1::N Items(fbs)::2] << Frame Size(300, 300) << Marker Size(10);

obs_varanalysis = Report(var) << XPath("//OutlineBox[@helpKey = 'Variability' and contains(text(), 'Variability Gauge Analysis for')]");
(obs_varanalysis << Get Scriptable Object) << show box plots(1); // change to 0

脚本索引也有示例，但这可能需要循环

或者如果你有 JMP18 << 广播应该可以工作

Names Default To Here(1);

dt = Open("$SAMPLE_DATA/Big Class.jmp");
var = dt << Variability Chart(
	Y(:Height, :Weight),
	X(:sex),
	Analysis Type("Choose best analysis (EMS REML Bayesian)"),
	Std Dev Chart(0),
	Points Jittered(1),
	Show Box Plots(0),
	Show range bars(0),
	Connect cell means(0),
	Show cell means(0)
);

fbs = Report(var) << XPath("//FrameBox[@helpKey = 'Variability Chart']");
fbs[1::N Items(fbs)::2] << Frame Size(300, 300) << Marker Size(10);

var << (Variability Analysis[1] << Broadcast(Show Box Plots(1)));