761351_zh-CN

liliconcom

迭代创建包含公式的列。

我想遍历具有规格限制的列并针对这些列进行分析。


	New Column("WM Minus Target", Numeric, "Continuous", Format("Best", 10), Formula(:WN - (:WN << get property("Spec Limits"))["Target"]), Set Selected);

此处的脚本接近我想要的。

已解决：当出现规格时，我想写一个失败名称，该如何编写脚本？ - JMP 用户社区

只是想知道如何获得更复杂的公式？

谢谢

扳手头

自动化和脚本回复：迭代创建包含公式的列。

根据您的分析，您可以为每个测量添加新列，或者先堆叠您的表格并创建单个新列。

为每个参数添加新列

Names Default To Here(1);

dt = Open("$SAMPLE_DATA/Semiconductor Capability.jmp");
cont_cols = dt << Get Column Names("Continuous", "String");

cols_created = {};
For Each({cont_col}, cont_cols,
	specs = Column(dt, cont_col) << Get Property("Spec Limits");
	If(Is Empty(specs), // skip columns without specs
		Continue();
	);
	cur_target = Try(specs["Target"], .); // If target isn't set -> use 0 (could for example use USL - LSL?)
	
	new_col = Eval(Substitute( // generally I use Eval(EvalExpr()) but in this case this makes expression more clear
		Expr(dt << New Column(cont_col || " Minus Target", Numeric, Continuos, Formula(
			_curcol_ - _targetval_
		))),
		Expr(_curcol_), Name Expr(AsColumn(dt, cont_col)),
		Expr(_targetval_), cur_target
	));	
	// new_col << Suppress Eval(1);
	Insert Into(cols_created, new_col << get name);
);

最后你会得到这样的列（如果你更改列属性，目标将不会更新）

堆叠

Names Default To Here(1);

dt = Open("$SAMPLE_DATA/Semiconductor Capability.jmp");
cont_cols = dt << Get Column Names("Continuous", "String");

ml = dt << Manage Limits(Process Variables(Eval(cont_cols))); // in this case this will open very annoying "help" window due to inconsistencies
dt_limits = ml << Save to Tall Limits Table;
ml << close window;

dt_stack = dt << Stack(
	columns(Eval(cont_cols)),
	Source Label Column("Measurement"),
	Stacked Data Column("Data"),
	Output Table("Data Stacked")
);

// If you don't care about LSL/USL they could be dropped from update
dt_stack << Update(
	With(dt_limits),
	Match Columns(:Measurement = :Variable),
	Replace Columns in Main Table(None)
);

dt_stack << New Column("Data Minus Target", Numeric, Continuous, Formula(
	:Data - :Target
));

两种数据格式都有其优点和缺点，这取决于您正在做什么。

编辑：

这应该从列属性中获取值，但不会重新评估（如果可以避免，我不会真正使用它）

Names Default To Here(1);

dt = Open("$SAMPLE_DATA/Semiconductor Capability.jmp");
cont_cols = dt << Get Column Names("Continuous", "String");

cols_created = {};
For Each({cont_col}, cont_cols,
	specs = Column(dt, cont_col) << Get Property("Spec Limits");
	If(Is Empty(specs), // skip columns without specs
		Continue();
	);
	
	new_col = Eval(Substitute( // generally I use Eval(EvalExpr()) but in this case this makes expression more clear
		Expr(dt << New Column(cont_col || " Minus Target", Numeric, Continuos, Formula(
			_curcol_ - (_curcol_ << Get Property("Spec Limits"))["Target"]
		))),
		Expr(_curcol_), Name Expr(AsColumn(dt, cont_col))
	));	
	//new_col << Suppress Eval(1);
	Insert Into(cols_created, new_col << get name);
);

回复：迭代创建包含公式的列。

Jim 的 Eval() 解决方案应该与如何使公式在我的示例中正确显示类似。

回复：迭代创建包含公式的列。

不使用 Eval(Evalexpr()) 不允许在执行之前完全展开公式代码。尝试下面我修改后的代码

Names Default To Here( 1 );
dt = 
// Open Data Table: semiconductor capability.jmp
// → Data Table( "semiconductor capability" )
Open( "$SAMPLE_DATA/semiconductor capability.jmp" );

colNames = dt << get column names( continuous, string );

For Each( {xcol}, colNames,
	col = xcol;
	theTarget = (Column( Eval( col ) ) << get property( "Spec Limits" ))["Target"];
	Eval(
		Eval Expr(
			New Column( col || " Minus Target",
				Numeric,
				"Continuous",
				Format( "Best", 10 ),
				Formula( As Column( Eval( col ) ) - Expr( theTarget ) )
			)
		)
	);
);

回复：迭代创建包含公式的列。

看起来很有趣，但给了我一个错误。名称未解析：theTarget 在访问或评估“theTarget”，theTarget/***###*/

回复：迭代创建包含公式的列。

代码有效，但是当我查看结果列中的公式时，它看起来像这样。

As Column( Column( i ) ) - lstTargets[j]

回复：迭代创建包含公式的列。

还有另一种方法

Names Default To Here( 1 );
dt = 
// Open Data Table: semiconductor capability.jmp
// → Data Table( "semiconductor capability" )
Open( "$SAMPLE_DATA/semiconductor capability.jmp" );

colNames = dt << get column names( continuous, string );

For each( {col}, colNames,
	Eval(
		Eval Expr(
			theTarget = (Column( Eval( col ) ) << get property( "Spec Limits" ))["Target"];
			New Column( Expr( col ) || " Minus Target",
				Numeric,
				"Continuous",
				Format( "Best", 10 ),
				Formula( As Column( Eval( col ) ) - Expr( theTarget ) )
			);
		)
	);
);

回复：迭代创建包含公式的列。

这是一种方法。使用关联数组而不是 2 个列表可能更优雅，但使用 2 个列表对我来说更容易理解：

Names Default To Here( 1 );
dt = Open( "$SAMPLE_DATA/Semiconductor Capability.jmp" );

lstCols = {};
lstTargets = {};

//get cols with targets
For Each( {i}, 1 :: N Col( dt ),
	t = .;
	Try( t = (Column( i ) << Get Property( "Spec Limits" ))["Target"], );
	If( !Is Missing( t ),
		Insert Into( lstCols, i );
		Insert Into( lstTargets, t);
	);
);

//make formulas
For Each( {i, j}, lstCols,
	//i = 5; j = 1;
	dt << New Column( char(Column Name( i )) || " Minus Target",
		Numeric,
		"Continuous",
		Format( "Best", 10 ),
		Formula( as column(Column( i )) - lstTargets[j] )
	)
);

/*JMP STATISTICAL DISCOVERY LLC (“JMP”) PERMITS THE USE OF THIS COMPUTER SOFTWARE CODE (“CODE”) ON AN AS-IS BASIS AND AUTHORIZES YOU TO USE THE CODE SUBJECT TO THE TERMS LISTED HEREIN.  BY USING THE CODE, YOU AGREE TO THESE TERMS.  YOUR USE OF THE CODE IS AT YOUR OWN RISK.  JMP MAKES NO REPRESENTATION OR WARRANTY, EXPRESS OR IMPLIED, INCLUDING BUT NOT LIMITED TO, WARRANTIES OF MERCHANTABILITY, FITNESS FOR A PARTICULAR PURPOSE, NONINFRIGEMENT, AND TITLE, WITH RESPECT TO THE CODE.
You may use the Code solely as part of a software product you currently have licensed from JMP, JMP’s parent company SAS Institute Inc. (“SAS”), or one of JMP’s or SAS’s subsidiaries or authorized agents (the “Software”), and not for any other purpose.  The Code is designed to add functionality to the Software but has not necessarily been tested.  Accordingly, JMP makes no representation or warranty that the Code will operate error-free.  JMP is under no obligation to maintain, support, or continue to distribute the Code.
Neither JMP nor its licensors shall be liable to you or any third-party for any general, special, direct, indirect, consequential, incidental, or other damages whatsoever arising out of or related to your use or inability to use the Code, even if JMP has been advised of the possibility of such damages.  Except as otherwise provided above, the Code is governed by the same agreement that governs the Software.  If you do not have an existing agreement with JMP or SAS governing the Software, you may not use the Code.
JMP and all other JMP Statistical Discovery LLC product or service names are registered trademarks or trademarks of JMP Statistical Discovery LLC in the USA and other countries.  ® indicates USA registration.  Other brand and product names are registered trademarks or trademarks of their respective companies.
*/