797873_de-DE

liliconcom

Wie erhält man Spezifikationsgrenzen in separaten Spalten einer 5-Punkte-Zusammenfassungstabelle?

Das Beispielskript unten liefert mir die 5-Zahlen-Zusammenfassung im von mir benötigten Format. Ich möchte jedoch auch die Spezifikationsgrenzen für jeden Parameter (unter „Analysespalten“), LSL und USL, in zwei separaten Spalten in der endgültigen „Zusammenfassung“-Datentabelle erhalten. Wie bekomme ich dies über JSL?

Gibt es außerdem eine andere/bessere Möglichkeit, das zu tun, was ich brauche, ohne Tabulate() zu verwenden?

Names Default To Here( 1 );
Clear Log();
dt = Open( "$SAMPLE_DATA/Semiconductor Capability.jmp" );
col_names = dt << Get Column Group( "Processes" );

(dt << Tabulate(
	Show Control Panel( 0 ),
	Add Table(
		Column Table( Statistics( Min ) ),
		Column Table( Statistics( Mean, Median ) ),
		Column Table( Statistics( Max ) ),
		Column Table( Statistics( Std Dev ) ),
		Row Table(
			Grouping Columns( :lot_id, :wafer, :Wafer ID in lot ID ),
			Analysis Columns(
				Eval( col_names )

			)
		)
	)
)) << Make Into Data Table;

Automatisierung und SkriptingWindowsBetreff: Wie erhalte ich Spezifikationsgrenzen in separaten Spalten in einer 5-Punkte-Zusammenfassungstabelle?

Sie können das System „Limits verwalten“ verwenden, um zu tun, was Sie wollen

Names Default To Here( 1 );
Clear Log();
dt = Open( "$SAMPLE_DATA/Semiconductor Capability.jmp" );
col_names = dt << Get Column Group( "Processes" );

(tab = dt << Tabulate(
	Show Control Panel( 0 ),
	Add Table(
		Column Table( Statistics( Min ) ),
		Column Table( Statistics( Mean, Median ) ),
		Column Table( Statistics( Max ) ),
		Column Table( Statistics( Std Dev ) ),
		Row Table(
			Grouping Columns( :lot_id, :wafer, :Wafer ID in lot ID ),
			Analysis Columns(
				Eval( col_names )

			)
		)
	)
)) << Make Into Data Table;
dtTab = current data table();
tab << close window;

procCols = Associative Array(dtTab:Analysis Columns << get values) << get keys;
obj = dt << Manage Limits(
	Process Variables ( eval(procCols) )
);
obj << Save to Tall Limits Table;
dtLimits = current data table();
obj << close window;
try( window("Consistency Problem") << close window );

dtTab << Update(
	with( dtLimits ),
	Match Columns( :Analysis Columns = :Variable ),
	Add Columns from Update Table( :LSL, :Target, :USL)
);

Betreff: Wie erhalte ich Spezifikationsgrenzen in separaten Spalten in einer 5-Punkte-Zusammenfassungstabelle?

@txnelson Danke. Ich bekomme einen Fehler in meinem JMP 16.2

Betreff: Wie erhalte ich Spezifikationsgrenzen in separaten Spalten in einer 5-Punkte-Zusammenfassungstabelle?

Könnte ausreichen, wenn Sie Variablen verwenden, anstatt sich auf die aktuelle Datentabelle zu verlassen. Zumindest in JMP17.2 geben sowohl tabellieren << in Datentabelle erstellen als auch << Tabelle mit hohen Grenzwerten speichern einen Verweis auf die Tabelle zurück.

Names Default To Here(1);
Clear Log();
dt = Open("$SAMPLE_DATA/Semiconductor Capability.jmp");
col_names = dt << Get Column Group("Processes");

tab = dt << Tabulate(
	Show Control Panel(0),
	Add Table(
		Column Table(Statistics(Min)),
		Column Table(Statistics(Mean, Median)),
		Column Table(Statistics(Max)),
		Column Table(Statistics(Std Dev)),
		Row Table(
			Grouping Columns(:lot_id, :wafer, :Wafer ID in lot ID),
			Analysis Columns(
				Eval(col_names)

			)
		)
	)
);

dttab = tab << Make Into Data Table;
tab << close window;

procCols = Associative Array(dtTab:Analysis Columns << get values) << get keys;
obj = dt << Manage Limits(Process Variables(Eval(procCols)));
dtlimits = obj << Save to Tall Limits Table;
obj << close window;
Try(Window("Consistency Problem") << close window);

dtTab << Update(
	with(dtLimits),
	Match Columns(:Analysis Columns = :Variable),
	Add Columns from Update Table(:LSL, :Target, :USL)
);

Betreff: Wie erhalte ich Spezifikationsgrenzen in separaten Spalten in einer 5-Punkte-Zusammenfassungstabelle?

@jthi Erhalten Sie diesen Fehler bei JMP 16.2

Object 'Data Table' does not recognize the message 'Manage Limits'; <BR />perhaps you mean one of these:  <<MANAGE spec="" limits=""><<ITEM analysis=""><<FACTOR><<COMBINE columns...=""><<MAKE indicator=""><<NEW><<PASTE columns=""><<MARKERS><<SELECT matching="" cells=""><<GET rows=""><<MAXIMIZE display=""><<MOVE scripts=""><<RENAME table="" script=""><<MATCHED pairs=""><<MULTIVARIATE><<NORMAL mixtures=""><<CAPABILITY><<PARALLEL plot.="" there="" is="" no="" other="" opened="" data="https://community.jmp.com/" to="" update="" the="" current="" table.="" empty=""></PARALLEL></CAPABILITY></NORMAL></MULTIVARIATE></MATCHED></RENAME></MOVE></MAXIMIZE></GET></SELECT></MARKERS></PASTE></NEW></MAKE></COMBINE></FACTOR></ITEM></MANAGE>

Changing Manage Limits () to Manage Spec Limits () gives me another error.

<SPAN class="lia-inline-image-display-wrapper lia-image-align-inline" image-alt="Neo_0-1726217735617.png" style="width: 400px;"><SPAN class="lia-inline-image-display-wrapper" image-alt="Neo_0-1726217735617.png" style="width: 385px;"><SPAN class="lia-inline-image-display-wrapper" image-alt="Neo_0-1726217735617.png" style="width: 385px;"><span class="lia-inline-image-display-wrapper" image-alt="Neo_0-1726217735617.png" style="width: 385px;"><img src="https://us.v-cdn.net/6038925/uploads/images/68217i191CDFCAD2681B08/Neo_0-1726217735617.png" role="button" title="Neo_0-1726217735617.png" alt="Neo_0-1726217735617.png" /></span></SPAN></SPAN></SPAN>

Betreff: Wie erhalte ich Spezifikationsgrenzen in separaten Spalten in einer 5-Punkte-Zusammenfassungstabelle?

Vielleicht funktioniert das in JMP16.2 nicht. Sie müssen verschiedene Arten von Prüfungen für die Tabellen durchführen. Wenn ich mich richtig erinnere, ist Get Data Table List() eine ziemlich robuste Option und die neueste Tabelle ist immer zuerst

Betreff: Wie erhalte ich Spezifikationsgrenzen in separaten Spalten in einer 5-Punkte-Zusammenfassungstabelle?

Ich habe den Code geändert, um den Abschnitt „Limits verwalten“ zu entfernen und ihn in ein einfaches JSL-Stück zu ändern, das eine Limittabelle erstellt, indem es die Limits aus der Originaltabelle liest. Sehen Sie, ob das funktioniert

Names Default To Here( 1 );
Clear Log();
dt = Open( "$SAMPLE_DATA/Semiconductor Capability.jmp" );
col_names = dt << Get Column Group( "Processes" );

(tab = dt << Tabulate(
	Show Control Panel( 0 ),
	Add Table(
		Column Table( Statistics( Min ) ),
		Column Table( Statistics( Mean, Median ) ),
		Column Table( Statistics( Max ) ),
		Column Table( Statistics( Std Dev ) ),
		Row Table(
			Grouping Columns( :lot_id, :wafer, :Wafer ID in lot ID ),
			Analysis Columns(
				Eval( col_names )

			)
		)
	)
)) << Make Into Data Table;
dtTab = current data table();
tab << close window;

procCols = Associative Array(dtTab:Analysis Columns << get values) << get keys;
// Create a limits table
dtLimits = new table("Limits",
	new column("Variable", character),
	new column("LSL"),
	New column("Target"),
	New column("USL")
);

For Each({col}, procCols,
	specs = column(dt, col) << get property("Spec Limits");
	if(isList(specs),
		dtLimits << add rows(1);
		dtLimits:Variable[nrows(dtLimits)] = col;
		dtLimits:LSL[nrows(dtLimits)] = specs["LSL"];
		dtLimits:Target[nrows(dtLimits)] = specs["Target"];
		dtLimits:USL[nrows(dtLimits)] = specs["USL"];
	)
);

dtTab << Update(
	with( dtLimits ),
	Match Columns( :Analysis Columns = :Variable ),
	Add Columns from Update Table( :LSL, :Target, :USL)
);