732535_de-DE

liliconcom

Wie ersetze ich :column_name durch eine Variable in JMP JSL?

@jthi Können Sie mir helfen, den Codefehler unten zu beheben? Wie verwende ich eine Variable, um den Spaltennamen richtig zu ersetzen? Vielen Dank für Ihre Hilfe.

Names Default To Here( 1 );
Open( "$SAMPLE_DATA/Big Class.jmp" );
hvar = "height";
gvar = "sex";

std = Col Std Dev( if(Excluded( Row State() ) == 0 & column(gvar) =="M", column(hvar) ));

//std = Col Std Dev( if(Excluded( Row State() ) == 0 & :sex =="M", column(hvar) ));
show(std);

Automatisierung und SkriptingWindowsBetreff: Wie ersetze ich :column_name durch eine Variable in JMP JSL?

Vielen Dank. Das funktioniert sehr gut.

Betreff: Wie ersetze ich :column_name durch eine Variable in JMP JSL?

Wie Sie es ersetzen, hängt vom Anwendungsfall ab. In Ihrem Fall ist die Verwendung von AsColumn, wie von @pmroz vorgeschlagen, die einfachste Option.

Wenige Links

• Column() vs. As Column() vs. datierbar:Spalte vs. dt:As Name("Spalte")
• Verweisen auf eine Spalte in JSL
• JSL-Syntaxreferenz – Als Spalte
• JSL-Syntaxreferenz – Column()

Nachfolgend finden Sie einige weitere Optionen, die jedoch mehr Skripting erfordern, was in derartigen Fällen normalerweise unnötig ist.

Names Default To Here(1);

dt = Open("$SAMPLE_DATA/Big Class.jmp");

hvar = "height";
gvar = "sex";

// As Column
std = Col Std Dev(If(!Excluded(Row State()) & As Column(dt, gvar) == "M", As Column(dt, hvar)));

// Data table subscripting
// https://community.jmp.com/t5/Uncharted/Data-table-subscripting/ba-p/21013
rows_of_interest = dt << Get Rows Where(Excluded(Row State()) == 0 & Column(gvar)[] == "M");
std2 = Std Dev(dt[rows_of_interest, hvar]);

// Build and evaluate expression
// https://community.jmp.com/t5/JSL-Cookbook-Archived/Insert-one-expression-into-another-using-Eval-Insert-Eval-Expr/ta-p/48998
std3 = Eval(Substitute(
	Expr(Col Std Dev(If(!Excluded(Row State()) & groupcol == "M", numcol))),
	Expr(groupcol), Name Expr(AsColumn(gvar)),
	Expr(numcol), Name Expr(AsColumn(hvar))
));

// Check
std4 = Col Std Dev(If(Excluded(Row State()) == 0 & :sex == "M", :height));

show(std, std2, std3, std4);

Betreff: Wie ersetze ich :column_name durch eine Variable in JMP JSL?

Names Default To Here( 1 );
dt = Open( "$SAMPLE_DATA/Big Class.jmp" );
hvar = "height";
gvar = "sex";

std = Col Std Dev( if(!Excluded( Row State() ) & as column(dt, gvar) == "M", as column(dt, hvar) ));

//std = Col Std Dev( if(Excluded( Row State() ) == 0 & :sex =="M", column(hvar) ));
show(std);

Manchmal müssen Sie „als Spalte“ verwenden. Manchmal nur „Spalte“.