765358_it-IT

liliconcom

spline- problema con la legenda e il filtro

CIAO,

quando eseguo il mio script, i colori della spline e della legenda corrispondono, ma quando clicco sul filtro, il colore della legenda cambia ma la spline rimane la stessa, creando confusione nei dati.

come impostare lo stesso colore sia sulla legenda che sulla spline indipendentemente dal filtro?

nell'edizione, quando filtro in anticipo lo spline non funziona per altri filtri, cosa posso fare?

allegato lo script pertinente.

</CODE></PRE>
<P> </P>
<PRE><CODE class=" language-jsl">Lineup Box(
	abc = Bivariate(
		Y( :total_defects ),
		X( :start_date ),
		Automatic Recalc( 1 ),
		Local Data Filter(
			Conditional,
			Add Filter(
				columns( :CU_NC, :ceid, :entity ),
				Where( :CU_NC == "NC" ),
				Where( :ceid == "TNG" ),
				Display( :entity, List Display ),

			)
		),
		SendToReport(
			Dispatch( {}, "1", ScaleBox, {Label Row( Label Orientation( "Angled" ) )} ),
			Dispatch( {}, "2", ScaleBox,
				{Min( -5 ), Max( 250 ), Inc( 7 ), Minor Ticks( 1 ),
				Add Ref Line( 30, "DashDot", "Red", "UCL", 2 ), Label Row( Show Major Grid( 1 ) )}
			),
			Dispatch( {}, "Bivar Plot", FrameBox, {Frame Size( 800, 250 )} ),
			Dispatch( {}, "Bivar Plot", FrameBox,
				{Frame Size( 800, 250 ), Row Legend(
					entity,
					Color( 1 ),
					Color Theme( "JMP Default"(1) ),
					Marker( 0 ),
					Marker Theme( "" ),
					Continuous Scale( 0 ),
					Reverse Scale( 0 ),
					Excluded Rows( 0 )
				)}
			)
 
		), 
 
	);
	abc << group by( :entity );
	abc << fit spline( 0.1, Standardized, {Line Width( 2 ), Report( 0 )} );
)

Analisi e modellazione dei dati di baseRe: problema con spline- legenda e filtro

CIAO,

Volevo dire che se rimuovo il filtro inizialmente configurato (dove) non c'è alcuna spline per altri dati.

cosa si può fare per affrontarlo?

Re: problema con spline- legenda e filtro

Penso che questo richiederà un po' di scripting usando il gestore di modifica del filtro poiché quelle linee non seguono gli stati di riga/la proprietà della colonna del colore del valore (anche se c'è un solo punto, nessuna linea verrà adattata). Non sono sicuro di cosa intendi con "non funziona per altri filtri"?

Questa potrebbe non essere un'opzione molto affidabile, a causa del funzionamento del gestore dei cambi di filtro, ma la prima idea che mi è venuta...

Names Default To Here(1); 

dt = Open("$SAMPLE_DATA/Big Class.jmp");
Column(dt, "age") << Set Property(
	"Value Colors",
	{12 = -13912408, 13 = -4042310, 14 = -4354269, 15 = -13400361, 16 = -2668175, 17 = -10628061}
);

nw = new window("",
	Lineup Box(
		biv = dt << Bivariate(
			Y(:height),
			X(:weight),
			Automatic Recalc(1),
			SendToReport(
				Dispatch({}, "1", ScaleBox, {Label Row(Label Orientation("Angled"))}),
				Dispatch(
					{},
					"2",
					ScaleBox,
					{Min(-5), Max(250), Inc(7), Minor Ticks(1), Add Ref Line(30, "DashDot", "Red", "UCL", 2),
					Label Row(Show Major Grid(1))}
				),
				Dispatch({}, "Bivar Plot", FrameBox, {Frame Size(800, 250)}),
				Dispatch(
					{},
					"Bivar Plot",
					FrameBox,
					{Frame Size(800, 250), Row Legend(
						age,
						Color(1),
						Color Theme(""),
						Marker(0),
						Marker Theme(""),
						Continuous Scale(0),
						Reverse Scale(0),
						Excluded Rows(0)
					)}
				)
			)
		);
	)
);

ldf = biv << Local Data Filter(
	Conditional,
	Add Filter(
		columns(:sex, :name, :age),
		Where(:sex == "M")
	)
);


summarize(dt, groups = by(:age)); // based on your By column

fitlines = Function({a},
	For(i = 1, i <= N Items(groups), i++,
		biv << (Curve[1] << remove fit);
	);
	biv << group by(:age);
	biv << fit spline(0.1, Standardized, {Line Width(2), Report(0)});
	wait(0);

);

ss = ldf << Make Filter Change Handler(fitlines);
fitlines(1);

Write();