668802_de-DE

liliconcom

So wähle ich meine Hauptdatentabelle aus

Hallo,

Ich arbeite also an einer Datentabelle und habe ein Skript geschrieben, um mehrere Teilmengen davon zu erstellen. Ich gehe durch eine For-Schleife, um einige Modellanalysen zu automatisieren. Die erste Iteration läuft gut: Erstelle die Teilmenge, starte ein passendes Modell in der Teilmenge.

Aber dann, in der zweiten Iteration der Schleife, funktioniert es nicht mehr, weil die ausgewählte Tabelle die Teilmenge und nicht die Haupttabelle ist. Ich kann nicht die richtigen Befehle finden, um die aktuelle Datentabelle meiner Originaltabelle zuzuordnen. Irgendwelche Ideen?

Automatisierung und SkriptingBetreff: Wie wähle ich meine Hauptdatentabelle aus?

Sie müssen entweder eine Variable zuweisen, die auf die Haupttabelle verweist, oder sie über ihren Namen referenzieren.

Names Default To Here( 1 );
dt = 
// Open Data Table: big class.jmp
// → Data Table( "big class" )
Open( "/C:/Program Files/SAS/JMPPRO/16/Samples/Data/big class.jmp" );

ages = Associative Array( dt:age ) << get keys;

For Each( {year}, ages, 

	dt << select where( :sex == "F" & :age == year );
	dt << Subset(
		Selected Rows( 1 ),
		,
		Selected columns only( 0 )
	);
);

Oder

Names Default To Here( 1 );
// Open Data Table: big class.jmp
// → Data Table( "big class" )
Open( "/C:/Program Files/SAS/JMPPRO/16/Samples/Data/big class.jmp" );

ages = Associative Array( data table("big class"):age ) << get keys;

For Each( {year}, ages, 

	Data Table( "big class" ) << select where( :sex == "F" & :age == year );
	Data Table( "big class" ) << Subset(
		Selected Rows( 1 ),
		,
		Selected columns only( 0 )
	);
);

Betreff: Wie wähle ich meine Hauptdatentabelle aus?

Verweisen Sie auf Ihre Datentabellen mit Namen oder arbeiten Sie mit der aktuellen Datentabelle? Mit anderen Worten, sieht Ihr Skript so aus:

dt = Open( "data table.jmp" );

dt2 = dt << Subset( ... );
dt2 << Fit Model( ... );

dt << subset( ... );

oder so?

Open( "data table.jmp" );

Subset( ... );
Fit Model( ... );

subset( ... );

oder vielleicht etwas ganz anderes?