Wie legt man mit der Seitenoption im Graph Builder auf jeder Seite eine Referenzlinie fest?Das folgende Skript erstellt einige Diagramme mit der Seitenoption im Graph Builder. Wie lege ich für jedes Diagramm eine horizontale Referenzlinie fest, beispielsweise bei Gewicht = 80 kg, und beschrifte sie (80 kg) mit JSL?
(Die Referenzlinie muss erhalten bleiben, auch wenn sich die Anzahl der dargestellten Diagramme ändert.)
Names Default To Here(1);
dt = open("$SAMPLE_DATA/Big Class.jmp");
gb = dt << Graph Builder(
Size(528, 2954),
Show Control Panel(0),
Variables(X(:height), Y(:weight), Page(:age)),
Elements(Points(X, Y, Legend(15)), Smoother(X, Y, Legend(16)))
);Automatisierung und SkriptingWindowsBetreff: Wie lege ich mit der Seitenoption im Graph Builder auf jeder Seite eine Referenzlinie fest?Names Default To Here(1);
dt = open("$SAMPLE_DATA/Big Class.jmp");
gb = dt << Graph Builder(
Size(528, 2954),
Show Control Panel(0),
Variables(X(:height), Y(:weight), Page(:age)),
Elements(Points(X, Y, Legend(15)), Smoother(X, Y, Legend(16)))
);
axis = gb << XPath( "//AxisBox" );
Summarize( page = By( :age ) );
axis[2::(2*NItems( page ))::2] << Add Ref Line( 80, "Solid", "Red", "Reference" );Betreff: Wie lege ich mit der Seitenoption im Graph Builder auf jeder Seite eine Referenzlinie fest?@Mark_Bailey Funktioniert bei mir nicht mehr (JMP 16.2), wenn ich nach dem Plotten den lokalen Datenfilter für das Alter aufrufe, wie unten
Betreff: Wie lege ich mit der Seitenoption im Graph Builder auf jeder Seite eine Referenzlinie fest?Am einfachsten ist es, Ihrer Datentabelle eine neue Spalte mit demselben Wert für jede Zeile hinzuzufügen und diese dann Ihrem Diagramm hinzuzufügen. Dies funktioniert mit Filtern
Betreff: Wie lege ich mit der Seitenoption im Graph Builder auf jeder Seite eine Referenzlinie fest?@jthi, Ihr Vorschlag funktioniert gut, außer dass ich die Linienbeschriftung gerne rechts hätte. Gibt es eine Möglichkeit, die Position der Linienbeschriftung zu ändern?
Betreff: Wie lege ich mit der Seitenoption im Graph Builder auf jeder Seite eine Referenzlinie fest?Ich weiß nicht mehr, welche Optionen in JMP16 verfügbar sind, da ich heutzutage hauptsächlich JMP18 verwende (mit etwas JMP17 dazwischengemischt).
Names Default To Here(1);
dt = Open("$SAMPLE_DATA/Big Class.jmp");
dt << New Column("Ref", Numeric, Continuous, Set Each Value(80));
gb = dt << Graph Builder(
Size(528, 984),
Show Control Panel(0),
Variables(X(:height), Y(:weight), Y(:Ref, Position(1)), Page(:age)),
Elements(
Points(X, Y(1), Legend(15)),
Smoother(X, Y(1), Legend(16)),
Line(Y(2), Legend(17))
),
Local Data Filter(
Add Filter(
columns(:age),
Where(:age == {12, 15}),
Display(:age, N Items(6))
)
),
SendToReport(
Dispatch({}, "400", ScaleBox,
{Legend Model(
17,
Level Name(0, "Ref", Item ID("Mean(Ref)", 1)),
Properties(
0,
{Line Label Properties(
{Name Label(1), Name Label Position("Last")}
)},
Item ID("Mean(Ref)", 1)
)
)}
)
)
);
Write();
Betreff: Wie lege ich mit der Seitenoption im Graph Builder auf jeder Seite eine Referenzlinie fest?Es ist nicht erforderlich, die Datentabelle zu ändern.
Replizieren der Achseneinstellung über
Link Page Axes( "Y Only" )
kopiert auch die Referenzlinien.
z.B
dt = Open( "$SAMPLE_DATA/Big Class.jmp" );
Graph Builder(
Link Page Axes( "Y Only" ),
Variables( X( :height ), Y( :weight ), Page( :sex ), Overlay( :sex ) ),
Elements( Points( X, Y), Smoother( X, Y) ),
SendToReport(
Dispatch( {}, "weight", ScaleBox,
{Add Ref Line( 100, "Solid", "Black", "", 1 )}
)
)
);
Betreff: Wie lege ich mit der Seitenoption im Graph Builder auf jeder Seite eine Referenzlinie fest?Das ist auch eine Option, aber Sie verlieren einen der Vorteile von Page: die Möglichkeit, für verschiedene „Seiten“ unterschiedliche Achsenskalierungen zu haben. Dies ist hier möglicherweise kein Problem und könnte sogar von Vorteil sein.
Betreff: Wie lege ich mit der Seitenoption im Graph Builder auf jeder Seite eine Referenzlinie fest?@jthi Danke.
Name Label Position("Last")scheint in JMP 16.2 nicht verfügbar zu sein/zu funktionieren.
@hogi Der Grund, warum ich die Option „Seite“ gewählt habe, ist, dass ich so eine andere Skalierung der Y-Achse erhalten kann. Ich bin sicher, dass es andere Möglichkeiten gibt, dies zu tun, aber die Option „Seite“ scheint am einfachsten zu sein.
Betreff: Wie lege ich mit der Seitenoption im Graph Builder auf jeder Seite eine Referenzlinie fest?Dann müssen Sie möglicherweise zu Marks Lösung zurückkehren und den Filteränderungshandler damit verwenden. Auch hier keine Ahnung, was die Einschränkungen von JMP16 mit dieser Option sind
Names Default To Here(1);
dt = Open("$SAMPLE_DATA/Big Class.jmp");
gb = dt << Graph Builder(
Size(528, 984),
Show Control Panel(0),
Variables(X(:height), Y(:weight), Page(:age)),
Elements(
Points(X, Y(1), Legend(15)),
Smoother(X, Y(1), Legend(16))
),
Local Data Filter(
Add Filter(
columns(:age),
Where(:age == {12, 15}),
Display(:age, N Items(6))
)
)
);
add_reflines = EvalExpr(
axis = Expr(gb) << XPath("//AxisBox");
axis[2::N Items(axis)::2] << Add Ref Line(80, "Solid", "Red", "Reference", 1, 1, Label Settings({Opposite Axis(1)}));
);
f = Function({a}, add_reflines);
ldf = (Report(gb) << top parent)[OutlineBox("Local Data Filter")] << Get Scriptable Object;
rs = ldf << Make Filter Change Handler(f);
add_reflines;
Write();
Dies ist zwar nicht die zuverlässigste Möglichkeit, aber eine recht einfache.
Betreff: Wie lege ich mit der Seitenoption im Graph Builder auf jeder Seite eine Referenzlinie fest?Und Grafikskript könnte eine Option sein
Names Default To Here(1);
dt = Open("$SAMPLE_DATA/Big Class.jmp");
gb = dt << Graph Builder(
Size(528, 984),
Show Control Panel(0),
Variables(X(:height), Y(:weight), Page(:age)),
Elements(
Points(X, Y(1), Legend(15)),
Smoother(X, Y(1), Legend(16))
)
);
(Report(gb) << XPath("//FrameBox")) << Add Graphics Script(
Pen Color("Red");
Text Color("red");
Text(Right Justified, {X Origin() + X Range(), 80}, "Reference");
H Line(80);
);
gb << Local Data Filter(
Add Filter(
columns(:age),
Display(:age, N Items(6))
)
);
Write();
