800949_ko-KR

liliconcom

다중 변동성 플롯의 마커 크기와 프레임 크기 변경

안녕하세요 여러분,

:height 및 :weight 변동성 차트의 프레임 크기와 마커 크기를 변경하기 위해 "sendtoreport" 및 "dispatch" 함수를 사용하는 쉬운 방법이 있습니까?

아래는 Big Class.jmp를 사용한 예입니다. 두 가지 변동성 차트에서 작동하도록 마커 크기와 프레임 크기를 변경하는 방법을 찾을 수 없었습니다. for 루프를 사용하지 않고도 쉬운 방법이 있는지 잘 모르겠습니다.

감사해요,

렉스

Open( "$SAMPLE_DATA/Big Class.jmp" );
Variability Chart(
		Y( :Height ,:Weight),
		X(:sex),
		Analysis Type( "Choose best analysis (EMS REML Bayesian)" ),
		Std Dev Chart( 0 ),
		Points Jittered( 1 ),
		Show Box Plots( 0 ),
		Show range bars(0),
		Connect cell means(0),
		Show cell means(0),
		SendToReport(
				Dispatch(
					{},
					"variability chart",
					FrameBox,
					{Frame Size( 800, 240 ), Marker Size( 2 )}
				)
		)
	);

자동화 및 스크립팅기본 데이터 분석 및 모델링데이터 탐색 및 시각화윈도우Re: 다중 가변성 플롯의 마커 크기 및 프레임 크기 변경

XPath를 사용하여 프레임 상자에 대한 참조 목록을 가져온 다음 해당 목록에 메시지를 보낼 수 있습니다.

Names Default To Here(1);

dt = Open("$SAMPLE_DATA/Big Class.jmp");
var = dt << Variability Chart(
	Y(:Height, :Weight),
	X(:sex),
	Analysis Type("Choose best analysis (EMS REML Bayesian)"),
	Std Dev Chart(0),
	Points Jittered(1),
	Show Box Plots(0),
	Show range bars(0),
	Connect cell means(0),
	Show cell means(0)
);

fbs = Report(var) << XPath("//FrameBox[@helpKey = 'Variability Chart']");

fbs[1::N Items(fbs)::2] << Frame Size(300, 300) << Marker Size(10);

stddev 차트가 보고서에 있고 숨겨져 있기 때문에 1,3 인덱스(1::N Items(fbs)::2)를 사용하지만, 이 크기도 업데이트해도 괜찮을 가능성이 높습니다.

Re: 다중 가변성 플롯의 마커 크기 및 프레임 크기 변경

-자르모,

이 예제 스크립트에서 제가 가진 또 다른 문제는 "Show Box Plots(0)"가 상자 그림을 끄지 않는다는 것입니다. 이 예제에서 상자 그림을 끄는 방법을 알려 주시겠습니까?

감사해요,

렉스

Re: 다중 가변성 플롯의 마커 크기 및 프레임 크기 변경

제 경우에는 제 예에서 비활성화되어 있습니다. 그래도 작동하지 않으면 각 개요 변동성 분석(또는 플랫폼)에 별도로 메시지를 보낼 수 있습니다.

Names Default To Here(1);

dt = Open("$SAMPLE_DATA/Big Class.jmp");
var = dt << Variability Chart(
	Y(:Height, :Weight),
	X(:sex),
	Analysis Type("Choose best analysis (EMS REML Bayesian)"),
	Std Dev Chart(0),
	Points Jittered(1),
	Show Box Plots(0),
	Show range bars(0),
	Connect cell means(0),
	Show cell means(0)
);

fbs = Report(var) << XPath("//FrameBox[@helpKey = 'Variability Chart']");

fbs[1::N Items(fbs)::2] << Frame Size(300, 300) << Marker Size(10);

obs_varanalysis = Report(var) << XPath("//OutlineBox[@helpKey = 'Variability' and contains(text(), 'Variability Gauge Analysis for')]");
(obs_varanalysis << Get Scriptable Object) << show box plots(1); // change to 0

스크립팅 인덱스에도 예가 있지만 여기에는 루핑이 필요할 수 있습니다.

또는 JMP18이 있는 경우 << Broadcast가 작동해야 합니다.

Names Default To Here(1);

dt = Open("$SAMPLE_DATA/Big Class.jmp");
var = dt << Variability Chart(
	Y(:Height, :Weight),
	X(:sex),
	Analysis Type("Choose best analysis (EMS REML Bayesian)"),
	Std Dev Chart(0),
	Points Jittered(1),
	Show Box Plots(0),
	Show range bars(0),
	Connect cell means(0),
	Show cell means(0)
);

fbs = Report(var) << XPath("//FrameBox[@helpKey = 'Variability Chart']");
fbs[1::N Items(fbs)::2] << Frame Size(300, 300) << Marker Size(10);

var << (Variability Analysis[1] << Broadcast(Show Box Plots(1)));