800824_ko-KR

liliconcom

다른 Y축에 걸쳐 다른 색상으로 배경에 주석을 달려면 어떻게 해야 하나요?

다음 JSL은 X축의 100~120 영역을 다른 색상으로 주석 처리할 수 있지만, 다른 Y축에 걸쳐 있을 수는 없습니다. Y축의 다른 변수에 다른 변수의 배경색을 주석 처리하도록 수정하려면 어떻게 해야 합니까?

Names Default To Here(1);

dt = Open("$SAMPLE_DATA/Big Class.jmp");

gb = dt << Graph Builder(
	Variables(X(:weight), Y(:height),Y(:age)),
	Elements(Points(X, Y, Legend(3))),
	SendToReport(

		Dispatch(
			{},
			"weight",
			ScaleBox,
			{Add Ref Line(100, "Solid", "blue", "", 5),
			Add Ref Line(120, "Solid", "blue", "", 5)}
		)
	)
);

rep = gb << report;
framebox = rep[frame box(1)];
framebox << Add Graphics Script(
	Transparency(0.5);
	Fill Color("Gray");
	Rect(100, Y Origin() + Y Range(), 120, Y Origin() , 1)
);

데이터 탐색 및 시각화Re: Y축에 따라 다른 색상으로 배경에 주석을 달려면 어떻게 해야 하나요?

여러 축(또는 그룹, 랩 또는 페이지)이 있는 경우 여러 FrameBox가 있으므로 예를 들어 각각에 별도의 그래픽 스크립트를 추가할 수 있습니다. 아래는 단순화된 버전입니다.

Names Default To Here(1);

dt = Open("$SAMPLE_DATA/Big Class.jmp");

gb = dt << Graph Builder(
	Variables(X(:weight), Y(:height), Y(:age)),
	Elements(Points(X, Y, Legend(3)))
);

rep = gb << report;
fbs = rep << XPath("//FrameBox");

fbs[1] << Add Graphics Script(
	Transparency(0.5);
	Fill Color("Gray");
	Rect(100, Y Origin() + Y Range(), 120, Y Origin(), 1);
);

fbs[2] << Add Graphics Script(
	Transparency(0.5);
	Fill Color("Green");
	Rect(100, Y Origin() + Y Range(), 120, Y Origin(), 1);
);

Re: Y축에 따라 다른 색상으로 배경에 주석을 달려면 어떻게 해야 하나요?

추가 질문: X축의 데이터 유형이 "텍스트"인 경우 색상 상자를 어떻게 그릴 수 있습니까?

예를 들어, TIM부터 JOE까지의 범위를 특정 색상으로 표시하고 싶습니다.

Names Default To Here(1);

dt = Open("$SAMPLE_DATA/Big Class.jmp");

gb = dt << Graph Builder(
	Variables(X(:name), Y(:height), Y(:age)),
	Elements(Points(X, Y, Legend(3)))
);

rep = gb << report;
fbs = rep << XPath("//FrameBox");

fbs[1] << Add Graphics Script(
	Transparency(0.5);
	Fill Color("Gray");
	Rect("TIM", Y Origin() + Y Range(), "JOE", Y Origin(), 1);
);

fbs[2] << Add Graphics Script(
	Transparency(0.5);
	Fill Color("Green");
	Rect("TIM", Y Origin() + Y Range(), "JOE", Y Origin(), 1);
);

Re: Y축에 따라 다른 색상으로 배경에 주석을 달려면 어떻게 해야 하나요?

올바른 x축 값을 파악한 다음 이를 활용해야 합니다.

Names Default To Here(1);

dt = Open("$SAMPLE_DATA/Big Class.jmp");

gb = dt << Graph Builder(
	Variables(X(:name), Y(:height), Y(:age)),
	Elements(Points(X, Y, Legend(3)))
);

rep = gb << report;
fbs = rep << XPath("//FrameBox");

fbs[1] << Add Graphics Script(
	Transparency(0.5);
	Fill Color("Gray");
	Rect(17, Y Origin() + Y Range(), 37, Y Origin(), 1);
);

fbs[2] << Add Graphics Script(
	Transparency(0.5);
	Fill Color("Green");
	Rect(17, Y Origin() + Y Range(), 37, Y Origin(), 1);
);

이는 쉽거나 때로는 매우 어려울 수 있지만 X축 설정 및 레이블을 확인하면 아이디어를 얻을 수 있습니다.

Re: Y축에 따라 다른 색상으로 배경에 주석을 달려면 어떻게 해야 하나요?

JSL을 사용하여 현재 X축에서 LABEL과 VALUE의 매핑을 어떻게 읽을 수 있습니까? 현재 X축에서 LABEL과 해당 VALUE를 읽는 방법을 찾을 수 없습니다.

텍스트 라벨에서 MATCH를 사용하여 VALUE를 구한 다음 색상이 있는 상자로 특정 값 범위를 강조 표시하고 싶습니다.

Re: Y축에 따라 다른 색상으로 배경에 주석을 달려면 어떻게 해야 하나요?

제 기억이 맞다면... (현재) 가장 쉬운 방법은 요약 테이블이나 요약을 이용하여 데이터 테이블에서 읽는 것입니다.

Re: Y축에 따라 다른 색상으로 배경에 주석을 달려면 어떻게 해야 하나요?

사용자가 선택한 영역에 따라 X축에 색상을 표시하고 싶습니다. 그러나 사용자가 로컬 데이터 필터를 사용했기 때문에 차트의 X축이 변경됩니다. X축의 텍스트 형식이 가변적이므로 고정된 값과 레이블 대응 관계를 지정할 수 없습니다. 차트의 X축에 있는 레이블과 값에 직접 액세스하거나 로컬 데이터 필터에서 사용자의 선택에 따라 X축에 있는 해당 값과 레이블을 결정할 수 있기를 바랍니다. 아래 스크립트에서 볼 수 있듯이 사용자가 로컬 데이터 필터를 선택하고 추가로 색상으로 표시할 X축을 선택할 수 있도록 하려고 합니다. 그래프의 X축에 현재 표시된 항목이나 로컬 데이터 필터에서 선택한 결과를 얻을 수 없다면 해당 값과 레이블을 원활하게 얻을 수 없습니다. 이를 달성할 수 있는 방법이 있습니까?"

Names Default To Here(1);

dt = Open("$SAMPLE_DATA/Big Class.jmp");

gb = dt << Graph Builder(
	Variables(X(:name), Y(:height), Y(:age)),
	Elements(Points(X, Y, Legend(3))),
	Local Data Filter(
		Add Filter(
			columns( :name ),
			Where(
				:name == {"ALFRED", "ALICE", "AMY", "BARBARA", "CAROL", "CHRIS",
				"CLAY"}
			),
			Display( :name, N Items( 15 ), Find( Set Text( "" ) ) )
		)
	),
);

rep = gb << report;
fbs = rep << XPath("//FrameBox");

fbs[1] << Add Graphics Script(
	Transparency(0.5);
	Fill Color("Gray");
	Rect(2, Y Origin() + Y Range(), 4, Y Origin(), 1);
);

fbs[2] << Add Graphics Script(
	Transparency(0.5);
	Fill Color("Green");
	Rect(2, Y Origin() + Y Range(), 4, Y Origin(), 1);
);

Re: Y축에 따라 다른 색상으로 배경에 주석을 달려면 어떻게 해야 하나요?

관리할 로컬 필터가 있다면 더 복잡해질 가능성이 큽니다. 어느 범위를 색칠하고 싶으신가요? 사용자가 그 범위를 필터링하거나 한쪽 끝을 필터링하면 어떻게 되나요?

Re: Y축에 따라 다른 색상으로 배경에 주석을 달려면 어떻게 해야 하나요?

네, 로컬 데이터 필터가 있으면 더 복잡해집니다. 따라서 그래프의 X축에 있는 현재 항목을 얻거나 로컬 데이터 필터의 선택된 옵션을 읽어 현재 값과 레이블에 대한 매핑 테이블을 계산하는 기술이 있는지 알고 싶습니다.

Re: Y축에 따라 다른 색상으로 배경에 주석을 달려면 어떻게 해야 하나요?

로컬 데이터 필터에서 다양한 유형의 값을 얻은 다음 이를 구문 분석/활용할 수 있습니다.

Names Default To Here(1);
dt = Open("$SAMPLE_DATA/Car Poll.jmp");
dist = dt << Distribution(
	Nominal Distribution(Column(:country))
);

ldf = dist << Local Data Filter(
	Add Filter(columns(:sex), Where(:sex == "Female")),
	Mode(Show(1), Include(1))
);

Show(ldf << get script, ldf << Get where clause, ldf << Get Filtered Rows);

행이 필터링되지 않는 특수한 경우를 확인하는 것을 잊지 마세요.