723216_ja-JP

liliconcom

プロセススクリーニングやその他のオブジェクトを動的に更新する方法。

JMPコミュニティの皆さん、こんにちは。

時間を割いて前回の質問に答えていただき、ありがとうございます。以下で実行したコード (JMP pro 17.2) は、意図したとおりに動作しないようです。私の目標は、 [やり直し]ボタンを押した後、プロセス スクリーニングが「lot_id」によるグループ化から「wafer」によるグループ化に変更されることです。

PS 変数を宣言すると、すべての初期設定が保持され、グループ化変数を更新する「<<」コマンドが見つからないため、動的に更新することはできないと思います。この例に対する簡単な解決策はありますか。

Cols = {"NPN1", "PNP1", "PNP2", "NPN2"};
GR = "lot_id";
dt = Open( "$SAMPLE_DATA/Semiconductor Capability.jmp" );

PLAT = Platform(
	dt,
	PS = Process Screening(
		Y( Eval( Cols ) ),
		Grouping( Eval( GR ) ),
		Control Chart Type( "Indiv and MR" ),
		Minimum Process Length( 1 ),
		Use Medians instead of Means( 1 ),
		Show tests( 0 ),
		Test 1( 0 ),
		Cp( 1 ),
		Spec Limits( 1 ), 
	), 
);

Redo= Expr(
			GR = "wafer";
			
			NW << Close Window;
			PS << Redo Analysis;
			Make_Win();
);

Make_Win = Expr(
	NW = New Window( "ProcessScreening",
		Vlist_box = V List Box( 
		PLAT, 
		BB = Button Box( "Redo", Redo ),
		),
	),
);

Make_Win();

よろしくお願いします、

NJS。

自動化とスクリプトmacOSRe: プロセススクリーニングやその他のオブジェクトを動的に更新する方法。

これはあなたが何ができるかのアイデアを与えるかもしれません

Names Default To Here(1);

Cols = {"NPN1", "PNP1", "PNP2", "NPN2"};
GR = "lot_id";

dt = Open("$SAMPLE_DATA/Semiconductor Capability.jmp");

ps = Expr(dt << Process Screening(
	Y(Eval(Cols)),
	Grouping(Eval(GR)),
	Control Chart Type("Indiv and MR"),
	Minimum Process Length(1),
	Use Medians instead of Means(1),
	Show tests(0),
	Test 1(0),
	Cp(1),
	Spec Limits(1)
));


redo_ps = Expr(
	If(GR == "lot_id",
		GR = "wafer";
	,
		GR = "lot_id";
	);
	
	ps_collector << Delete Box();
	vlb << Append(ps_collector = V List Box(ps));
);

nw = New Window("ProcessScreening", 
	V List Box(
		vlb = V List Box(
			ps_collector = V List Box(ps)
		),
		BB = Button Box("Redo", redo_ps);
	)
);