785508_zh-TW

liliconcom

列字元匹配公式

大家好，

我有一個包含 2 列的資料集，我只是想檢查第 1 列中的資料是否與第 2 列匹配，它不必逐行匹配。我感興趣的只是檢查我們是否有相同的觀察結果，如果不關心的話，它們在兩列中的順序。

有人可以幫我提供一個用於檢查這個的公式嗎？

感謝

肖恩

基礎資料分析與建模內容組織回覆：列字元匹配公式

這是執行此操作的一種方法的範例

Names Default To Here( 1 );
dt = New Table( "Example",
	add rows( 100 ),
	New Column( "c1", set each value( Random Integer( 1, 1000 ) ) ),
	New Column( "c2", set each value( Random Integer( 1, 1000 ) ) )
);

dt << New Column( "Is in Both",
	formula(
		As Constant( c1Matrix = :c1 << get values );
		If( Length( Loc( c1Matrix, :c2 ) ) > 0,
			1,
			0
		);
	)
);

回覆：列字元匹配公式

如果您的第 1 列和第 2 列中沒有小數，您也可以使用關聯數組來比較結果

Names Default To Here(1);

dt = New Table("Untitled",
	Add Rows(3),
	Compress File When Saved(1),
	New Column("Column 1", Character, "Nominal", Set Values({"A", "B", "C"})),
	New Column("Column 2", Character, "Nominal", Set Values({"AA", "B", "C"}))
);


dt << New Column("Diff", Numeric, Nominal, Formula(
	As Constant(
		aa1 = Associative Array(:Column 1);
		aa2 = Associative Array(:Column 2);
		aa1 << Remove(aa2);
		N Items(aa1) > 0;
	);
));