780564_it-IT

liliconcom

Come rinominare più variabili da 1 colonna?

Ho più variabili in 1 colonna (ad esempio B, F, T) che dovevano essere rinominate.

Local({dt, col1},
	dt = Data Table("ProductDefect");
	dt << Begin Data Update;
	col1 = dt << New Column(dt:LayerData);
	col1 << Set Name("Side");
	dt << Move Selected Columns({col1}, after(dt:LayerData));
	For Each Row(
		dt,
		col1[] = If(Contains(dt:LayerData, "B"),
			"Back",
			dt:LayerData
		)
	);
	dt << End Data Update;
);

Utilizzando questo script, sto modificando solo B mentre l'altra variabile (ad esempio, "F","T") non verrà modificata. Cosa si dovrebbe fare per rinominare tutto in una nuova colonna; B = Back, F = Front, T = Top?

Automazione e scriptingR: Come rinominare più variabili da 1 colonna?

La piattaforma Recode può creare facilmente questo tipo di conversione per te.

Local({dt, col1},
	dt = Data Table("Big Class");
	dt << Begin Data Update;
	col1 = dt << New Column(dt:sex);
	col1 << Set Name("sex 2");
	dt << Move Selected Columns({col1}, after(dt:sex));
	dt << Recode Column(
		dt:sex,
		{Map Value(_rcOrig, {"F", "Female", "M", "Male"}, Unmatched(_rcNow))},
		Update Properties(1),
		Target Column(col1)
	);
	dt << End Data Update;
);

Potresti anche prendere in considerazione l'utilizzo della proprietà della colonna Etichette valore

Non cambierà i dati nella tabella, ma vedrai i valori "ricodificati"

R: Come rinominare più variabili da 1 colonna?

Grazie per il feedback!

Tuttavia, utilizzando la piattaforma Recode, lo script non può essere automatizzato poiché dovrò caricare i dati dal database e ricodificarli manualmente ogni volta che ci saranno nuove aggiunte al database.

Come campione allegato, ad esempio, i miei dati continuano a essere aggiornati dal sistema, la denominazione cambierà continuamente mentre il numero e la variabile vengono mantenuti (ad esempio, 1B-xx, 1F-xx, 1T-xx, 2B-xx, 2F-xx, 2T-xx, ...). Dal sistema, non verrà visualizzato automaticamente, per cui B = Retro, F = Davanti, T = In alto.

Esiste un modo per evitare di dover ripetere Recode ogni volta che voglio effettuare un'analisi?

R: Come rinominare più variabili da 1 colonna?

"2B-New" dovrebbe essere "Back" o "2Back-New" e così via?

R: Come rinominare più variabili da 1 colonna?

Sì, nella nuova colonna voglio specificare solo il "Lato". Quindi 2B-New sarà "Back", 2T-Basic sarà "Top" e così via.

R: Come rinominare più variabili da 1 colonna?

Puoi usare Recode e Replace string più volte. Non conosco i tuoi dati, quindi non sono sicuro di quale sarebbe il modo migliore (forse opterei per una semplice regex e se fosse necessario qualcosa di più complicato potresti anche farlo)

Ripetere questo per tutti con i propri schemi

E JMP ti crea uno script

// Recode column: ProductDefect
Local({dt},
	dt = Data Table("Sheet1");
	dt << Begin Data Update;
	dt << Recode Column(
		dt:ProductDefect,
		{Regex(_rcNow, ".*?\d+B.*", "Back", GLOBALREPLACE),
		Regex(_rcNow, ".*?\d+T.*", "Top", GLOBALREPLACE),
		Regex(_rcNow, ".*?\d+F.*", "Front", GLOBALREPLACE)},
		Update Properties(1),
		Target Column(:ProductDefect)
	);
	dt << End Data Update;
);

Se non vuoi farlo in loco, esegui recode senza che sia abilitato

R: Come rinominare più variabili da 1 colonna?

Grazie mille per l'aiuto! Questo funziona come quello che avevo in mente!