800504_es-ES

liliconcom

Durante el bucle, se extrae el nombre de la columna de la lista y se agrega a la tabla del informe

Estoy trabajando en un script que recorre una lista de respuestas Y y ejecuta una degradación (prueba de estabilidad) en cada una antes de generar partes del informe en una tabla de datos combinados. Consta de los siguientes pasos:

1. Abre un cuadro de diálogo donde el usuario selecciona varias "Y, respuesta", la "Hora" y la "etiqueta, ID del sistema".
2. Para cada "respuesta Y", el script recorre el bucle y ejecuta una prueba de estabilidad de degradación y genera la información de "Comparaciones de modelos" en un informe.
3. Concatena los informes en una tabla maestra.

He incluido un código para tomar el nombre de la columna y de cada bucle y agregarlo como una nueva columna a cada informe y luego concatenar cada informe a una nueva tabla maestra. Los informes individuales y la 'combinedDataTable' tienen la nueva columna ("Source Y Column"); sin embargo, no completa las celdas con el nombre de la columna respectiva. El script se ejecuta bien y sin errores. He incluido una serie de capturas de pantalla a continuación. El código problemático se encuentra hacia el final del script.

 

// Initialize an empty data table to store combined results
combinedDataTable = New Table( "Combined Degradation Data" );

// Loop through each selected Y column and perform degradation analysis
For( i = 1, i <= N Items( YCols ), i++,
	currentYCol = Column( dt, YCols[i] );

    // Calculate the min and max values of the current Y column
	minValue = Col Minimum( currentYCol );
	maxValue = Col Maximum( currentYCol );

    // Adjust the min and max values by 2%
	adjustedMin = minValue * 0.98;
	adjustedMax = maxValue * 1.02;

    // Determine the increment value based on the highest value
	If( maxValue < 5,
		incValue = 0.25,
		If( maxValue > 5 & maxValue < 15,
			incValue = 0.25,
			If( maxValue > 90,
				incValue = 0.5,
				incValue = (adjustedMax - adjustedMin) / 10
			)
		)
	);
	
	//Determine the X Scale Box Based on Number of Timepoints
	maxTimepoint = Col Maximum( Column( dt, XCols[1] ) );
	adjustedMaxTimepoint = maxTimepoint + 1;

    // Perform Degradation Analysis
	degReport = dt << Degradation(
		Y( currentYCol ),
		Time( Column( dt, XCols[1] ) ), // Assuming only one X column is selected
		Label( Column( dt, BCols[1] ) ), // Assuming only one By column is selected
		Application( "Stability Test" ),
		Connect Data Markers( 0 ),
		Show Fitted Lines( 1 ),
		Show Spec Limits( 1 ),
		Show Median Curves( 0 ),
		Show Legend( 1 ),
		No Tab List( 0 ),
		Use Pooled MSE for Nonpoolable Model( 0 ),
		Set Censoring Time( . ),
		Show Residual Plot( 1 ),
		Show Inverse Prediction Plot( 1 ),
		Show Curve Interval( 1 ),
		Inverse Prediction Interval( "Confidence Interval" ),
		Inverse Prediction Alpha( 0.05 ),
		Inverse Prediction Side( "Lower One Sided" ),
		SendToReport(
			Dispatch( {"Overlay"}, "1", ScaleBox, {Min( -1 ), Max( adjustedMaxTimepoint ), Inc( 6 ), Minor Ticks( 1 )} ),
			Dispatch(
				{"Overlay"},
				"2",
				ScaleBox,
				{Format( "Fixed Dec", 12, 1 ), Min( adjustedMin ), Max( adjustedMax ), Inc( incValue ), Minor Ticks( 0 )}
			)
		)
	);
	 // Extract the data from the specified location
	extractedData = Report( degReport )["Degradation Data Analysis"]["Overlay"]["Stability Tests"][Table Box( 2 )] << Make Combined Data Table;

    // Add a column to indicate the source Y column
	currentYColName = Column( dt, YCols[i] ) << Get Name;
	extractedData << New Column( "Source Y Column", Character, "Nominal", Set Values( Repeat( currentYColName, N Rows( extractedData ) ) ) );

    // Combine the extracted data into the combined data table
	combinedDataTable << Concatenate( extractedData, Append to first table( 1 ) );
    
     // Close the individual report window
	Close( Window( degReport ) );
);

// Show the combined data table
combinedDataTable << Show Window;

Notas:
Aquí se muestra la ventana de resultados de uno de los análisis de degradación. Extraigo la información en el contorno rojo.

Aquí está la tabla de salida maestra que tiene ambas respuestas Y, pero la 'Columna de origen Y' no está completa.

 

Automatización y scriptingAnálisis de confiabilidadRe: Durante el bucle, se extrae el nombre de la columna de la lista y se agrega a la tabla del informe

Si está configurando el mismo valor para cada una de las filas, puede usar establecer cada valor

Names Default To Here(1);
dt = Open("$SAMPLE_DATA/Big Class.jmp");
mystr = "ABC";
dt << New Column("X", Character, Set Each Value(mystr));