798728_de-DE

liliconcom

[JSL] Weitere Informationen zu Spalten in einem Listenfeld hinzufügen ()

Hallo,

Ich versuche, ein neues Fenster () anzuzeigen, um den Benutzer aufzufordern, einige kategorische Faktoren aus einer Datentabelle in einer Listbox () auszuwählen.

Ich möchte diese Auswahl näher erläutern und Folgendes hervorheben:

- die Anzahl der Ebenen für jeden Faktor

- eine Farbe, um den Anteil leerer Zellen in den einzelnen Faktorenspalten anzuzeigen

Im Anhang finden Sie ein Beispiel dessen, was ich erreichen möchte.

Im folgenden Skript berechne ich die Informationen für jeden Faktor und fülle eine Liste „Wert“ aus.

Aber dann weiß ich nicht, wie ich mit diesen Informationen an das Design der List Box () herangehen soll

Vielen Dank für Ihre Hilfe

- der Prediger

Names Default To Here( 1 );
clear symbols();
Deletesymbols();

dt = New Table( "RawData",
	Add Rows( 20 ),
	New Column("factor1", Character, set values( {"A","A","A","A","A","A","A","B","B","B","B","B","B","C","C","C","C","C","C","C"})),
	New Column("factor2", Character, set values( {"T0","DROP1","DROP2","DROP3","DROP4","DROP5","DROP6","T0","DROP1","DROP2","DROP3","DROP4","DROP5","T0","DROP1","DROP2","DROP3","DROP4","DROP5", "DROP6"})),
	New Column("factor3", Character, set values({"1","1","1","2","2","", ,"","","" ,"" ,"", "","3","3","3","3"}) ),
	New Column("factor4", Character, set values({"a","a","a", "", "", "a", "a", "a", "a", "a", "a", "b", "b", "b", "b" , "b", "b", "b", "b"}) );
	);

RawDataCol = dt << get column names ("character");
show (RawDataCol);

for(i=1, i<= N items (RawDataCol), i++,
	FactorSummary = {};
	Eval(Eval Expr(FactorSummary = Column(dt, Expr(char(RawDataCol[i]))) << get values));
	//show (FactorSummary);
	
	//find cell count (non empty)
	Eval(Eval Expr(For( j = N Items(FactorSummary), j > 0, j--,
		If( FactorSummary[j] == "",
			Remove From( FactorSummary, j, 1 )
		)
	)));
	
	//Find number of level within a factor (non empty)
	Eval(Eval Expr(Summarize( LevelSummary = by(Column(dt, Expr(char(RawDataCol[i])))) )));
		Eval(Eval Expr(For( j = N Items(LevelSummary), j > 0, j--,
		If( LevelSummary[j] == "",
			Remove From( LevelSummary, j, 1 )
		)
	)));
	//show (LevelSummary);
	
	Eval(Eval Expr(Value = {Expr(RawDataCol[i]), Expr(N items(LevelSummary)), Expr(N items (FactorSummary) / N row(dt))}));
	show (Value);
);

MainWindow = New Window( "Select Factors",
	<<MODAL></MODAL>

<LINGO-LABS id="lingo-labs-798728" slang="en-US" mode="CREATE"><LINGO-LABEL>Automatisierung und Skripting</LINGO-LABEL></LINGO-LABS>Betreff: [JSL] Weitere Informationen zu Spalten in einer Listbox hinzufügen ()

Ich würde von der Verwendung eines Listenfelds zu einem Tabellenfeld wechseln, in dem mehrere Spalten angezeigt werden können.

Die Verwendung unterschiedlicher Farben für unterschiedliche Zeilen bleibt weiterhin ein Problem. Sie können jedoch problemlos eine Spalte mit den Zeichen 1, 2 usw. „*“ hinzufügen, um unterschiedliche Ebenen anzuzeigen.

Betreff: [JSL] Weitere Informationen zu Spalten in einer Listbox hinzufügen ()

List Box ist nicht die flexibelste Anzeigebox und ich stimme txnelson zu, dass Sie Table Box verwenden könnten. Unten ist ein Beispiel

Names Default To Here(1);

dt = New Table("RawData",
	Add Rows(20),
	New Column("factor1",
		Character,
		set values({"A", "A", "A", "A", "A", "A", "A", "B", "B", "B", "B", "B", "B", "C", "C", "C", "C", "C", "C", "C"})
	),
	New Column("factor2",
		Character,
		set values(
			{"T0", "DROP1", "DROP2", "DROP3", "DROP4", "DROP5", "DROP6", "T0", "DROP1", "DROP2", "DROP3", "DROP4", "DROP5", "T0", "DROP1", "DROP2",
			"DROP3", "DROP4", "DROP5", "DROP6"}
		)
	),
	New Column("factor3", Character, set values({"1", "1", "1", "2", "2", "", , "", "", "", "", "", "", "3", "3", "3", "3"})),
	New Column("factor4", Character, set values({"a", "a", "a", "", "", "a", "a", "a", "a", "a", "a", "b", "b", "b", "b", "b", "b", "b", "b"}))
);

cols = dt << get column names("character", "string");
factors = {};
factor_counts = {};
missing_perc = {};

For Each({colname}, cols,
	Summarize(dt, uniq = by(Eval(colname)));
	Remove From(uniq, Contains(uniq, ""));
	nvalues = Col Number(Column(dt, colname));
	Insert Into(factors, colname);
	Insert Into(factor_counts, N Items(uniq));
	Insert Into(missing_perc, (nvalues)/ N Rows(dt));
);

dt_factors = New Table("Demo",
	Add Rows(N Items(factors)),
	New Column("Factor", Character, Nominal, Values(factors)),
	New Column("Count", Numeric, Continuous, Values(factor_counts)),
	New Column("% Non-missing", Numeric, Continuous, Format("Percent", 12, 3), Values(missing_perc)),
	Invisible
);

orange_rows = dt_factors << Get Rows Where(:"% Non-missing"n < 0.5);
yellow_rows = dt_factors << Get Rows Where(0.5 < :"% Non-missing"n < 0.9);

For Each({colname}, dt_factors << Get Column Names("String"),
	Column(dt_factors, colname) << Color Cells("Green");
	Column(dt_factors, colname) << Color Cells("Orange", orange_rows);
	Column(dt_factors, colname) << Color Cells("Yellow", yellow_rows);
);

nw = New Window("Select",
	H List Box(
		Panel Box("Select factors to run the analysis",
			bb = dt_factors << get as report
		),
		Panel Box("Actions",
			Lineup Box(N Col(1),
				Button Box("OK",
					tb = bb << child;
					sel_rows = tb << get selected rows;
					show(sel_rows, tb[1][sel_rows]);
				),
				Button Box("Cancel", << Set Function(function({this}, this << close window))),
			)
		)
	)
);


Close(dt_factors, no save);

Betreff: [JSL] Weitere Informationen zu Spalten in einer Listbox hinzufügen ()

Hallo Jarmo,

Mir gefällt diese Lösung sehr gut (danke auch an Jim für den Vorschlag).

Ich muss dabei berücksichtigen, dass möglicherweise mehrere Dutzend Faktoren eine Rolle spielen.
Gibt es eine Möglichkeit, eine feste Höhe für Table Box() zu erzwingen?

Beispielsweise nur 5 sichtbare Zeilen und die Möglichkeit, nach unten zu scrollen, um eine feste Höhe zu erhalten, damit weitere Benutzereingaben (Optionsfelder, Kontrollkästchen usw.) hinzugefügt werden können.

Unten sehen Sie ein Beispiel für eine Tabellenbox () mit mehreren Zeilen, die alle sichtbar sind (bei vielen weiteren Faktoren wird es zu einem Problem)

Vielen Dank

Names Default To Here(1);

dt = New Table("RawData",
	Add Rows(20),
	New Column("factor1",
		Character,
		set values({"A", "A", "A", "A", "A", "A", "A", "B", "B", "B", "B", "B", "B", "C", "C", "C", "C", "C", "C", "C"})
	),
	New Column("factor2",
		Character,
		set values(
			{"T0", "DROP1", "DROP2", "DROP3", "DROP4", "DROP5", "DROP6", "T0", "DROP1", "DROP2", "DROP3", "DROP4", "DROP5", "T0", "DROP1", "DROP2",
			"DROP3", "DROP4", "DROP5", "DROP6"}
		)
	),
	New Column("factor3", Character, set values({"1", "1", "1", "2", "2", "", , "", "", "", "", "", "", "3", "3", "3", "3"})),
	New Column("factor4", Character, set values({"a", "a", "a", "", "", "a", "a", "a", "a", "a", "a", "b", "b", "b", "b", "b", "b", "b", "b"})),
	New Column("factor5", Character, set values({"a", "a", "a", "", "", "a", "a", "a", "a", "a", "a", "b", "b", "b", "b", "b", "b", "b", "b"})),
	New Column("factor6", Character, set values({"a", "a", "a", "", "", "a", "a", "a", "a", "a", "a", "b", "b", "b", "b", "b", "b", "b", "b"})),
	New Column("factor7", Character, set values({"a", "a", "a", "", "", "a", "a", "a", "a", "a", "a", "b", "b", "b", "b", "b", "b", "b", "b"})),
	New Column("factor8", Character, set values({"a", "a", "a", "", "", "a", "a", "a", "a", "a", "a", "b", "b", "b", "b", "b", "b", "b", "b"})),
	New Column("factor9", Character, set values({"a", "a", "a", "", "", "a", "a", "a", "a", "a", "a", "b", "b", "b", "b", "b", "b", "b", "b"})),
	New Column("factor10", Character, set values({"a", "a", "a", "", "", "a", "a", "a", "a", "a", "a", "b", "b", "b", "b", "b", "b", "b", "b"})),
	New Column("factor12", Character, set values({"a", "a", "a", "", "", "a", "a", "a", "a", "a", "a", "b", "b", "b", "b", "b", "b", "b", "b"})),
	New Column("factor13", Character, set values({"a", "a", "a", "", "", "a", "a", "a", "a", "a", "a", "b", "b", "b", "b", "b", "b", "b", "b"})),
	New Column("factorA", Character, set values({"a", "a", "a", "", "", "a", "a", "a", "a", "a", "a", "b", "b", "b", "b", "b", "b", "b", "b"})),
	New Column("factorB", Character, set values({"a", "a", "a", "", "", "a", "a", "a", "a", "a", "a", "b", "b", "b", "b", "b", "b", "b", "b"})),
	New Column("factorB1", Character, set values({"a", "a", "a", "", "", "a", "a", "a", "a", "a", "a", "b", "b", "b", "b", "b", "b", "b", "b"})),
	New Column("factorC", Character, set values({"a", "a", "a", "", "", "a", "a", "a", "a", "a", "a", "b", "b", "b", "b", "b", "b", "b", "b"})),
	New Column("factorD", Character, set values({"a", "a", "a", "", "", "a", "a", "a", "a", "a", "a", "b", "b", "b", "b", "b", "b", "b", "b"})),
	New Column("factor69", Character, set values({"a", "a", "a", "", "", "a", "a", "a", "a", "a", "a", "b", "b", "b", "b", "b", "b", "b", "b"})),
	New Column("factor67", Character, set values({"a", "a", "a", "", "", "a", "a", "a", "a", "a", "a", "b", "b", "b", "b", "b", "b", "b", "b"})),
	New Column("factor47", Character, set values({"a", "a", "a", "", "", "a", "a", "a", "a", "a", "a", "b", "b", "b", "b", "b", "b", "b", "b"})),
	New Column("factor56", Character, set values({"a", "a", "a", "", "", "a", "a", "a", "a", "a", "a", "b", "b", "b", "b", "b", "b", "b", "b"}))
);

cols = dt << get column names("character", "string");
factors = {};
factor_counts = {};
missing_perc = {};

For Each({colname}, cols,
	Summarize(dt, uniq = by(Eval(colname)));
	Remove From(uniq, Contains(uniq, ""));
	nvalues = Col Number(Column(dt, colname));
	Insert Into(factors, colname);
	Insert Into(factor_counts, N Items(uniq));
	Insert Into(missing_perc, (nvalues)/ N Rows(dt));
);

dt_factors = New Table("Demo",
	Add Rows(N Items(factors)),
	New Column("Factor", Character, Nominal, Values(factors)),
	New Column("Count", Numeric, Continuous, Values(factor_counts)),
	New Column("% Non-missing", Numeric, Continuous, Format("Percent", 12, 3), Values(missing_perc)),
	Invisible
);

orange_rows = dt_factors << Get Rows Where(:"% Non-missing"n < 0.5);
yellow_rows = dt_factors << Get Rows Where(0.5 < :"% Non-missing"n < 0.9);

For Each({colname}, dt_factors << Get Column Names("String"),
	Column(dt_factors, colname) << Color Cells("Green");
	Column(dt_factors, colname) << Color Cells("Orange", orange_rows);
	Column(dt_factors, colname) << Color Cells("Yellow", yellow_rows);
);

nw = New Window("Select",
	H List Box(
		Panel Box("Select factors to run the analysis",
			bb = dt_factors << get as report
		),
		Panel Box("Actions",
			Lineup Box(N Col(1),
				Button Box("OK",
					tb = bb << child;
					sel_rows = tb << get selected rows;
					show(sel_rows, tb[1][sel_rows]);
				),
				Button Box("Cancel", << Set Function(function({this}, this << close window))),
			)
		)
	)
);


Close(dt_factors, no save);

Betreff: [JSL] Weitere Informationen zu Spalten in einer Listbox hinzufügen ()

Schauen Sie im Skriptindex nach und suchen Sie im Tabellenfeld. Dort finden Sie Beispiele zum Festlegen der Anzahl der Anzeigezeilen.

Betreff: [JSL] Weitere Informationen zu Spalten in einer Listbox hinzufügen ()

Hallo Jim,

JA!, der Befehl << set scrollable ( 5 , 0 ); löst mein Problem.

Vielen Dank!!

Julien