如何使用圖形產生器中的頁面選項在每個頁面上設定參考線？以下腳本使用圖形產生器中的頁面選項繪製一些圖表？如何為每個圖表設定水平參考線，例如重量 = 80 公斤並使用 JSL 標記它（80 公斤）？
（即使繪製的圖表數量發生變化，我也需要保留參考線）
Names Default To Here(1);
dt = open("$SAMPLE_DATA/Big Class.jmp");
gb = dt << Graph Builder(
Size(528, 2954),
Show Control Panel(0),
Variables(X(:height), Y(:weight), Page(:age)),
Elements(Points(X, Y, Legend(15)), Smoother(X, Y, Legend(16)))
);自動化和腳本編寫視窗回覆：如何使用圖形產生器中的頁面選項在每個頁面上設定參考線？Names Default To Here(1);
dt = open("$SAMPLE_DATA/Big Class.jmp");
gb = dt << Graph Builder(
Size(528, 2954),
Show Control Panel(0),
Variables(X(:height), Y(:weight), Page(:age)),
Elements(Points(X, Y, Legend(15)), Smoother(X, Y, Legend(16)))
);
axis = gb << XPath( "//AxisBox" );
Summarize( page = By( :age ) );
axis[2::(2*NItems( page ))::2] << Add Ref Line( 80, "Solid", "Red", "Reference" );回覆：如何使用圖形產生器中的頁面選項在每個頁面上設定參考線？如果我在繪圖後調用年齡上的本機資料過濾器， @Mark_Bailey將停止為我工作（JMP 16.2），如下所示
回覆：如何使用圖形產生器中的頁面選項在每個頁面上設定參考線？最簡單的方法是將新列新增到資料表中，每行具有相同的值，並將其新增至圖表。這將與過濾器一起使用
回覆：如何使用圖形產生器中的頁面選項在每個頁面上設定參考線？@jthi你的建議效果很好，除了我希望線路標籤位於右側。有沒有辦法改變線標籤的位置？
回覆：如何使用圖形產生器中的頁面選項在每個頁面上設定參考線？我不記得 JMP16 中有哪些選項可用，因為我現在主要使用 JMP18（混合了一些 JMP17）
Names Default To Here(1);
dt = Open("$SAMPLE_DATA/Big Class.jmp");
dt << New Column("Ref", Numeric, Continuous, Set Each Value(80));
gb = dt << Graph Builder(
Size(528, 984),
Show Control Panel(0),
Variables(X(:height), Y(:weight), Y(:Ref, Position(1)), Page(:age)),
Elements(
Points(X, Y(1), Legend(15)),
Smoother(X, Y(1), Legend(16)),
Line(Y(2), Legend(17))
),
Local Data Filter(
Add Filter(
columns(:age),
Where(:age == {12, 15}),
Display(:age, N Items(6))
)
),
SendToReport(
Dispatch({}, "400", ScaleBox,
{Legend Model(
17,
Level Name(0, "Ref", Item ID("Mean(Ref)", 1)),
Properties(
0,
{Line Label Properties(
{Name Label(1), Name Label Position("Last")}
)},
Item ID("Mean(Ref)", 1)
)
)}
)
)
);
Write();
回覆：如何使用圖形產生器中的頁面選項在每個頁面上設定參考線？無需更改數據表。
透過複製軸設置
Link Page Axes( "Y Only" )
也複製參考線。
例如
dt = Open( "$SAMPLE_DATA/Big Class.jmp" );
Graph Builder(
Link Page Axes( "Y Only" ),
Variables( X( :height ), Y( :weight ), Page( :sex ), Overlay( :sex ) ),
Elements( Points( X, Y), Smoother( X, Y) ),
SendToReport(
Dispatch( {}, "weight", ScaleBox,
{Add Ref Line( 100, "Solid", "Black", "", 1 )}
)
)
);
回覆：如何使用圖形產生器中的頁面選項在每個頁面上設定參考線？這也是一種選擇，但您確實失去了 Page 的好處之一：針對不同的「頁面」具有不同的軸縮放。這可能不是問題，甚至可能是一個好處。
回覆：如何使用圖形產生器中的頁面選項在每個頁面上設定參考線？@jthi謝謝。
Name Label Position("Last")似乎在 JMP 16.2 中不可用/工作。
@hogi我選擇“頁面”選項的原因是這樣我可以獲得不同的 y 軸縮放比例。我確信還有其他方法可以做到這一點，但頁面選項似乎最簡單。
回覆：如何使用圖形產生器中的頁面選項在每個頁面上設定參考線？然後您可能必須返回 Mark 的解決方案並使用過濾器更改處理程序。再次不知道 JMP16 使用此選項有什麼限制
Names Default To Here(1);
dt = Open("$SAMPLE_DATA/Big Class.jmp");
gb = dt << Graph Builder(
Size(528, 984),
Show Control Panel(0),
Variables(X(:height), Y(:weight), Page(:age)),
Elements(
Points(X, Y(1), Legend(15)),
Smoother(X, Y(1), Legend(16))
),
Local Data Filter(
Add Filter(
columns(:age),
Where(:age == {12, 15}),
Display(:age, N Items(6))
)
)
);
add_reflines = EvalExpr(
axis = Expr(gb) << XPath("//AxisBox");
axis[2::N Items(axis)::2] << Add Ref Line(80, "Solid", "Red", "Reference", 1, 1, Label Settings({Opposite Axis(1)}));
);
f = Function({a}, add_reflines);
ldf = (Report(gb) << top parent)[OutlineBox("Local Data Filter")] << Get Scriptable Object;
rs = ldf << Make Filter Change Handler(f);
add_reflines;
Write();
這不是執行此操作的最強大的選項，但它是相當簡單的選項。
回覆：如何使用圖形產生器中的頁面選項在每個頁面上設定參考線？圖形腳本可能是一種選擇
Names Default To Here(1);
dt = Open("$SAMPLE_DATA/Big Class.jmp");
gb = dt << Graph Builder(
Size(528, 984),
Show Control Panel(0),
Variables(X(:height), Y(:weight), Page(:age)),
Elements(
Points(X, Y(1), Legend(15)),
Smoother(X, Y(1), Legend(16))
)
);
(Report(gb) << XPath("//FrameBox")) << Add Graphics Script(
Pen Color("Red");
Text Color("red");
Text(Right Justified, {X Origin() + X Range(), 80}, "Reference");
H Line(80);
);
gb << Local Data Filter(
Add Filter(
columns(:age),
Display(:age, N Items(6))
)
);
Write();
