800824_ja-JP

liliconcom

異なる Y 軸にわたって異なる色で背景に注釈を付けるにはどうすればよいですか?

次の JSL では、X 軸上の 100 から 120 の領域に異なる色で注釈を付けることができますが、異なる Y 軸にまたがることはできません。異なる変数に異なる背景色で Y 軸上の異なる変数に注釈を付けるように変更するには、どうすればよいでしょうか。

Names Default To Here(1);

dt = Open("$SAMPLE_DATA/Big Class.jmp");

gb = dt << Graph Builder(
	Variables(X(:weight), Y(:height),Y(:age)),
	Elements(Points(X, Y, Legend(3))),
	SendToReport(

		Dispatch(
			{},
			"weight",
			ScaleBox,
			{Add Ref Line(100, "Solid", "blue", "", 5),
			Add Ref Line(120, "Solid", "blue", "", 5)}
		)
	)
);

rep = gb << report;
framebox = rep[frame box(1)];
framebox << Add Graphics Script(
	Transparency(0.5);
	Fill Color("Gray");
	Rect(100, Y Origin() + Y Range(), 120, Y Origin() , 1)
);

データの探索と視覚化Re: 異なる Y 軸にわたって異なる色で背景に注釈を付けるにはどうすればよいですか?

複数の軸（またはグループ、ラップ、ページ）がある場合は複数のフレームボックスがあるため、たとえば、それぞれに個別のグラフィック スクリプトを追加できます。以下は簡略版です。

Names Default To Here(1);

dt = Open("$SAMPLE_DATA/Big Class.jmp");

gb = dt << Graph Builder(
	Variables(X(:weight), Y(:height), Y(:age)),
	Elements(Points(X, Y, Legend(3)))
);

rep = gb << report;
fbs = rep << XPath("//FrameBox");

fbs[1] << Add Graphics Script(
	Transparency(0.5);
	Fill Color("Gray");
	Rect(100, Y Origin() + Y Range(), 120, Y Origin(), 1);
);

fbs[2] << Add Graphics Script(
	Transparency(0.5);
	Fill Color("Green");
	Rect(100, Y Origin() + Y Range(), 120, Y Origin(), 1);
);

Re: 異なる Y 軸にわたって異なる色で背景に注釈を付けるにはどうすればよいですか?

追加の質問: X 軸のデータ型が「テキスト」の場合、カラー ボックスを描画するにはどうすればよいですか?

たとえば、TIM から JOE までの範囲を特定の色でマークしたいとします。

Names Default To Here(1);

dt = Open("$SAMPLE_DATA/Big Class.jmp");

gb = dt << Graph Builder(
	Variables(X(:name), Y(:height), Y(:age)),
	Elements(Points(X, Y, Legend(3)))
);

rep = gb << report;
fbs = rep << XPath("//FrameBox");

fbs[1] << Add Graphics Script(
	Transparency(0.5);
	Fill Color("Gray");
	Rect("TIM", Y Origin() + Y Range(), "JOE", Y Origin(), 1);
);

fbs[2] << Add Graphics Script(
	Transparency(0.5);
	Fill Color("Green");
	Rect("TIM", Y Origin() + Y Range(), "JOE", Y Origin(), 1);
);

Re: 異なる Y 軸にわたって異なる色で背景に注釈を付けるにはどうすればよいですか?

正しいX軸の値を把握し、それを活用する必要があります

Names Default To Here(1);

dt = Open("$SAMPLE_DATA/Big Class.jmp");

gb = dt << Graph Builder(
	Variables(X(:name), Y(:height), Y(:age)),
	Elements(Points(X, Y, Legend(3)))
);

rep = gb << report;
fbs = rep << XPath("//FrameBox");

fbs[1] << Add Graphics Script(
	Transparency(0.5);
	Fill Color("Gray");
	Rect(17, Y Origin() + Y Range(), 37, Y Origin(), 1);
);

fbs[2] << Add Graphics Script(
	Transparency(0.5);
	Fill Color("Green");
	Rect(17, Y Origin() + Y Range(), 37, Y Origin(), 1);
);

これは簡単なこともあれば、時には非常に難しいこともありますが、X軸の設定とラベルを確認することでアイデアを得ることができます。

Re: 異なる Y 軸にわたって異なる色で背景に注釈を付けるにはどうすればよいですか?

JSL を使用して現在の X 軸の LABEL と VALUE のマッピングを読み取るにはどうすればよいですか? 現在の X 軸の LABEL と対応する VALUE を読み取る方法が見つかりません。

テキスト ラベルで MATCH を使用して VALUE を取得し、特定の値の範囲を色付きのボックスで強調表示したいと思います。

Re: 異なる Y 軸にわたって異なる色で背景に注釈を付けるにはどうすればよいですか?

私の記憶が正しければ... (現在のところ) 最も簡単な方法は、Summary テーブルまたは Summarize を使用してデータ テーブルから読み取ることです。

Re: 異なる Y 軸にわたって異なる色で背景に注釈を付けるにはどうすればよいですか?

ユーザーが選択した領域に応じて、X 軸に色を付けたいのですが、ユーザーがローカル データ フィルターを使用すると、グラフの X 軸が変わります。X 軸のテキスト形式は可変であるため、固定値とラベルの対応を指定することはできません。グラフの X 軸のラベルと値に直接アクセスするか、ローカル データ フィルターでのユーザーの選択に基づいて、X 軸の対応する値とラベルを決定できるようにしたいと考えています。以下のスクリプトに示すように、ユーザーがローカル データ フィルターを選択し、さらに色でマークする X 軸を選択できるようにしたいと考えています。グラフの X 軸に現在表示されている項目や、ローカル データ フィルターで選択した結果を取得できない場合、対応する値とラベルをスムーズに取得することはできません。これを実現する方法はありますか。

Names Default To Here(1);

dt = Open("$SAMPLE_DATA/Big Class.jmp");

gb = dt << Graph Builder(
	Variables(X(:name), Y(:height), Y(:age)),
	Elements(Points(X, Y, Legend(3))),
	Local Data Filter(
		Add Filter(
			columns( :name ),
			Where(
				:name == {"ALFRED", "ALICE", "AMY", "BARBARA", "CAROL", "CHRIS",
				"CLAY"}
			),
			Display( :name, N Items( 15 ), Find( Set Text( "" ) ) )
		)
	),
);

rep = gb << report;
fbs = rep << XPath("//FrameBox");

fbs[1] << Add Graphics Script(
	Transparency(0.5);
	Fill Color("Gray");
	Rect(2, Y Origin() + Y Range(), 4, Y Origin(), 1);
);

fbs[2] << Add Graphics Script(
	Transparency(0.5);
	Fill Color("Green");
	Rect(2, Y Origin() + Y Range(), 4, Y Origin(), 1);
);

Re: 異なる Y 軸にわたって異なる色で背景に注釈を付けるにはどうすればよいですか?

管理するローカル フィルターがある場合は、おそらくさらに複雑になります。どの範囲に色を付けますか? ユーザーがその範囲またはその一端をフィルターするとどうなりますか?

Re: 異なる Y 軸にわたって異なる色で背景に注釈を付けるにはどうすればよいですか?

はい、ローカル データ フィルターが存在すると、より複雑になります。したがって、グラフの X 軸上の現在の項目を取得する方法や、ローカル データ フィルターの選択されたオプションを読み取って、現在の値とラベルのマッピング テーブルを計算する方法があるかどうかを知りたいです。

Re: 異なる Y 軸にわたって異なる色で背景に注釈を付けるにはどうすればよいですか?

ローカルデータフィルタからさまざまなタイプの値を取得し、それらを解析/利用することができます。

Names Default To Here(1);
dt = Open("$SAMPLE_DATA/Car Poll.jmp");
dist = dt << Distribution(
	Nominal Distribution(Column(:country))
);

ldf = dist << Local Data Filter(
	Add Filter(columns(:sex), Where(:sex == "Female")),
	Mode(Show(1), Include(1))
);

Show(ldf << get script, ldf << Get where clause, ldf << Get Filtered Rows);

行がフィルタリングされていない特別なケースも必ず確認してください。