779486_es-ES

liliconcom

Expresión del generador de gráficos de Taylor

Estimada comunidad,

Me gustaría crear un script de creación de gráficos (quiero ponerlo como script en una nueva tabla) que contenga una lista larga de variables y.

Mi primer intento fue intentar manipular expresiones, pero no funcionó como esperaba.

¿Alguien podría explicarme cuál sería una buena forma de escribir ese guión?

El siguiente ejemplo también contiene mi forma actual, creando la instancia de GB y agregando variables y después.

Gracias y un saludo,

Names Default To Here( 1 );

cdt = Open( "$SAMPLE_DATA\Big Class.jmp" );

col_lst = cdt << get column names( Continuous, "String" );

gb_expr = Expr(
	cdt << Graph Builder(
		Size( 534, 450 ),
		Show Control Panel( 0 ),
		Variables( X( :age ), Y( :height ) ),
		Elements( Position( 1, 1 ), Points( X, Y, Legend( 4 ) ) ),
		Elements( Position( 1, 2 ), Points( X, Y, Legend( 5 ) ) )
	)
);
// this does not work, Expr() does not accept comma separated items
// Substitute Into( gb_expr, Expr( Y( :height ) ), Expr( Y( :height ), Y( :weight ) ) );
// gb_obj = gb_expr;

// this works
// creating GB instance
gb_obj = cdt << Graph Builder(
	Size( 534, 450 ),
	Show Control Panel( 0 ),
	Variables( X( :age )),
	Elements( Position( 1, 1 ), Points( X, Y, Legend( 4 ) ) ),
	Elements( Position( 1, 2 ), Points( X, Y, Legend( 5 ) ) )
);

// adding Y's
For Each( {ycol}, col_lst, Eval( Parse( Eval Insert( "gb_obj << variables( Y(:^ycol^ ))" ) ) ) );

// this I would like to create directly, w/o large parse/eval parts, that are bad for maintenance
my_target_expression = gb_obj << get script();

Automatización y scriptingRe: Expresión del generador de gráficos de Taylor

¿Podría este pequeño cambio en el uso de Eval(Eval Expr()) brindarle lo que desea?

Names Default To Here( 1 );

cdt = Open( "$SAMPLE_DATA\Big Class.jmp" );

col_lst = cdt << get column names( Continuous, "String" );

gb_expr = Expr(
	cdt << Graph Builder(
		Size( 534, 450 ),
		Show Control Panel( 0 ),
		Variables( X( :age ), Y( :height ) ),
		Elements( Position( 1, 1 ), Points( X, Y, Legend( 4 ) ) ),
		Elements( Position( 1, 2 ), Points( X, Y, Legend( 5 ) ) )
	)
);
// this does not work, Expr() does not accept comma separated items
// Substitute Into( gb_expr, Expr( Y( :height ) ), Expr( Y( :height ), Y( :weight ) ) );
// gb_obj = gb_expr;

// this works
// creating GB instance
gb_obj = cdt << Graph Builder(
	Size( 534, 450 ),
	Show Control Panel( 0 ),
	Variables( X( :age ) ),
	Elements( Position( 1, 1 ), Points( X, Y, Legend( 4 ) ) ),
	Elements( Position( 1, 2 ), Points( X, Y, Legend( 5 ) ) )
);

// adding Y's
For Each( {ycol}, col_lst,
	Eval( Eval Expr( gb_obj << variables( Y( Expr( ycol ) ) ) ) )
);

// this I would like to create directly, w/o large parse/eval parts, that are bad for maintenance
my_target_expression = gb_obj << get script();

Re: Expresión del generador de gráficos de Taylor

Hola Jim,

Gracias, esto también funciona usando eval/evalexpr.

Pero mi pregunta era, ¿cómo podría construir esa gb_expr completa en la parte superior?

Lo que más me impresionó fue que:

Substitute Into( gb_expr, Expr( Y( :height ) ), Expr( Y( :height ), Y( :weight ) ) );

no funcionó.

Entonces quiero sustituir muchos "Y(:c1), Y(:c2) ..." en la expresión del generador de gráficos usando manipulación de expresiones (no manipulación de cadenas).

Atentamente,

Re: Expresión del generador de gráficos de Taylor

No sé cómo solucionar el problema de sustitución. Es posible que desees explorar el índice de secuencias de comandos Mensajes del generador de gráficos que se pueden pasar al generador de gráficos

Names Default To Here( 1 );
dt = Open( "$SAMPLE_DATA/Big Class.jmp" );
gb = Graph Builder(
	Variables( X( :sex ) ),
	Elements( Points( X, Y ), Smoother( X, Y ) )
);
gb << Add Variable( {:height, Role( "Y" )} );
gb << Add Variable( {:weight, Role( "Y" )} );

Re: Expresión del generador de gráficos de Taylor

@Georg

Siguiendo la sugerencia de @txnelson sobre enviar mensajes al generador de gráficos, esto podría acercarte a lo que estás buscando:

Names Default To Here( 1 );
cdt = Open( "$SAMPLE_DATA/Big Class.jmp" );

col_lst = cdt << get column names( Continuous, "String" );

gb = Graph Builder(
	Variables( X( :age ) ),
	Elements( Points( X, Y ) )
);

for each( { yCol }, col_lst,
	gb << Add Variable( { eval( yCol ), Role( "Y" ) } );
);

El script de creación de gráficos resultante es:

Graph Builder(<BR />Variables( X( :age ), Y( :height ), Y( :weight ) ),<BR />Elements( Position( 1, 1 ), Points( X, Y, Legend( 1 ) ) ),<BR />Elements( Position( 1, 2 ), Points( X, Y, Legend( 2 ) ) )<BR />);

Re: Expresión del generador de gráficos de Taylor

¡Gracias a todos, se ve bien!

Re: Expresión del generador de gráficos de Taylor

Normalmente no uso sustitutos para eso, sino que los construyo usando expresiones. A continuación se muestra una opción, pero hay otras opciones.

Names Default To Here(1);

dt = Open("$SAMPLE_DATA\Big Class.jmp");

col_lst = cdt << get column names(Continuous, "String");

var_expr = Expr(Variables(X(:age)));

For Each({colname}, col_lst,
	colname = "height";
	Insert Into(var_expr, EvalExpr(Y(Expr(Name Expr(As Column(dt, colname))))));
);

gb_expr = EvalExpr(
	dt << Graph Builder(
		Size(534, 450),
		Show Control Panel(0),
		Expr(Name Expr(var_expr))
	);
);

gb = Eval(gb_expr);
// gb << get script

gb << Save Script to Data Table("Plot");

Si solo quieres usar Sustituir, creo que tendrás que sustituir toda la parte de Variables (o posiblemente hacer algunos trucos)

Names Default To Here(1);

cdt = Open("$SAMPLE_DATA\Big Class.jmp");

col_lst = cdt << get column names(Continuous, "String");

gb_expr = Expr(
	cdt << Graph Builder(
		Size(534, 450),
		Show Control Panel(0),
		Variables(X(:age), Y(:height)),
		Elements(Position(1, 1), Points(X, Y, Legend(4))),
		Elements(Position(1, 2), Points(X, Y, Legend(5)))
	)
);

Substitute Into(gb_expr, Expr(Variables(X(:age), Y(:height))), Expr(Variables(X(:age), Y(:height), Y(:weight))));

show(gb_expr);