780686_ko-KR

liliconcom

슬라이더 상자로 그래디언트 최대값 변경

안녕하세요,

슬라이더 상자를 사용하여 그래디언트의 최대값을 변경하는 방법이 있나요?

Names Default To Here( 1 );

dt = Open( "$SAMPLE_DATA/Wafer Stacked.jmp" );
sliderValue = .6;
New Window( "", 
	
	
	H List Box(
		
		Panel Box( "Slider Box",
			tb = Text Box( "Gradient Maxium: " || Char( sliderValue ) ),
			sb = Slider Box( 0, 10, sliderValue, tb << Set Text( "Value: " || Char( sliderValue ) ) )
		), 	
		
		H List Box(
			Graph Builder(
				Size( 592, 569 ),
				Show Control Panel( 0 ),
				Variables( X( :X_Die ), Y( :Y_Die ), Color( :Defects ) ),
				Elements( Heatmap( X, Y, Legend( 5 ) ) ),
				SendToReport(
					Dispatch(
						{},
						"400",
						ScaleBox,
						{Legend Model( 5, Properties( 0, {gradient( {Min Lightness( 0 ), Width( 12 )} )}, Item ID( "Defects", 1 ) ) )}
					)
				)
			)
		)
	)
);

자동화 및 스크립팅Re: 슬라이더 상자로 그래디언트 최대값 변경

당신은 할 수 있습니다

Names Default To Here(1);

dt = Open("$SAMPLE_DATA/Wafer Stacked.jmp");
sliderValue = 0.6;

nw = New Window("", 
	H List Box(
		Panel Box("Slider Box",
			sb = Slider Box(0, 10, sliderValue, 
				vals = [.] || Matrix(sliderValue);
				Eval(EvalExpr(
					item << Set Properties({gradient({Scale Values(Expr(vals))})})
				));
			)
		), 	
		H List Box(
			gb = dt << Graph Builder(
				Size(592, 569),
				Show Control Panel(0),
				Variables(X(:X_Die), Y(:Y_Die), Color(:Defects)),
				Elements(Heatmap(X, Y, Legend(5))),
				SendToReport(
					Dispatch({}, "400", ScaleBox,
						{Legend Model(
							5,
							Properties(
								0,
								{gradient({Min Lightness(0), Width(12)})},
								Item ID("Defects", 1)
							)
						)}
					)
				)
			)
		)
	)
);

server = gb << Get Legend Server;
item = server << Get Legend Item(5, 1);

Re: 슬라이더 상자로 그래디언트 최대값 변경

Set Gradient Scale Values ​​메시지를 사용하여 Scale Values를 변경하면 원하는 작업을 수행할 수 있다고 생각합니다. 설명과 예는 Scripting Index를 참조하세요.