Creare in modo iterativo colonne contenenti formule.Vorrei scorrere le colonne che hanno limiti di specifiche ed eseguire analisi su di esse.
New Column("WM Minus Target", Numeric, "Continuous", Format("Best", 10), Formula(:WN - (:WN << get property("Spec Limits"))["Target"]), Set Selected);Lo script che si trova qui è molto simile a quello che voglio.
Risolto: Quando una specifica è attiva, come faccio a scrivere uno script quando voglio scrivere un nome di errore? - JMP User Community
Mi chiedevo come ottenere la formula più complessa?
Grazie
Testa della chiave inglese
Automazione e scriptingRe: Creare in modo iterativo colonne contenenti formule.A seconda dell'analisi, è possibile aggiungere una nuova colonna per ogni misurazione oppure sovrapporre prima la tabella e creare una nuova colonna singola.
Aggiunta di nuove colonne per ogni parametro
Names Default To Here(1);
dt = Open("$SAMPLE_DATA/Semiconductor Capability.jmp");
cont_cols = dt << Get Column Names("Continuous", "String");
cols_created = {};
For Each({cont_col}, cont_cols,
specs = Column(dt, cont_col) << Get Property("Spec Limits");
If(Is Empty(specs), // skip columns without specs
Continue();
);
cur_target = Try(specs["Target"], .); // If target isn't set -> use 0 (could for example use USL - LSL?)
new_col = Eval(Substitute( // generally I use Eval(EvalExpr()) but in this case this makes expression more clear
Expr(dt << New Column(cont_col || " Minus Target", Numeric, Continuos, Formula(
_curcol_ - _targetval_
))),
Expr(_curcol_), Name Expr(AsColumn(dt, cont_col)),
Expr(_targetval_), cur_target
));
// new_col << Suppress Eval(1);
Insert Into(cols_created, new_col << get name);
);
e ti ritrovi con colonne come questa (il target non verrà aggiornato SE modifichi la proprietà della colonna)
Accatastamento
Names Default To Here(1);
dt = Open("$SAMPLE_DATA/Semiconductor Capability.jmp");
cont_cols = dt << Get Column Names("Continuous", "String");
ml = dt << Manage Limits(Process Variables(Eval(cont_cols))); // in this case this will open very annoying "help" window due to inconsistencies
dt_limits = ml << Save to Tall Limits Table;
ml << close window;
dt_stack = dt << Stack(
columns(Eval(cont_cols)),
Source Label Column("Measurement"),
Stacked Data Column("Data"),
Output Table("Data Stacked")
);
// If you don't care about LSL/USL they could be dropped from update
dt_stack << Update(
With(dt_limits),
Match Columns(:Measurement = :Variable),
Replace Columns in Main Table(None)
);
dt_stack << New Column("Data Minus Target", Numeric, Continuous, Formula(
:Data - :Target
));
Entrambi i formati di dati hanno i loro pro e contro, che dipendono dall'uso che se ne fa.
Modificare:
Questo dovrebbe ottenere i valori dalla proprietà della colonna MA non verrà rivalutato (non lo userei davvero se puoi evitarlo)
Names Default To Here(1);
dt = Open("$SAMPLE_DATA/Semiconductor Capability.jmp");
cont_cols = dt << Get Column Names("Continuous", "String");
cols_created = {};
For Each({cont_col}, cont_cols,
specs = Column(dt, cont_col) << Get Property("Spec Limits");
If(Is Empty(specs), // skip columns without specs
Continue();
);
new_col = Eval(Substitute( // generally I use Eval(EvalExpr()) but in this case this makes expression more clear
Expr(dt << New Column(cont_col || " Minus Target", Numeric, Continuos, Formula(
_curcol_ - (_curcol_ << Get Property("Spec Limits"))["Target"]
))),
Expr(_curcol_), Name Expr(AsColumn(dt, cont_col))
));
//new_col << Suppress Eval(1);
Insert Into(cols_created, new_col << get name);
);
Re: Creare in modo iterativo colonne contenenti formule.Anche la soluzione Eval() di Jim dovrebbe essere simile a quella che ho usato per far sì che la formula venisse visualizzata correttamente nel mio esempio.
Re: Creare in modo iterativo colonne contenenti formule.Non usare Eval(Evalexpr()) non consente l'espansione completa del codice della formula prima dell'esecuzione. Prova il mio codice modificato qui sotto
Names Default To Here( 1 );
dt =
// Open Data Table: semiconductor capability.jmp
// → Data Table( "semiconductor capability" )
Open( "$SAMPLE_DATA/semiconductor capability.jmp" );
colNames = dt << get column names( continuous, string );
For Each( {xcol}, colNames,
col = xcol;
theTarget = (Column( Eval( col ) ) << get property( "Spec Limits" ))["Target"];
Eval(
Eval Expr(
New Column( col || " Minus Target",
Numeric,
"Continuous",
Format( "Best", 10 ),
Formula( As Column( Eval( col ) ) - Expr( theTarget ) )
)
)
);
);Re: Creare in modo iterativo colonne contenenti formule.Sembra interessante, mi dà un errore però. Nome non risolto: theTarget in accesso o valutazione di 'theTarget', theTarget/*###*/
Re: Creare in modo iterativo colonne contenenti formule.Il codice funziona, ma quando guardo la formula nella colonna risultante, appare così.
As Column( Column( i ) ) - lstTargets[j]
Re: Creare in modo iterativo colonne contenenti formule.Ed ecco un altro modo
Names Default To Here( 1 );
dt =
// Open Data Table: semiconductor capability.jmp
// → Data Table( "semiconductor capability" )
Open( "$SAMPLE_DATA/semiconductor capability.jmp" );
colNames = dt << get column names( continuous, string );
For each( {col}, colNames,
Eval(
Eval Expr(
theTarget = (Column( Eval( col ) ) << get property( "Spec Limits" ))["Target"];
New Column( Expr( col ) || " Minus Target",
Numeric,
"Continuous",
Format( "Best", 10 ),
Formula( As Column( Eval( col ) ) - Expr( theTarget ) )
);
)
);
);Re: Creare in modo iterativo colonne contenenti formule.Ecco un modo. Potrebbe essere più elegante con un array associativo invece di 2 liste, ma usare 2 liste è più facile per me da capire:
Names Default To Here( 1 );
dt = Open( "$SAMPLE_DATA/Semiconductor Capability.jmp" );
lstCols = {};
lstTargets = {};
//get cols with targets
For Each( {i}, 1 :: N Col( dt ),
t = .;
Try( t = (Column( i ) << Get Property( "Spec Limits" ))["Target"], );
If( !Is Missing( t ),
Insert Into( lstCols, i );
Insert Into( lstTargets, t);
);
);
//make formulas
For Each( {i, j}, lstCols,
//i = 5; j = 1;
dt << New Column( char(Column Name( i )) || " Minus Target",
Numeric,
"Continuous",
Format( "Best", 10 ),
Formula( as column(Column( i )) - lstTargets[j] )
)
);
/*JMP STATISTICAL DISCOVERY LLC (“JMP”) PERMITS THE USE OF THIS COMPUTER SOFTWARE CODE (“CODE”) ON AN AS-IS BASIS AND AUTHORIZES YOU TO USE THE CODE SUBJECT TO THE TERMS LISTED HEREIN. BY USING THE CODE, YOU AGREE TO THESE TERMS. YOUR USE OF THE CODE IS AT YOUR OWN RISK. JMP MAKES NO REPRESENTATION OR WARRANTY, EXPRESS OR IMPLIED, INCLUDING BUT NOT LIMITED TO, WARRANTIES OF MERCHANTABILITY, FITNESS FOR A PARTICULAR PURPOSE, NONINFRIGEMENT, AND TITLE, WITH RESPECT TO THE CODE.
You may use the Code solely as part of a software product you currently have licensed from JMP, JMP’s parent company SAS Institute Inc. (“SAS”), or one of JMP’s or SAS’s subsidiaries or authorized agents (the “Software”), and not for any other purpose. The Code is designed to add functionality to the Software but has not necessarily been tested. Accordingly, JMP makes no representation or warranty that the Code will operate error-free. JMP is under no obligation to maintain, support, or continue to distribute the Code.
Neither JMP nor its licensors shall be liable to you or any third-party for any general, special, direct, indirect, consequential, incidental, or other damages whatsoever arising out of or related to your use or inability to use the Code, even if JMP has been advised of the possibility of such damages. Except as otherwise provided above, the Code is governed by the same agreement that governs the Software. If you do not have an existing agreement with JMP or SAS governing the Software, you may not use the Code.
JMP and all other JMP Statistical Discovery LLC product or service names are registered trademarks or trademarks of JMP Statistical Discovery LLC in the USA and other countries. ® indicates USA registration. Other brand and product names are registered trademarks or trademarks of their respective companies.
*/
