800949_it-IT

liliconcom

Modificare la dimensione del marcatore e la dimensione del frame del grafico a variabilità multipla

Ciao a tutti,

Esiste un modo semplice per utilizzare le funzioni "sendtoreport" e "dispatch" per modificare le dimensioni del frame e del marker dei grafici di variabilità :height e :weight?

Di seguito è riportato un esempio che usa Big Class.jmp. Non sono riuscito a trovare un modo per modificare la dimensione del marcatore e la dimensione del frame in modo che funzionino in entrambi i grafici di variabilità. Non sono sicuro che ci sia un modo semplice senza dover usare il ciclo for.

Grazie,

rex

Open( "$SAMPLE_DATA/Big Class.jmp" );
Variability Chart(
		Y( :Height ,:Weight),
		X(:sex),
		Analysis Type( "Choose best analysis (EMS REML Bayesian)" ),
		Std Dev Chart( 0 ),
		Points Jittered( 1 ),
		Show Box Plots( 0 ),
		Show range bars(0),
		Connect cell means(0),
		Show cell means(0),
		SendToReport(
				Dispatch(
					{},
					"variability chart",
					FrameBox,
					{Frame Size( 800, 240 ), Marker Size( 2 )}
				)
		)
	);

Automazione e scriptingAnalisi e modellazione dei dati di baseEsplorazione e visualizzazione dei datiFinestreRe: Modificare la dimensione del marcatore e la dimensione del frame del grafico a variabilità multipla

È possibile utilizzare XPath per ottenere l'elenco dei riferimenti ai framebox e quindi inviare messaggi a tale elenco

Names Default To Here(1);

dt = Open("$SAMPLE_DATA/Big Class.jmp");
var = dt << Variability Chart(
	Y(:Height, :Weight),
	X(:sex),
	Analysis Type("Choose best analysis (EMS REML Bayesian)"),
	Std Dev Chart(0),
	Points Jittered(1),
	Show Box Plots(0),
	Show range bars(0),
	Connect cell means(0),
	Show cell means(0)
);

fbs = Report(var) << XPath("//FrameBox[@helpKey = 'Variability Chart']");

fbs[1::N Items(fbs)::2] << Frame Size(300, 300) << Marker Size(10);

Utilizzo indici 1,3 (1::N Items(fbs)::2) perché i grafici stddev sono nel report, sono solo nascosti (in questo caso indici 2 e 4), ma molto probabilmente andrebbe bene aggiornare anche quelle dimensioni.

Re: Modificare la dimensione del marcatore e la dimensione del frame del grafico a variabilità multipla

-Jarmo,

Un altro problema che ho in questo script di esempio è che "Show Box Plots(0)" non disattiva il box plot. Puoi consigliarmi come disattivare il box plot in questo esempio?

Grazie,

rex

Re: Modificare la dimensione del marcatore e la dimensione del frame del grafico a variabilità multipla

Per me sono disabilitati nel mio esempio. Se non funziona, puoi inviare il messaggio separatamente a ciascuna delle analisi di variabilità di contorno (o alla piattaforma)

Names Default To Here(1);

dt = Open("$SAMPLE_DATA/Big Class.jmp");
var = dt << Variability Chart(
	Y(:Height, :Weight),
	X(:sex),
	Analysis Type("Choose best analysis (EMS REML Bayesian)"),
	Std Dev Chart(0),
	Points Jittered(1),
	Show Box Plots(0),
	Show range bars(0),
	Connect cell means(0),
	Show cell means(0)
);

fbs = Report(var) << XPath("//FrameBox[@helpKey = 'Variability Chart']");

fbs[1::N Items(fbs)::2] << Frame Size(300, 300) << Marker Size(10);

obs_varanalysis = Report(var) << XPath("//OutlineBox[@helpKey = 'Variability' and contains(text(), 'Variability Gauge Analysis for')]");
(obs_varanalysis << Get Scriptable Object) << show box plots(1); // change to 0

Anche l'indice di scripting ha un esempio, ma potrebbe essere necessario un ciclo

o se hai JMP18 << La trasmissione dovrebbe funzionare

Names Default To Here(1);

dt = Open("$SAMPLE_DATA/Big Class.jmp");
var = dt << Variability Chart(
	Y(:Height, :Weight),
	X(:sex),
	Analysis Type("Choose best analysis (EMS REML Bayesian)"),
	Std Dev Chart(0),
	Points Jittered(1),
	Show Box Plots(0),
	Show range bars(0),
	Connect cell means(0),
	Show cell means(0)
);

fbs = Report(var) << XPath("//FrameBox[@helpKey = 'Variability Chart']");
fbs[1::N Items(fbs)::2] << Frame Size(300, 300) << Marker Size(10);

var << (Variability Analysis[1] << Broadcast(Show Box Plots(1)));