798498_es-ES

liliconcom

Agregar una tabla en la primera pestaña de un panel

¿Puedo agregar una tabla en la primera pestaña? como en el ejemplo.

Names Default To Here( 1 );

dt = Open( "$SAMPLE_DATA/Big Class.jmp" );


// Create a table for the first tab
tableBox = dt << Summary(
    Group( :sex ),
    Mean( :weight ),
    Mean( :height ),
    N
);

gb_collector = Tab Box( "Dashboard",
    V List Box(
        tableBox
    )
	
);


For( i = 1, i <= 20, i++,
    // Column box for plot of all batches
    col1 = Col Box( "All Batches" || Char( i ) );

    // Create the first Graph Builder plot
    gb = Expr(
        dt << Graph Builder(
            invisible,
            Show Control Panel( 0 ),
            Variables( X( :weight ), Y( :height ), Overlay( :sex ) ),
            Elements( Points( X, Y, Legend( 9 ) ), Line Of Fit( X, Y, Legend( 11 ) ) )
        )
    );
    col1 << Append( gb );

    // Create column boxes for the Graph Builder plots
    col2 = Col Box( "Actual Data " || Char( i ) );
    col3 = Col Box( "Actual  " || Char( i ) );

    // Loop to create and append multiple Graph Builder plots to col2 and col3
    For( j = 1, j <= 2, j++,
        gbb = Expr(
            dt << Graph Builder(
                invisible,
                Show Control Panel( 0 ),
                Variables( X( :weight ), Y( :height ), Overlay( :sex ) ),
                Elements( Points( X, Y, Legend( 5 ) ), Line Of Fit( X, Y, Legend( 11 ) ) )
            )
        );
        col2 << Append( gbb );

        gbbb = Expr(
            dt << Graph Builder(
                invisible,
                Show Control Panel( 0 ),
                Variables( X( :weight ), Y( :height ), Overlay( :sex ) ),
                Elements( Points( X, Y, Legend( 9 ) ), Line Of Fit( X, Y, Legend( 11 ) ) )
            )
        );
        col3 << Append( gbbb );
    );

    // Create a tab for col1, col2, and col3 and append it to gb_collector
    tab = Tab Page Box( Char(i),
        V List Box(
            col1,
            H List Box( col2, col3 ) // Placing the two plots next to each other
        )
    );
    gb_collector << Append( tab );

);

gb_collector << Dockable( 1 );
gb_collector << Set Overflow Enabled( 1 );

nw = New Window( "Dashboard",
    gb_collector
);

Exploración y visualización de datosRe: agregar una tabla en la primera pestaña de un panel

Puede utilizar Insertar con cuadro de pestaña para determinar en qué posición se debe agregar el cuadro de visualización

Con índice

Names Default To Here(1);
New Window("Example",
	tb = Tab Box(
		Tab Page Box("First Tab", Tip("First Tab Tooltip"), Button Box("Press One")),
		Tab Page Box("Second Tab", Closeable(1), Button Box("Press Two")),
		Tab Page Box("Third Tab", Icon("Nominal"), Button Box("Press Three"))
	)
);
Wait(1);
tb << Insert(1, Tab Page Box(Title("To first"), Button Box("Press Four")));

Re: agregar una tabla en la primera pestaña de un panel

¡Gracias! pero el problema es que me estoy demorando en imprimir la tabla en una pestaña.

Names Default To Here( 1 );

dt = Open( "$SAMPLE_DATA/Big Class.jmp" );


gb_collector = Tab Box();


For( i = 1, i <= 20, i++,
    // Column box for plot of all batches
    col1 = Col Box( "All Batches" || Char( i ) );

    // Create the first Graph Builder plot
    gb = Expr(
        dt << Graph Builder(
            invisible,
            Show Control Panel( 0 ),
            Variables( X( :weight ), Y( :height ), Overlay( :sex ) ),
            Elements( Points( X, Y, Legend( 9 ) ), Line Of Fit( X, Y, Legend( 11 ) ) )
        )
    );
    col1 << Append( gb );

    // Create column boxes for the Graph Builder plots
    col2 = Col Box( "Actual Data " || Char( i ) );
    col3 = Col Box( "Actual  " || Char( i ) );

    // Loop to create and append multiple Graph Builder plots to col2 and col3
    For( j = 1, j <= 2, j++,
        gbb = Expr(
            dt << Graph Builder(
                invisible,
                Show Control Panel( 0 ),
                Variables( X( :weight ), Y( :height ), Overlay( :sex ) ),
                Elements( Points( X, Y, Legend( 5 ) ), Line Of Fit( X, Y, Legend( 11 ) ) )
            )
        );
        col2 << Append( gbb );

        gbbb = Expr(
            dt << Graph Builder(
                invisible,
                Show Control Panel( 0 ),
                Variables( X( :weight ), Y( :height ), Overlay( :sex ) ),
                Elements( Points( X, Y, Legend( 9 ) ), Line Of Fit( X, Y, Legend( 11 ) ) )
            )
        );
        col3 << Append( gbbb );
    );

    // Create a tab for col1, col2, and col3 and append it to gb_collector
    tab = Tab Page Box( Char(i),
        V List Box(
            col1,
            H List Box( col2, col3 ) // Placing the two plots next to each other
        )
    );
    gb_collector << Append( tab );

);


// Create a table for the first tab
tableBox = Expr(dt << Summary(
    Group( :sex ),
    Mean( :weight ),
    Mean( :height ),
    N
));



// Create the "Results" tab
resultsTab = Tab Page Box("Results", tableBox);

// Insert the "Results" tab at the first position
gb_collector << Insert(1, resultsTab);


gb_collector << Dockable( 1 );
gb_collector << Set Overflow Enabled( 1 );

nw = New Window( "Dashboard",
    gb_collector
);

Re: agregar una tabla en la primera pestaña de un panel

Por ejemplo, puede utilizar obtener como informe.

Names Default To Here(1);
New Window("Example",
	tb = Tab Box(
		Tab Page Box("First Tab", Tip("First Tab Tooltip"), Button Box("Press One")),
		Tab Page Box("Second Tab", Closeable(1), Button Box("Press Two")),
		Tab Page Box("Third Tab", Icon("Nominal"), Button Box("Press Three"))
	)
);
Wait(1);

dt = open("$SAMPLE_DATA/Big Class.jmp");

tb << Insert(1, Tab Page Box(Title("To first"), 
	dt << get as report
));