732535_zh-TW

liliconcom

如何在 JMP JSL 中將 :column_name 替換為變數？

@jthi你能幫我修復下面的程式碼錯誤嗎？如何使用變數以正確的方式替換：列名稱？非常感謝您的幫忙。

Names Default To Here( 1 );
Open( "$SAMPLE_DATA/Big Class.jmp" );
hvar = "height";
gvar = "sex";

std = Col Std Dev( if(Excluded( Row State() ) == 0 & column(gvar) =="M", column(hvar) ));

//std = Col Std Dev( if(Excluded( Row State() ) == 0 & :sex =="M", column(hvar) ));
show(std);

自動化和腳本編寫視窗回覆：如何在 JMP JSL 中將 :column_name 替換為變數？

太感謝了。這非常有效。

回覆：如何在 JMP JSL 中將 :column_name 替換為變數？

如何替換它取決於用例，在您的情況下，使用@pmroz建議的 AsColumn 是最簡單的選擇。

連結很少

• Column() vs As Column() vs datable:column vs dt:As name("column")
• 在 JSL 中引用列
• JSL 語法參考 - 作為列
• JSL 語法參考 - Column()

以下是一些其他選項，但它們確實需要更多腳本，這在這種情況下通常是不必要的

Names Default To Here(1);

dt = Open("$SAMPLE_DATA/Big Class.jmp");

hvar = "height";
gvar = "sex";

// As Column
std = Col Std Dev(If(!Excluded(Row State()) & As Column(dt, gvar) == "M", As Column(dt, hvar)));

// Data table subscripting
// https://community.jmp.com/t5/Uncharted/Data-table-subscripting/ba-p/21013
rows_of_interest = dt << Get Rows Where(Excluded(Row State()) == 0 & Column(gvar)[] == "M");
std2 = Std Dev(dt[rows_of_interest, hvar]);

// Build and evaluate expression
// https://community.jmp.com/t5/JSL-Cookbook-Archived/Insert-one-expression-into-another-using-Eval-Insert-Eval-Expr/ta-p/48998
std3 = Eval(Substitute(
	Expr(Col Std Dev(If(!Excluded(Row State()) & groupcol == "M", numcol))),
	Expr(groupcol), Name Expr(AsColumn(gvar)),
	Expr(numcol), Name Expr(AsColumn(hvar))
));

// Check
std4 = Col Std Dev(If(Excluded(Row State()) == 0 & :sex == "M", :height));

show(std, std2, std3, std4);

回覆：如何在 JMP JSL 中用變數取代 :column_name？

Names Default To Here( 1 );
dt = Open( "$SAMPLE_DATA/Big Class.jmp" );
hvar = "height";
gvar = "sex";

std = Col Std Dev( if(!Excluded( Row State() ) & as column(dt, gvar) == "M", as column(dt, hvar) ));

//std = Col Std Dev( if(Excluded( Row State() ) == 0 & :sex =="M", column(hvar) ));
show(std);

有時您需要使用“作為列”。有時只是“列”。