799260_ja-JP

liliconcom

管理図上の特定のポイントを強調表示する

こんにちは、

限界値 (この場合は 98%) 以下のデータ ポイントを強調表示したいのですが、うまくいかないようです。どこでエラーが発生しているのかわかりません。

これが私の jsl コードです:

Names Default To Here( 1 );
dt2 = Current Data Table();<BR />
dt2 << begin data update;
fairows = dt2 << get rows where( As Column( "1" ) <= 0.98 );
dt2 << end data update;<BR />
vc1 = dt2 << Control Chart Builder(
	Size( 890, 273 ),
	Show Two Shewhart Charts( 0 ),
	Test Excluded Subgroups( 0 ),
	Include Missing Categories( 0 ),
	Show Excluded Region( 0 ),
	Show Limit Summaries( 0 ),
	Variables( Subgroup( :Date ), Y( :"1"n ) ),
	Chart(
		Points( Statistic( "Individual" ) ),
		Limits( Sigma( "Moving Range" ), Show Center Line( 0 ), Show Lower Limit( 0 ), Show Upper Limit( 0 ) )
	),
	Show Control Panel( 0 ),
	SendToReport(
		Dispatch( {}, "Control Chart Builder", OutlineBox, {Set Title( "1" )} ),
		Dispatch( {}, "Date", ScaleBox, {Label Row( {Label Orientation( "Angled" ), Set Font Size( 8 )} )} ),
		Dispatch(
			{},
			"1",
			ScaleBox,
			{Add Ref Line( 0.928901607373389, "Dotted", "Medium Light Magenta", "Suggested (92.89%)", 3 ),
			Add Ref Line( 0.897380548253792, "Solid", "Orange", "4.5 sigma(89.74%)", 2 ), Add Ref Line(
				0.865859489134196, "Solid", "Medium Dark Green", "6 sigma(86.59%)", 2
			), Add Ref Line( 0.9, "Dense Dash", "Medium Dark Red", "90.00%", 3 )}
		),
		Dispatch( {}, "graph display 1 title", TextEditBox, {Set Text( "" )} ),
		Dispatch( {}, "Subgroup display 1 title", TextEditBox, {Set Text( "" ), Set Font Size( 10 ), Set Font Style( "Bold" )} ),
		Dispatch( {}, "Y display 1 title", TextEditBox, {Set Text( "" )} ),
		Dispatch( {}, "Control Chart Builder", FrameBox, {Background Color( -15658734 ), Marker Size( 2 ), Marker Drawing Mode( "Outlined" )} )
	)
);



//Highlight data points < 98%
Eval(

	Eval Expr(

		Report( vc1 )[Framebox( 1 )] << add graphics script(
			Marker(
				Marker Size( 10 );
				Color State( "red" );,
				Expr( :"1"n[fairows] ),
				Expr( :Date[fairows] )
			)
		)

	)

);

自動化とスクリプトRe: 管理図上の特定のポイントを強調表示する

あなたが探しているものを実現できるかもしれないオプションが1つあります

Names Default To Here(1);

dt = Open("$DOWNLOADS/data.jmp");

fairows = dt << get rows where(As Column("1") <= 0.98);

vc1 = dt << Control Chart Builder(
	Size(890, 273),
	Show Two Shewhart Charts(0),
	Test Excluded Subgroups(0),
	Include Missing Categories(0),
	Show Excluded Region(0),
	Show Limit Summaries(0),
	Variables(Subgroup(:Date), Y(:"1"n)),
	Chart(Points(Statistic("Individual")), Limits(Sigma("Moving Range"), Show Center Line(0), Show Lower Limit(0), Show Upper Limit(0))),
	Show Control Panel(0),
	SendToReport(
		Dispatch({}, "Control Chart Builder", OutlineBox, {Set Title("1")}),
		Dispatch({}, "Date", ScaleBox, {Label Row({Label Orientation("Angled"), Set Font Size(8)})}),
		Dispatch({}, "1", ScaleBox,
			{Add Ref Line(0.928901607373389, "Dotted", "Medium Light Magenta", "Suggested (92.89%)", 3),
			Add Ref Line(0.897380548253792, "Solid", "Orange", "4.5 sigma(89.74%)", 2), Add Ref Line(
				0.865859489134196, "Solid", "Medium Dark Green", "6 sigma(86.59%)", 2
			), Add Ref Line(0.9, "Dense Dash", "Medium Dark Red", "90.00%", 3)}
		),
		Dispatch({}, "graph display 1 title", TextEditBox, {Set Text("")}),
		Dispatch({}, "Subgroup display 1 title", TextEditBox, {Set Text(""), Set Font Size(10), Set Font Style("Bold")}),
		Dispatch({}, "Y display 1 title", TextEditBox, {Set Text("")}),
		Dispatch({}, "Control Chart Builder", FrameBox, {Background Color(-15658734), Marker Size(2), Marker Drawing Mode("Outlined")})
	)
);

ms = Report(vc1)[FrameBox(1)] << Find Seg(MarkerSeg(1));
xs = ms << Get X Values;
ys = ms << Get Y Values;

Eval(Eval Expr(
	Report(vc1)[Framebox(1)] << add graphics script(
		Marker Size(10);
		Marker(
			Color State("red"),
			Expr(xs[fairows]),
			Expr(ys[fairows])
		)
	);
));

Re: 管理図上の特定のポイントを強調表示する

ありがとう、Jarmo!

Re: 管理図上の特定のポイントを強調表示する

他の良い選択肢としては、テーブルに新しい列を作成し、それに基づいて行の状態を追加することです（行の凡例として使用することもできます）。ただし、この方法ではマーカーのサイズを簡単に変更することはできません。

Re: 管理図上の特定のポイントを強調表示する

こんにちは@jthi さん

何らかの理由で、0.007 未満の値が強調表示されています。ただし、行を取得するための条件は '>' に設定されています。xs と ys に何か問題があります。また、別のグラフに反映されるため、行に色を付けたくありません。グラフィック スクリプトが優先されます。

Names Default To Here( 1 );
dt = Current Data Table();
fairows = dt << get rows where( As Column( "861" ) > 0.007 );

vc1 = dt << Control Chart Builder(
	Size( 890, 273 ),
	Show Two Shewhart Charts( 0 ),
	Test Excluded Subgroups( 0 ),
	Include Missing Categories( 0 ),
	Show Excluded Region( 0 ),
	Show Limit Summaries( 0 ),
	Variables( Subgroup( :Date ), Y( :"861"n ) ),
	Chart( Points( Statistic( "Average" ) ), Limits( Sigma( "Moving Range" ), Show Center Line( 0 ), Show Lower Limit( 0 ), Show Upper Limit( 0 ) ) ),
	Show Control Panel( 0 ),
	SendToReport(
		Dispatch(
			{},
			"Control Chart Builder",
			OutlineBox,
			{Set Title( "861                                                                       Percent Fail: 1.45%" )}
		),
		Dispatch( {}, "Date", ScaleBox, {Label Row( {Label Orientation( "Angled" ), Set Font Size( 8 )} )} ),
		Dispatch(
			{},
			"861",
			ScaleBox,
			{Add Ref Line( 0.00435435825878142, "Solid", "Blue", "3 sigma(0.44%)", 2 ), Add Ref Line(
				0.00653153738817213, "Dotted", "Medium Light Magenta", "Suggested (0.65%)", 3
			), Add Ref Line( 0.00870871651756283, "Solid", "Medium Dark Green", "6 sigma(0.87%)", 2 ), Add Ref Line(
				0.007, "Dense Dash", "Medium Dark Red", "0.70%", 3
			)}
		),
		Dispatch( {}, "graph display 1 title", TextEditBox, {Set Text( "" )} ),
		Dispatch( {}, "Subgroup display 1 title", TextEditBox, {Set Text( "" ), Set Font Size( 10 ), Set Font Style( "Bold" )} ),
		Dispatch( {}, "Y display 1 title", TextEditBox, {Set Text( "" )} )
	)
);

ms = Report( vc1 )[FrameBox( 1 )] << Find Seg( Marker Seg( 1 ) );
xs = ms << Get X Values;
ys = ms << Get Y Values;

Eval(
	Eval Expr(
		Report( vc1 )[Framebox( 1 )] << add graphics script(
			Marker Size( 10 );
			Marker( Color State( "red" ), Expr( xs[fairows] ), Expr( ys[fairows] ) );
		)
	)
);

Re: 管理図上の特定のポイントを強調表示する

同じ行に一致するかどうかを比較する必要があります。一致しない場合は、まずデータを並べ替え、目的の行を取得し、管理図を作成してからマーカーを追加することをお勧めします。

Re: 管理図上の特定のポイントを強調表示する

どうやって比較すればいいのでしょうか？

Re: 管理図上の特定のポイントを強調表示する

テーブルから値を取得し、xs と ys の値と比較します (比較を実行する方法は無限にあります)。データには問題を引き起こす可能性のある重複値が 1 つあるようです。データ テーブルではなく ys で比較を実行したほうがよいのではないでしょうか。

r = Loc(ys > 0.007);