多重変動プロットのマーカーサイズとフレームサイズを変更するこんにちは、みんな、
「sendtoreport」および「dispatch」関数を使用して、:height および :weight 変動チャートのフレーム サイズとマーカー サイズを変更する簡単な方法はありますか?
以下は、Big Class.jmp を使用した例です。マーカー サイズとフレーム サイズを変更して、両方の変動チャートで機能させる方法が見つかりませんでした。for ループを使用せずに簡単な方法があるかどうかはわかりません。
ありがとう、
レックス
Open( "$SAMPLE_DATA/Big Class.jmp" );
Variability Chart(
Y( :Height ,:Weight),
X(:sex),
Analysis Type( "Choose best analysis (EMS REML Bayesian)" ),
Std Dev Chart( 0 ),
Points Jittered( 1 ),
Show Box Plots( 0 ),
Show range bars(0),
Connect cell means(0),
Show cell means(0),
SendToReport(
Dispatch(
{},
"variability chart",
FrameBox,
{Frame Size( 800, 240 ), Marker Size( 2 )}
)
)
);自動化とスクリプト基本的なデータ分析とモデリングデータの探索と視覚化ウィンドウズRe: 多重変動プロットのマーカーサイズとフレームサイズの変更XPathを使用してフレームボックスへの参照リストを取得し、そのリストにメッセージを送信することができます。
Names Default To Here(1);
dt = Open("$SAMPLE_DATA/Big Class.jmp");
var = dt << Variability Chart(
Y(:Height, :Weight),
X(:sex),
Analysis Type("Choose best analysis (EMS REML Bayesian)"),
Std Dev Chart(0),
Points Jittered(1),
Show Box Plots(0),
Show range bars(0),
Connect cell means(0),
Show cell means(0)
);
fbs = Report(var) << XPath("//FrameBox[@helpKey = 'Variability Chart']");
fbs[1::N Items(fbs)::2] << Frame Size(300, 300) << Marker Size(10);
stddev チャートがレポート内にあるため、1、3 のインデックス (1::N Items(fbs)::2) を使用します。これらは非表示になっているだけです (この場合は 2 と 4 のインデックス)。ただし、おそらくそれらのサイズも更新しても問題ないでしょう。
Re: 多重変動プロットのマーカーサイズとフレームサイズの変更- ジャーモ、
このサンプル スクリプトのもう 1 つの問題は、「Show Box Plots(0)」でボックス プロットがオフにならないことです。この例でボックス プロットをオフにする方法を教えていただけますか?
ありがとう、
レックス
Re: 多重変動プロットのマーカーサイズとフレームサイズの変更私の例では無効になっています。それでもうまくいかない場合は、アウトライン変動分析（またはプラットフォーム）ごとにメッセージを個別に送信できます。
Names Default To Here(1);
dt = Open("$SAMPLE_DATA/Big Class.jmp");
var = dt << Variability Chart(
Y(:Height, :Weight),
X(:sex),
Analysis Type("Choose best analysis (EMS REML Bayesian)"),
Std Dev Chart(0),
Points Jittered(1),
Show Box Plots(0),
Show range bars(0),
Connect cell means(0),
Show cell means(0)
);
fbs = Report(var) << XPath("//FrameBox[@helpKey = 'Variability Chart']");
fbs[1::N Items(fbs)::2] << Frame Size(300, 300) << Marker Size(10);
obs_varanalysis = Report(var) << XPath("//OutlineBox[@helpKey = 'Variability' and contains(text(), 'Variability Gauge Analysis for')]");
(obs_varanalysis << Get Scriptable Object) << show box plots(1); // change to 0
スクリプトインデックスにも例がありますが、ループが必要になる場合があります。
またはJMP18をお持ちの場合は<<ブロードキャストが機能するはずです
Names Default To Here(1);
dt = Open("$SAMPLE_DATA/Big Class.jmp");
var = dt << Variability Chart(
Y(:Height, :Weight),
X(:sex),
Analysis Type("Choose best analysis (EMS REML Bayesian)"),
Std Dev Chart(0),
Points Jittered(1),
Show Box Plots(0),
Show range bars(0),
Connect cell means(0),
Show cell means(0)
);
fbs = Report(var) << XPath("//FrameBox[@helpKey = 'Variability Chart']");
fbs[1::N Items(fbs)::2] << Frame Size(300, 300) << Marker Size(10);
var << (Variability Analysis[1] << Broadcast(Show Box Plots(1)));
