800949_de-DE

liliconcom

Markergröße und Rahmengröße des Diagramms mit multipler Variabilität ändern

Hallo zusammen,

Gibt es eine einfache Möglichkeit, mit den Funktionen „sendtoreport“ und „dispatch“ die Rahmengröße und Markierungsgröße der Variabilitätsdiagramme :height und :weight zu ändern?

Unten sehen Sie ein Beispiel mit Big Class.jmp. Ich konnte keine Möglichkeit finden, die Markierungs- und Rahmengröße so zu ändern, dass sie in beiden Variabilitätsdiagrammen funktioniert. Ich bin mir nicht sicher, ob es eine einfache Möglichkeit gibt, ohne die For-Schleife verwenden zu müssen.

Danke,

rex

Open( "$SAMPLE_DATA/Big Class.jmp" );
Variability Chart(
		Y( :Height ,:Weight),
		X(:sex),
		Analysis Type( "Choose best analysis (EMS REML Bayesian)" ),
		Std Dev Chart( 0 ),
		Points Jittered( 1 ),
		Show Box Plots( 0 ),
		Show range bars(0),
		Connect cell means(0),
		Show cell means(0),
		SendToReport(
				Dispatch(
					{},
					"variability chart",
					FrameBox,
					{Frame Size( 800, 240 ), Marker Size( 2 )}
				)
		)
	);

Automatisierung und SkriptingGrundlegende Datenanalyse und ModellierungDatenexploration und -visualisierungWindowsBetreff: Markergröße und Rahmengröße des Diagramms mit mehreren Variabilitäten ändern

Sie können XPath verwenden, um eine Liste mit Verweisen auf Frameboxen abzurufen und dann Nachrichten an diese Liste zu senden

Names Default To Here(1);

dt = Open("$SAMPLE_DATA/Big Class.jmp");
var = dt << Variability Chart(
	Y(:Height, :Weight),
	X(:sex),
	Analysis Type("Choose best analysis (EMS REML Bayesian)"),
	Std Dev Chart(0),
	Points Jittered(1),
	Show Box Plots(0),
	Show range bars(0),
	Connect cell means(0),
	Show cell means(0)
);

fbs = Report(var) << XPath("//FrameBox[@helpKey = 'Variability Chart']");

fbs[1::N Items(fbs)::2] << Frame Size(300, 300) << Marker Size(10);

Ich verwende 1,3 Indizes (1::N Elemente (fbs)::2), da die Standardabweichungsdiagramme im Bericht enthalten sind. Sie sind nur ausgeblendet (in diesem Fall die Indizes 2 und 4), aber höchstwahrscheinlich wäre es in Ordnung, auch diese Größen zu aktualisieren.

Betreff: Markergröße und Rahmengröße des Diagramms mit mehreren Variabilitäten ändern

-Jarmo,

Ein weiteres Problem, das ich in diesem Beispielskript habe, ist, dass „Show Box Plots(0)“ das Boxplot nicht ausschaltet. Können Sie mir bitte erklären, wie man das Boxplot in diesem Beispiel ausschaltet?

Danke,

rex

Betreff: Markergröße und Rahmengröße des Diagramms mit mehreren Variabilitäten ändern

Für mich sind sie in meinem Beispiel deaktiviert. Wenn das nicht funktioniert, können Sie die Nachricht separat an jede der Gliederungsvariabilitätsanalysen (oder die Plattform) senden.

Names Default To Here(1);

dt = Open("$SAMPLE_DATA/Big Class.jmp");
var = dt << Variability Chart(
	Y(:Height, :Weight),
	X(:sex),
	Analysis Type("Choose best analysis (EMS REML Bayesian)"),
	Std Dev Chart(0),
	Points Jittered(1),
	Show Box Plots(0),
	Show range bars(0),
	Connect cell means(0),
	Show cell means(0)
);

fbs = Report(var) << XPath("//FrameBox[@helpKey = 'Variability Chart']");

fbs[1::N Items(fbs)::2] << Frame Size(300, 300) << Marker Size(10);

obs_varanalysis = Report(var) << XPath("//OutlineBox[@helpKey = 'Variability' and contains(text(), 'Variability Gauge Analysis for')]");
(obs_varanalysis << Get Scriptable Object) << show box plots(1); // change to 0

Der Scripting-Index enthält auch ein Beispiel, aber dies könnte eine Schleife erfordern

oder wenn Sie JMP18 haben << Broadcast sollte funktionieren

Names Default To Here(1);

dt = Open("$SAMPLE_DATA/Big Class.jmp");
var = dt << Variability Chart(
	Y(:Height, :Weight),
	X(:sex),
	Analysis Type("Choose best analysis (EMS REML Bayesian)"),
	Std Dev Chart(0),
	Points Jittered(1),
	Show Box Plots(0),
	Show range bars(0),
	Connect cell means(0),
	Show cell means(0)
);

fbs = Report(var) << XPath("//FrameBox[@helpKey = 'Variability Chart']");
fbs[1::N Items(fbs)::2] << Frame Size(300, 300) << Marker Size(10);

var << (Variability Analysis[1] << Broadcast(Show Box Plots(1)));