¿Cómo cuento el número de filas que no están en blanco en filas específicas?Tengo la tabla que se muestra aquí y me gustaría crear una nueva columna que contenga "N", que es la cantidad de columnas que tienen números, pero solo para las columnas etiquetadas como "DecodeCount_BW**". Por ejemplo, para la primera fila, debería devolver "5", para la segunda fila debería devolver "2", etc.
En Excel hago esto con "counta", pero estoy tratando de aprender JMP para mejorar el análisis estadístico, pero me he quedado estancado en cosas simples como esta, tal vez debido a mi cerebro con formato Excel... Lo siento si esto es súper básico, pero no puedo encontrar una fórmula en la lista de fórmulas que haga esto.
Gracias
Usuario JMP17
Organización de contenidoCombinación y limpieza de datosRe: ¿Cómo cuento la cantidad de filas que no están en blanco en filas específicas?En general, las fórmulas no funcionan en esta dirección con tanta facilidad (calcular algo por fila en lugar de por columna). Según lo que esté haciendo, apilar los datos primero puede resultar beneficioso.
Puedes usar una fórmula para eso (puede que sea un poco complicado), pero por lo general yo usaría un script. A continuación se muestra un ejemplo.
Names Default To Here(1);
dt = New Table("Untitled 3",
Add Rows(3),
Compress File When Saved(1),
New Column("Column 1", Numeric, "Continuous", Format("Best", 12), Set Values([., ., .])),
New Column("Column 2", Numeric, "Continuous", Format("Best", 12), Set Values([., ., .])),
New Column("AB1", Numeric, "Continuous", Format("Best", 12), Set Values([2, ., .])),
New Column("AB2", Numeric, "Continuous", Format("Best", 12), Set Values([., 2, 1])),
New Column("AB3", Numeric, "Continuous", Format("Best", 12), Set Values([., 5, .]))
);
dt << New Column("N", Numeric, Continuous);
cols_of_interest = Filter Each({colname}, dt << Get Column Names("String"),
Starts With(colname, "AB");
);
For Each Row(Current Data Table(),
:N = Sum(!Is Missing(dt[Row(), cols_of_interest]));
);
Y si realmente quieres usar una fórmula, es posible que puedas usar algo como esto.
As Constant(cols_of_interest = Filter Each({colname}, Current Data Table() << Get Column Names("String"),
Starts With(colname, "AB");
));
Sum(!Is Missing(dt[Row(), cols_of_interest]));
Debes calcular tu propia comparación para filtrar las columnas de interés (Comienza con también debería funcionar para tus datos)
Re: ¿Cómo cuento la cantidad de filas que no están en blanco en filas específicas?Las tablas y los resúmenes pueden contar por usted. Para que cuenten en varias columnas, primero debe apilar los datos:
dt = New Table( "test",
Add Rows( 6 ),
New Column( "W8",Set Values( [2, 5, ., 5, ., 6] )),
New Column( "W9",Set Values( [2, ., 3, 3, 1, 2] )),
New Column( "W1",Set Values( [2, ., ., ., ., .] )),
New Column( "W2",Set Values( [3, ., ., ., ., .] )),
New Column( "W3",Set Values( [3, ., ., ., ., .] )),
New Column( "W4",Set Values( [., ., 4, ., 2, .] )),
New Column( "W5",Set Values( [., 2, ., ., ., .] )),
New Column( "W6",Set Values( [., ., 5, ., 3, .] )));
dt << New Column( "row",Formula( Row() ));
dtstack =dt << Stack( columns( :W8, :W9, :W1, :W2, :W3, :W4, :W5, :W6 ),"Non-stacked columns"n( Keep( :row ) ));
dtstack << Summary( Group( :row ), N( :Data ) );
por cierto:
"Non-stacked columns"n
un argumento nombrado que debe escribirse como "..."n . ¡Argh!
¡Qué bueno que ese log mejorado conoce estos detalles...!
