723027_de-DE

liliconcom

Unterschiedliche Spezifikationsgrenzen nach Datenkategorie im Variabilitätsdiagramm

Hallo,

Ich habe eine Anwendung, bei der ich ein Variabilitätsdiagramm in JMP Pro 14 verwende, um Daten darzustellen, die in diskreten Intervallen über einen bestimmten Zeitraum erfasst wurden. Basierend auf dieser Datenerfassung müssen auch die Spezifikationsgrenzen der Daten variiert werden. Beispiel:

Während der „Phase K “ eines Projekts kann es M verschiedene Stichprobengruppen geben, jede mit ihrer eigenen Stichprobengröße N. Während der Phase K gibt es eine Reihe von Grenzwerten, die wir dagegen aufzeichnen möchten.

Irgendwann wird das Projekt in die „Phase K+1 “ eintreten, in der wir die Spezifikationsgrenzen anpassen und zusätzliche Daten sammeln, die mit den neuen Grenzen verglichen werden müssen.

Wiederholen Sie dies bis zum Erbrechen …

Gibt es eine Möglichkeit, Spezifikationsgrenzen in eine kontinuierliche numerische Spalte zu codieren, die von einer separaten Spalte gesteuert wird, in der die Projektphase so codiert ist, dass, wenn ich die Daten im Y eines Variabilitätsdiagramms aufzeichne, das Diagramm die entsprechenden Spezifikationsgrenzen im Variabilitätsdiagramm für jede der Beispielgruppen enthält? Ich habe kein Problem damit, etwas so Einfaches wie das Erstellen von LSL/Ziel/USL-Spalten direkt in der Tabelle zu tun, aber das ist natürlich nicht vorzuziehen.

Übrigens bin ich mir bewusst, dass Variabilitätsdiagramme möglicherweise nicht die „richtige“ Art sind, diese Daten darzustellen, aber es ist das, was getan wird, also sind wir hier:)

Danke!

Konzeptualisiert basierend auf der beigefügten JMP-Tabelle:

Datenexploration und -visualisierungErgebnisse teilen und kommunizierenBetreff: Unterschiedliche Spezifikationsgrenzen nach Datenkategorie im Variabilitätsdiagramm

Ich weiß, dass Sie ein Variabilitätsdiagramm verwenden möchten, aber der Graph Builder ist normalerweise (zumindest in der neueren Version von JMP) für Diagramme wie dieses einfacher

Mehr anzeigen...

Names Default To Here(1);

dt = Open("$DOWNLOADS/variable_spec_limits_sample.jmp");

gb = dt << Graph Builder(
	Size(808, 557),
	Show Control Panel(0),
	Variables(
		X(:Phase),
		X(:SampleGroup, Position(1)),
		Y(:Data),
		Y(:LSL, Position(1)),
		Y(:Target, Position(1)),
		Y(:USL, Position(1))
	),
	Elements(
		Points(X(1), X(2), Y(1), Legend(6)),
		Box Plot(X(1), X(2), Y(1), Legend(7), Outliers(0), Width Proportion(0.1)),
		Bar(X(1), Y(2), Y(3), Y(4), Legend(9), Bar Style("Float"))
	),
	SendToReport(
		Dispatch(
			{},
			"Phase",
			ScaleBox,
			{Label Row(1, Lower Frame(1)), Label Row(
				2,
				{Lower Frame(1), Major Grid Line Color("Black"), Show Major Grid(1)}
			)}
		),
		Dispatch(
			{},
			"Data",
			ScaleBox,
			{Min(3.08101), Max(4.54538984217895), Inc(0.2), Minor Ticks(1),
			Label Row({Show Major Grid(1), Show Minor Grid(1)})}
		),
		Dispatch(
			{},
			"400",
			ScaleBox,
			{Legend Model(
				9,
				Properties(
					0,
					{Line Color(3), Line Width(1)},
					Item ID("Mean(LSL)", 1)
				),
				Properties(
					1,
					{Line Color(3), Line Style("Dotted"), Line Width(1)},
					Item ID("Mean(Target)", 1)
				),
				Properties(
					2,
					{Line Color(3), Line Width(1)},
					Item ID("Mean(USL)", 1)
				)
			)}
		),
		Dispatch(
			{},
			"Graph Builder",
			FrameBox,
			{DispatchSeg(
				Box Plot Seg("Box Plot (Phase 1>>AF145)"),
				{Fill Color("Black"), Fill(0)}
			), DispatchSeg(
				Box Plot Seg("Box Plot (Phase 1>>PT334)"),
				{Fill Color("Black"), Fill(0)}
			), DispatchSeg(
				Box Plot Seg("Box Plot (Phase 2>>ZF010)"),
				{Fill Color("Black"), Fill(0)}
			), DispatchSeg(BarSeg(1), {Set Width Proportion(1)})}
		)
	)
);

Betreff: Unterschiedliche Spezifikationsgrenzen nach Datenkategorie im Variabilitätsdiagramm

Eine Möglichkeit besteht darin, ein Grafikskript zu verwenden und zwischen den einzelnen „Gruppen“ Zeilen einzufügen. Hierzu sind jedoch einige Skripts erforderlich.

Ich bin nicht sicher, ob das auf JMP14 funktioniert

Names Default To Here(1);

dt = Open("$DOWNLOADS/variable_spec_limits_sample.jmp");

var = dt << Variability Chart(Y(:Data), X(:Phase, :SampleGroup));

dt_summary = dt << Summary(
	Group(:Phase),
	Max(:LSL),
	Mean(:Target),
	Min(:USL),
	N Categories(:SampleGroup),
	Freq("None"),
	Weight("None"),
	statistics column name format("column"),
	Link to original data table(0)
);
dt_summary << Delete Columns("N Rows");

// We need access to the framebox
fb = Report(var)[Outline Box("Variability Chart for Data"), Frame Box(1)];

// Using graphic scripts most likely easiest option
xidx = 0;
For(i = 1, i <= N Items(phases), i++,
	curphase = dt_summary[i, "Phase"];
	curlsl = dt_summary[i, "LSL"];
	curusl = dt_summary[i, "USL"];
	curtarget = dt_summary[i, "Target"];
	curcount = dt_summary[i, "SampleGroup"];
	
	xend = xidx + curcount;
	
	lslstart = Eval List({xidx, curlsl});
	lslend = Eval List({xend, curlsl});

	uslstart = Eval List({xidx, curusl});
	uslend = Eval List({xend, curusl});

	targetstart = Eval List({xidx, curtarget});
	targetend = Eval List({xend, curtarget});
	
	xidx = xend;
	
	Eval(EvalExpr(
			fb << Add Graphics Script(
			Pen Color("Red");
			Pen Size(1);
			Line(Expr(lslstart), Expr(lslend)); // {x1, y1}, {x2, y2}
			Line(Expr(uslstart), Expr(uslend)); // {x1, y1}, {x2, y2}
			Pen Color("Blue");
			Line(Expr(targetstart), Expr(targetend)); // {x1, y1}, {x2, y2}
		);
	));
);


// You might also want to have some sort of scaling to Y-axis
// ((fb << parent) << Prev Sib)[AxisBox(1)] << Min(Min(dt_summary[0, "LSL"])) << Max(Max(dt_summary[0, "USL"]));

Und es gibt möglicherweise keine Stiloption für die Linie (oder eher den Stift?), sodass Sie möglicherweise die Farbe dafür ändern müssen