723027_es-ES

liliconcom

Variación de los límites de especificación por categoría de datos en el gráfico de variabilidad

Hola,

Tengo una aplicación en la que utilizo un gráfico de variabilidad en JMP Pro 14 para representar datos recopilados en intervalos discretos durante un período de tiempo. En función de esta recopilación de datos, también será necesario modificar los límites de especificación de los datos. Por ejemplo:

Durante la "Fase K " de un proyecto, puede haber M grupos de muestra diferentes, cada uno con su propio tamaño de muestra N. Durante la Fase K , habrá un conjunto de límites que desearemos representar gráficamente en relación con esto.

En algún momento, el proyecto entrará en la “Fase K+1 ”, durante la cual ajustaremos los límites de las especificaciones y recopilaremos datos adicionales que deberán compararse con los nuevos límites.

Repetir hasta la saciedad...

¿Existe alguna manera de codificar límites de especificación en una columna numérica continua que estén controlados por una columna separada en la que se codifique la fase del proyecto de modo que cuando trace los datos en la Y de un gráfico de variabilidad, el gráfico incluya los límites de especificación apropiados en el gráfico de variabilidad para cada uno de los grupos de muestra? No tengo ningún problema con hacer algo tan básico como crear columnas LSL/Target/USL directamente en la tabla, pero, por supuesto, eso no es lo mejor.

Por cierto, soy consciente de que los gráficos de variabilidad pueden no ser la forma "correcta" de representar estos datos, pero es lo que se hace, así que aquí estamos.:)

¡Gracias!

Conceptualizado en base a la tabla jmp adjunta:

Exploración y visualización de datosCompartir y comunicar resultadosRe: Variación de los límites de especificación según la categoría de datos en el gráfico de variabilidad

Sé que "quieres" usar un gráfico de variabilidad, pero el generador de gráficos suele ser (al menos en la versión más nueva de JMP) más fácil para gráficos como este.

Ver más...

Names Default To Here(1);

dt = Open("$DOWNLOADS/variable_spec_limits_sample.jmp");

gb = dt << Graph Builder(
	Size(808, 557),
	Show Control Panel(0),
	Variables(
		X(:Phase),
		X(:SampleGroup, Position(1)),
		Y(:Data),
		Y(:LSL, Position(1)),
		Y(:Target, Position(1)),
		Y(:USL, Position(1))
	),
	Elements(
		Points(X(1), X(2), Y(1), Legend(6)),
		Box Plot(X(1), X(2), Y(1), Legend(7), Outliers(0), Width Proportion(0.1)),
		Bar(X(1), Y(2), Y(3), Y(4), Legend(9), Bar Style("Float"))
	),
	SendToReport(
		Dispatch(
			{},
			"Phase",
			ScaleBox,
			{Label Row(1, Lower Frame(1)), Label Row(
				2,
				{Lower Frame(1), Major Grid Line Color("Black"), Show Major Grid(1)}
			)}
		),
		Dispatch(
			{},
			"Data",
			ScaleBox,
			{Min(3.08101), Max(4.54538984217895), Inc(0.2), Minor Ticks(1),
			Label Row({Show Major Grid(1), Show Minor Grid(1)})}
		),
		Dispatch(
			{},
			"400",
			ScaleBox,
			{Legend Model(
				9,
				Properties(
					0,
					{Line Color(3), Line Width(1)},
					Item ID("Mean(LSL)", 1)
				),
				Properties(
					1,
					{Line Color(3), Line Style("Dotted"), Line Width(1)},
					Item ID("Mean(Target)", 1)
				),
				Properties(
					2,
					{Line Color(3), Line Width(1)},
					Item ID("Mean(USL)", 1)
				)
			)}
		),
		Dispatch(
			{},
			"Graph Builder",
			FrameBox,
			{DispatchSeg(
				Box Plot Seg("Box Plot (Phase 1>>AF145)"),
				{Fill Color("Black"), Fill(0)}
			), DispatchSeg(
				Box Plot Seg("Box Plot (Phase 1>>PT334)"),
				{Fill Color("Black"), Fill(0)}
			), DispatchSeg(
				Box Plot Seg("Box Plot (Phase 2>>ZF010)"),
				{Fill Color("Black"), Fill(0)}
			), DispatchSeg(BarSeg(1), {Set Width Proportion(1)})}
		)
	)
);

Re: Variación de los límites de especificación según la categoría de datos en el gráfico de variabilidad

Usar un script gráfico y agregar líneas entre cada "grupo" es una opción, pero requiere algo de programación.

No estoy seguro de si esto funcionará en JMP14

Names Default To Here(1);

dt = Open("$DOWNLOADS/variable_spec_limits_sample.jmp");

var = dt << Variability Chart(Y(:Data), X(:Phase, :SampleGroup));

dt_summary = dt << Summary(
	Group(:Phase),
	Max(:LSL),
	Mean(:Target),
	Min(:USL),
	N Categories(:SampleGroup),
	Freq("None"),
	Weight("None"),
	statistics column name format("column"),
	Link to original data table(0)
);
dt_summary << Delete Columns("N Rows");

// We need access to the framebox
fb = Report(var)[Outline Box("Variability Chart for Data"), Frame Box(1)];

// Using graphic scripts most likely easiest option
xidx = 0;
For(i = 1, i <= N Items(phases), i++,
	curphase = dt_summary[i, "Phase"];
	curlsl = dt_summary[i, "LSL"];
	curusl = dt_summary[i, "USL"];
	curtarget = dt_summary[i, "Target"];
	curcount = dt_summary[i, "SampleGroup"];
	
	xend = xidx + curcount;
	
	lslstart = Eval List({xidx, curlsl});
	lslend = Eval List({xend, curlsl});

	uslstart = Eval List({xidx, curusl});
	uslend = Eval List({xend, curusl});

	targetstart = Eval List({xidx, curtarget});
	targetend = Eval List({xend, curtarget});
	
	xidx = xend;
	
	Eval(EvalExpr(
			fb << Add Graphics Script(
			Pen Color("Red");
			Pen Size(1);
			Line(Expr(lslstart), Expr(lslend)); // {x1, y1}, {x2, y2}
			Line(Expr(uslstart), Expr(uslend)); // {x1, y1}, {x2, y2}
			Pen Color("Blue");
			Line(Expr(targetstart), Expr(targetend)); // {x1, y1}, {x2, y2}
		);
	));
);


// You might also want to have some sort of scaling to Y-axis
// ((fb << parent) << Prev Sib)[AxisBox(1)] << Min(Min(dt_summary[0, "LSL"])) << Max(Max(dt_summary[0, "USL"]));

Y es posible que no haya una opción de estilo para la línea (o más bien, ¿Bolígrafo?), por lo que es posible que tengas que cambiarle el color.