732535_fr-FR

liliconcom

Comment remplacer :column_name par une variable dans JMP JSL ?

@jthi Pouvez-vous m'aider à corriger l'erreur de code ci-dessous ? Comment utiliser la variable pour remplacer le nom de la colonne de manière correcte ? Merci beaucoup pour votre aide.

Names Default To Here( 1 );
Open( "$SAMPLE_DATA/Big Class.jmp" );
hvar = "height";
gvar = "sex";

std = Col Std Dev( if(Excluded( Row State() ) == 0 & column(gvar) =="M", column(hvar) ));

//std = Col Std Dev( if(Excluded( Row State() ) == 0 & :sex =="M", column(hvar) ));
show(std);

Automatisation et scriptsFenêtresRe : Comment remplacer :column_name par une variable dans JMP JSL ?

Merci beaucoup, ça marche très bien.

Re : Comment remplacer :column_name par une variable dans JMP JSL ?

La manière dont vous le remplacez dépend du cas d'utilisation, dans votre cas, utiliser AsColumn comme @pmroz l'a suggéré est l'option la plus simple.

Quelques liens

• Column() vs As Column() vs datable:column vs dt:As name("column")
• Référencer une colonne en JSL
• Référence de la syntaxe JSL - En tant que colonne
• Référence de la syntaxe JSL - Column()

Vous trouverez ci-dessous quelques autres options, mais elles nécessitent davantage de scripts, ce qui est généralement inutile dans ce type de cas.

Names Default To Here(1);

dt = Open("$SAMPLE_DATA/Big Class.jmp");

hvar = "height";
gvar = "sex";

// As Column
std = Col Std Dev(If(!Excluded(Row State()) & As Column(dt, gvar) == "M", As Column(dt, hvar)));

// Data table subscripting
// https://community.jmp.com/t5/Uncharted/Data-table-subscripting/ba-p/21013
rows_of_interest = dt << Get Rows Where(Excluded(Row State()) == 0 & Column(gvar)[] == "M");
std2 = Std Dev(dt[rows_of_interest, hvar]);

// Build and evaluate expression
// https://community.jmp.com/t5/JSL-Cookbook-Archived/Insert-one-expression-into-another-using-Eval-Insert-Eval-Expr/ta-p/48998
std3 = Eval(Substitute(
	Expr(Col Std Dev(If(!Excluded(Row State()) & groupcol == "M", numcol))),
	Expr(groupcol), Name Expr(AsColumn(gvar)),
	Expr(numcol), Name Expr(AsColumn(hvar))
));

// Check
std4 = Col Std Dev(If(Excluded(Row State()) == 0 & :sex == "M", :height));

show(std, std2, std3, std4);

Re : Comment remplacer :column_name par une variable dans JMP JSL ?

Names Default To Here( 1 );
dt = Open( "$SAMPLE_DATA/Big Class.jmp" );
hvar = "height";
gvar = "sex";

std = Col Std Dev( if(!Excluded( Row State() ) & as column(dt, gvar) == "M", as column(dt, hvar) ));

//std = Col Std Dev( if(Excluded( Row State() ) == 0 & :sex =="M", column(hvar) ));
show(std);

Parfois, vous devez utiliser « comme colonne ». Parfois, simplement « colonne ».