800949_fr-FR

liliconcom

Modifier la taille du marqueur et la taille du cadre du graphique à variabilité multiple

Salut tout le monde,

Existe-t-il un moyen simple d'utiliser les fonctions « sendtoreport » et « dispatch » pour modifier la taille du cadre et la taille du marqueur des graphiques de variabilité :height et :weight ?

Vous trouverez ci-dessous un exemple utilisant Big Class.jmp. Je n'ai pas trouvé de moyen de modifier la taille du marqueur et la taille du cadre pour qu'elles fonctionnent dans les deux graphiques de variabilité. Je ne sais pas s'il existe un moyen simple sans avoir à utiliser la boucle for.

Merci,

rex

Open( "$SAMPLE_DATA/Big Class.jmp" );
Variability Chart(
		Y( :Height ,:Weight),
		X(:sex),
		Analysis Type( "Choose best analysis (EMS REML Bayesian)" ),
		Std Dev Chart( 0 ),
		Points Jittered( 1 ),
		Show Box Plots( 0 ),
		Show range bars(0),
		Connect cell means(0),
		Show cell means(0),
		SendToReport(
				Dispatch(
					{},
					"variability chart",
					FrameBox,
					{Frame Size( 800, 240 ), Marker Size( 2 )}
				)
		)
	);

Automatisation et scriptsAnalyse et modélisation de données de baseExploration et visualisation des donnéesFenêtresRé: Modifier la taille du marqueur et la taille du cadre du graphique à variabilité multiple

Vous pouvez utiliser XPath pour obtenir la liste des références aux frameboxes, puis envoyer des messages à cette liste

Names Default To Here(1);

dt = Open("$SAMPLE_DATA/Big Class.jmp");
var = dt << Variability Chart(
	Y(:Height, :Weight),
	X(:sex),
	Analysis Type("Choose best analysis (EMS REML Bayesian)"),
	Std Dev Chart(0),
	Points Jittered(1),
	Show Box Plots(0),
	Show range bars(0),
	Connect cell means(0),
	Show cell means(0)
);

fbs = Report(var) << XPath("//FrameBox[@helpKey = 'Variability Chart']");

fbs[1::N Items(fbs)::2] << Frame Size(300, 300) << Marker Size(10);

J'utilise 1,3 index (1::N Items(fbs)::2) car les graphiques stddev sont dans le rapport, ils sont simplement masqués (2 et 4 index dans ce cas) mais il serait probablement acceptable de mettre à jour ces tailles également.

Ré: Modifier la taille du marqueur et la taille du cadre du graphique à variabilité multiple

-Jarmo,

Un autre problème que j'ai dans cet exemple de script est que « Afficher les boîtes à moustaches (0) » ne désactive pas la boîte à moustaches. Pouvez-vous m'indiquer comment désactiver la boîte à moustaches dans cet exemple ?

Merci,

rex

Ré: Modifier la taille du marqueur et la taille du cadre du graphique à variabilité multiple

Pour moi, ils sont désactivés dans mon exemple. Si cela ne fonctionne pas, vous pouvez envoyer le message séparément à chacune des analyses de variabilité du contour (ou à la plateforme)

Names Default To Here(1);

dt = Open("$SAMPLE_DATA/Big Class.jmp");
var = dt << Variability Chart(
	Y(:Height, :Weight),
	X(:sex),
	Analysis Type("Choose best analysis (EMS REML Bayesian)"),
	Std Dev Chart(0),
	Points Jittered(1),
	Show Box Plots(0),
	Show range bars(0),
	Connect cell means(0),
	Show cell means(0)
);

fbs = Report(var) << XPath("//FrameBox[@helpKey = 'Variability Chart']");

fbs[1::N Items(fbs)::2] << Frame Size(300, 300) << Marker Size(10);

obs_varanalysis = Report(var) << XPath("//OutlineBox[@helpKey = 'Variability' and contains(text(), 'Variability Gauge Analysis for')]");
(obs_varanalysis << Get Scriptable Object) << show box plots(1); // change to 0

L'index de script a également un exemple, mais cela peut nécessiter une boucle

ou si vous avez JMP18 << La diffusion devrait fonctionner

Names Default To Here(1);

dt = Open("$SAMPLE_DATA/Big Class.jmp");
var = dt << Variability Chart(
	Y(:Height, :Weight),
	X(:sex),
	Analysis Type("Choose best analysis (EMS REML Bayesian)"),
	Std Dev Chart(0),
	Points Jittered(1),
	Show Box Plots(0),
	Show range bars(0),
	Connect cell means(0),
	Show cell means(0)
);

fbs = Report(var) << XPath("//FrameBox[@helpKey = 'Variability Chart']");
fbs[1::N Items(fbs)::2] << Frame Size(300, 300) << Marker Size(10);

var << (Variability Analysis[1] << Broadcast(Show Box Plots(1)));