JMP JSL で :column_name を変数に置き換えるにはどうすればいいですか?@jthi以下のコード エラーを修正するのを手伝ってもらえますか? 変数を使用して :column 名を正しく置き換えるにはどうすればよいでしょうか? ご協力いただき、ありがとうございます。
Names Default To Here( 1 );
Open( "$SAMPLE_DATA/Big Class.jmp" );
hvar = "height";
gvar = "sex";
std = Col Std Dev( if(Excluded( Row State() ) == 0 & column(gvar) =="M", column(hvar) ));
//std = Col Std Dev( if(Excluded( Row State() ) == 0 & :sex =="M", column(hvar) ));
show(std);
自動化とスクリプトウィンドウズRe: JMP JSL で :column_name を変数に置き換えるにはどうすればいいですか?本当にありがとうございます。とてもうまくいきました。
Re: JMP JSL で :column_name を変数に置き換えるにはどうすればいいですか?どのように置き換えるかはユースケースによって異なりますが、あなたの場合は、 @pmrozが提案したように AsColumn を使用するのが最も簡単なオプションです。
リンクが少ない
以下に他のオプションをいくつか示しますが、これらのオプションにはスクリプトの追加が必要ですが、このタイプのケースでは通常不要です。
Names Default To Here(1);
dt = Open("$SAMPLE_DATA/Big Class.jmp");
hvar = "height";
gvar = "sex";
// As Column
std = Col Std Dev(If(!Excluded(Row State()) & As Column(dt, gvar) == "M", As Column(dt, hvar)));
// Data table subscripting
// https://community.jmp.com/t5/Uncharted/Data-table-subscripting/ba-p/21013
rows_of_interest = dt << Get Rows Where(Excluded(Row State()) == 0 & Column(gvar)[] == "M");
std2 = Std Dev(dt[rows_of_interest, hvar]);
// Build and evaluate expression
// https://community.jmp.com/t5/JSL-Cookbook-Archived/Insert-one-expression-into-another-using-Eval-Insert-Eval-Expr/ta-p/48998
std3 = Eval(Substitute(
Expr(Col Std Dev(If(!Excluded(Row State()) & groupcol == "M", numcol))),
Expr(groupcol), Name Expr(AsColumn(gvar)),
Expr(numcol), Name Expr(AsColumn(hvar))
));
// Check
std4 = Col Std Dev(If(Excluded(Row State()) == 0 & :sex == "M", :height));
show(std, std2, std3, std4);
Re: JMP JSL で :column_name を変数に置き換えるにはどうすればいいですか?Names Default To Here( 1 );
dt = Open( "$SAMPLE_DATA/Big Class.jmp" );
hvar = "height";
gvar = "sex";
std = Col Std Dev( if(!Excluded( Row State() ) & as column(dt, gvar) == "M", as column(dt, hvar) ));
//std = Col Std Dev( if(Excluded( Row State() ) == 0 & :sex =="M", column(hvar) ));
show(std);
場合によっては、「as column」を使用する必要があります。場合によっては、「column」のみを使用する必要があります。
