749264_ja-JP

liliconcom

列内の色付きセルの行番号を取得し、新しく作成された列にタグ (たとえば「1」) を割り当てるにはどうすればよいでしょうか。

測定データ内の仕様違反を色分けするために、Color Out of Spec Values() を使用しました。測定データを含む列が複数あり、各列の仕様外の値は、各パラメーター列の仕様に従って色分けされます。

各パラメータ列に対して、セルが色付きの場合は「1」、そうでない場合は「0」を割り当てる隣接列を作成します。

JSL 経由でこれを実現するにはどうすればよいでしょうか?

自動化とスクリプトウィンドウズRe: 列内の色付きセルの行番号を取得し、新しく作成された列にタグ (たとえば「1」) を割り当てるにはどうすればよいでしょうか?

わあ、素晴らしいアイデアですね - コラムのスクリプト経由です!

JMP の素晴らしい点:
回避策:)

JMP のあまりクールではない点:
回避策のための回避策。

色を経由せずに仕様外の値を直接取得するには、投票してください: :folded_hands: 仕様内 (値)

Re: 列内の色付きセルの行番号を取得し、新しく作成された列にタグ (たとえば「1」) を割り当てるにはどうすればよいでしょうか?

Forループを使用せず、<<選択した列を移動を使用して、指定した列の後に列を移動します。

もっと見る...

Names Default To Here(1);

get_colored_cells = Function({dt, colname}, {Default Local},
	colscript = Column(dt, colname) << Get Script;
	l = Substitute(Name Expr(colscript), Expr(New Column()), List());
	colored_cells = {};
	Try(
		colors = l["Color Cells"];
		If(Type(colors[1]) == "List",
			jmptrickery = 1,
			jmptrickery = 0
		);
		For Each({color}, colors,
			If(jmptrickery,
				Insert Into(colored_cells, color[2]),
				Insert Into(colored_cells, color)
			)
		);
	);
	Return(Matrix(colored_cells));
);

create_failed_column_after = function({dt, colname}, {Default Local},
	curname = Column(dt, colname) << get name;

	failed_rows = get_colored_cells(dt, colname);
	row_vals = J(1, N Rows(dt), 0);
	row_vals[failed_rows] = 1;
	
	new_col = dt << New Column((curname || "_FAIL"), Numeric, Nominal, Values(row_vals));	
	dt << Move Selected Columns(new_col, After(Column(dt, colname)));
	
	return(new_col);
);


dt = Open("$SAMPLE_DATA/Semiconductor Capability.jmp");
col_names = dt << Get Column Group("Processes");

dt << show window(0);
wait(0);

ps = dt << Process Screening(
	Process Variables(Eval(col_names)),
	Spec Limits Dialog("No (skip columns with no spec limits)")
);
ps << Color Out Of Spec Values(1);
ps << Close Window;
dt << Clear Select << Clear Column Selection;


For Each({colref}, col_names,
	colname = colref << get name;
	create_failed_column_after(dt, colname);
);


dt << show window(1);
wait(0);

Re: 列内の色付きセルの行番号を取得し、新しく作成された列にタグ (たとえば「1」) を割り当てるにはどうすればよいでしょうか?

@jthiありがとうございます。あなたのスクリプトを、私のものとよく一致するデータセットで使用するように調整しました。1 つの列名の場合は正常に動作しますが、列名をループすると動作しません。また、ループ内で操作が実行される列の横 (右側) に、新しく作成された各列を配置するにはどうすればよいでしょうか。

Names Default To Here( 1 );
Clear Log();

dt = Open( "$SAMPLE_DATA/Semiconductor Capability.jmp" );

col_names = dt << Get Column Group( "Processes" );

ps = dt << Process Screening(
	Process Variables( Eval( col_names ) ),
	Spec Limits Dialog( "No (skip columns with no spec limits)" ),
);

ps << Color Out Of Spec Values (1);

t = ps << Get Window Title; //Show( t );
ps << Close Window;
dt << Clear Select << Clear Column Selection;

get_colored_cells = Function({dt, colname}, {Default Local},
	colscript = Column(dt, colname) << Get Script;
	l = Substitute(Name Expr(colscript), Expr(New Column()), List());
	colored_cells = {};
	Try(
		colors = l["Color Cells"];
		If(Type(colors[1]) == "List",
			jmptrickery = 1;
		,
			jmptrickery = 0;
		);
		For Each({color}, colors,
			If(jmptrickery,
				Insert Into(colored_cells, color[2]);
			,
				Insert Into(colored_cells, color);
			);
		);
	);
	return(Matrix(colored_cells));
);

measColNames = dt << get column names(Numeric,Continuous ); show (measColNames[1]);

For( i = 1, i <= N Items( measColNames), i++,
	rows = J( 1, N Rows( dt ), 0 );
	colored_rows = get_colored_cells( dt, measColNames[i]);
	rows[colored_rows] = 1;
	dt << New Column( "PassFail"||measColNames[i], Numeric, Nominal, Values( rows ) );
);


//colname = "NPN1";
///// for single column
/*rows = J(1, N Rows(dt), 0);
colored_rows = get_colored_cells(dt, colname);
rows[colored_rows] = 1;
dt << New Column("result", Numeric, Nominal, Values(rows));*/

Re: 列内の色付きセルの行番号を取得し、新しく作成された列にタグ (たとえば「1」) を割り当てるにはどうすればよいでしょうか?

これは、1つの列の状況をどのように処理できるかを示しています

Names Default To Here(1);
dt = Open("$SAMPLE_DATA/Big Class.jmp");
a = {1, 3, 5};
b = {2, 4, 6};
c = {7, 8, 9};

:height << color cells({{"Red", a}, {"blue", b}, {"yellow", c}});
:weight << color cells({{"Red", a}});
:age << color cells({{"Red", a}, {"blue", b}});


get_colored_cells = Function({dt, colname}, {Default Local},
	colscript = Column(dt, colname) << Get Script;
	l = Substitute(Name Expr(colscript), Expr(New Column()), List());
	colored_cells = {};
	Try(
		colors = l["Color Cells"];
		If(Type(colors[1]) == "List",
			jmptrickery = 1;
		,
			jmptrickery = 0;
		);
		For Each({color}, colors,
			If(jmptrickery,
				Insert Into(colored_cells, color[2]);
			,
				Insert Into(colored_cells, color);
			);
		);
	);
	return(Matrix(colored_cells));
);

colname = "age";
// for single column
rows = J(1, N Rows(dt), 0);
colored_rows = get_colored_cells(dt, colname);
rows[colored_rows] = 1;
dt << New Column("result", Numeric, Nominal, Values(rows));

追加の列を作成して、ループするときに各列に色を付けることができます。