798498_fr-FR

liliconcom

ajouter un tableau sur le premier onglet d'un tableau de bord

Puis-je ajouter dans le premier onglet un tableau ? comme l'exemple.

Names Default To Here( 1 );

dt = Open( "$SAMPLE_DATA/Big Class.jmp" );


// Create a table for the first tab
tableBox = dt << Summary(
    Group( :sex ),
    Mean( :weight ),
    Mean( :height ),
    N
);

gb_collector = Tab Box( "Dashboard",
    V List Box(
        tableBox
    )
	
);


For( i = 1, i <= 20, i++,
    // Column box for plot of all batches
    col1 = Col Box( "All Batches" || Char( i ) );

    // Create the first Graph Builder plot
    gb = Expr(
        dt << Graph Builder(
            invisible,
            Show Control Panel( 0 ),
            Variables( X( :weight ), Y( :height ), Overlay( :sex ) ),
            Elements( Points( X, Y, Legend( 9 ) ), Line Of Fit( X, Y, Legend( 11 ) ) )
        )
    );
    col1 << Append( gb );

    // Create column boxes for the Graph Builder plots
    col2 = Col Box( "Actual Data " || Char( i ) );
    col3 = Col Box( "Actual  " || Char( i ) );

    // Loop to create and append multiple Graph Builder plots to col2 and col3
    For( j = 1, j <= 2, j++,
        gbb = Expr(
            dt << Graph Builder(
                invisible,
                Show Control Panel( 0 ),
                Variables( X( :weight ), Y( :height ), Overlay( :sex ) ),
                Elements( Points( X, Y, Legend( 5 ) ), Line Of Fit( X, Y, Legend( 11 ) ) )
            )
        );
        col2 << Append( gbb );

        gbbb = Expr(
            dt << Graph Builder(
                invisible,
                Show Control Panel( 0 ),
                Variables( X( :weight ), Y( :height ), Overlay( :sex ) ),
                Elements( Points( X, Y, Legend( 9 ) ), Line Of Fit( X, Y, Legend( 11 ) ) )
            )
        );
        col3 << Append( gbbb );
    );

    // Create a tab for col1, col2, and col3 and append it to gb_collector
    tab = Tab Page Box( Char(i),
        V List Box(
            col1,
            H List Box( col2, col3 ) // Placing the two plots next to each other
        )
    );
    gb_collector << Append( tab );

);

gb_collector << Dockable( 1 );
gb_collector << Set Overflow Enabled( 1 );

nw = New Window( "Dashboard",
    gb_collector
);

Exploration et visualisation des donnéesRe: ajout d'un tableau sur le premier onglet d'un tableau de bord

Vous pouvez utiliser Insérer avec la zone d'onglets pour déterminer dans quelle position la zone d'affichage doit être ajoutée

Avec index

Names Default To Here(1);
New Window("Example",
	tb = Tab Box(
		Tab Page Box("First Tab", Tip("First Tab Tooltip"), Button Box("Press One")),
		Tab Page Box("Second Tab", Closeable(1), Button Box("Press Two")),
		Tab Page Box("Third Tab", Icon("Nominal"), Button Box("Press Three"))
	)
);
Wait(1);
tb << Insert(1, Tab Page Box(Title("To first"), Button Box("Press Four")));

Re: ajout d'un tableau sur le premier onglet d'un tableau de bord

merci ! mais le problème c'est que j'ai du mal à imprimer le tableau sur un onglet.

Names Default To Here( 1 );

dt = Open( "$SAMPLE_DATA/Big Class.jmp" );


gb_collector = Tab Box();


For( i = 1, i <= 20, i++,
    // Column box for plot of all batches
    col1 = Col Box( "All Batches" || Char( i ) );

    // Create the first Graph Builder plot
    gb = Expr(
        dt << Graph Builder(
            invisible,
            Show Control Panel( 0 ),
            Variables( X( :weight ), Y( :height ), Overlay( :sex ) ),
            Elements( Points( X, Y, Legend( 9 ) ), Line Of Fit( X, Y, Legend( 11 ) ) )
        )
    );
    col1 << Append( gb );

    // Create column boxes for the Graph Builder plots
    col2 = Col Box( "Actual Data " || Char( i ) );
    col3 = Col Box( "Actual  " || Char( i ) );

    // Loop to create and append multiple Graph Builder plots to col2 and col3
    For( j = 1, j <= 2, j++,
        gbb = Expr(
            dt << Graph Builder(
                invisible,
                Show Control Panel( 0 ),
                Variables( X( :weight ), Y( :height ), Overlay( :sex ) ),
                Elements( Points( X, Y, Legend( 5 ) ), Line Of Fit( X, Y, Legend( 11 ) ) )
            )
        );
        col2 << Append( gbb );

        gbbb = Expr(
            dt << Graph Builder(
                invisible,
                Show Control Panel( 0 ),
                Variables( X( :weight ), Y( :height ), Overlay( :sex ) ),
                Elements( Points( X, Y, Legend( 9 ) ), Line Of Fit( X, Y, Legend( 11 ) ) )
            )
        );
        col3 << Append( gbbb );
    );

    // Create a tab for col1, col2, and col3 and append it to gb_collector
    tab = Tab Page Box( Char(i),
        V List Box(
            col1,
            H List Box( col2, col3 ) // Placing the two plots next to each other
        )
    );
    gb_collector << Append( tab );

);


// Create a table for the first tab
tableBox = Expr(dt << Summary(
    Group( :sex ),
    Mean( :weight ),
    Mean( :height ),
    N
));



// Create the "Results" tab
resultsTab = Tab Page Box("Results", tableBox);

// Insert the "Results" tab at the first position
gb_collector << Insert(1, resultsTab);


gb_collector << Dockable( 1 );
gb_collector << Set Overflow Enabled( 1 );

nw = New Window( "Dashboard",
    gb_collector
);

Re: ajout d'un tableau sur le premier onglet d'un tableau de bord

Vous pouvez par exemple utiliser get as report

Names Default To Here(1);
New Window("Example",
	tb = Tab Box(
		Tab Page Box("First Tab", Tip("First Tab Tooltip"), Button Box("Press One")),
		Tab Page Box("Second Tab", Closeable(1), Button Box("Press Two")),
		Tab Page Box("Third Tab", Icon("Nominal"), Button Box("Press Three"))
	)
);
Wait(1);

dt = open("$SAMPLE_DATA/Big Class.jmp");

tb << Insert(1, Tab Page Box(Title("To first"), 
	dt << get as report
));