779087_de-DE

liliconcom

Säulenumschalter mit mehreren Plattformen verbunden

dt = Open( "$SAMPLE_DATA/Process Measurements.jmp" );

clear log();

colnames = dt << getcolumnnames(numeric,string);
colnames = Filter Each({name}, colnames, !Is Missing(Regex(lowercase(name), "^(process).*")));

print(colnames[1]);

New Window("reacher",
	H List Box(
		V List Box (
			dist = dt << Distribution(Continuous Distribution(Column(column(dt, colnames[1])),Process Capability( 0 )),Histograms Only),
			biv = Bivariate( Y(column(dt, colnames[1])), X(column(dt, colnames[1])) )
		),
		cs = dt << Column Switcher(:Process 1, colnames),
//		cs = dt << Column Switcher(colnames[1], colnames),
	)
);
cs << Link Platform( dist );
cs << Link Platform( biv );

Ich versuche, einen Spaltenumschalter für eine beliebige Tabelle zu skripten.

Der obige Code funktioniert.

Wenn jedoch Zeile 16 kommentiert und Zeile 17 unkommentiert ist, funktioniert der Spaltenumschalter nicht

Bitte helfen Sie

Automatisierung und SkriptingBetreff: Spaltenumschalter für mehrere Plattformen verknüpft

Eventuell müssen Sie die colnames[1] im richtigen Format auswerten, um den Spaltenumschalter zu verwenden. Hier ist eine Möglichkeit

Names Default To Here(1);

dt = Open("$SAMPLE_DATA/Process Measurements.jmp");

colnames = dt << getcolumnnames(numeric, string);
colnames = Filter Each({name}, colnames, !Is Missing(Regex(Lowercase(name), "^(process).*")));

Eval(EvalExpr(
	nw = New Window("reacher",
		H List Box(
			V List Box(
				dist = dt << Distribution(
					Continuous Distribution(Column(Eval(colnames[1])), Process Capability(0)),
					Histograms Only
				),
				biv = Bivariate(Y(Eval(colnames[1])), X(Eval(colnames[1])))
			),
			cs = dt << Column Switcher(Expr(NameExpr(AsColumn(dt, colnames[1]))), colnames)
		)
	);	
));

cs << Link Platform(dist);
cs << Link Platform(biv);

Betreff: Spaltenumschalter für mehrere Plattformen verknüpft

Danke für den Hinweis.

Wenn der Spaltenname Sonderzeichen enthält, funktioniert der Ausdruck nicht

Beispielspalten: „Process:USL=8:LSL=1.0“

Betreff: Spaltenumschalter für mehrere Plattformen verknüpft

Welche JMP-Version verwenden Sie?

Funktioniert bei mir einwandfrei (mit JMP18.0.1)

Mehr sehen...

Names Default To Here(1);

dt = Open("$SAMPLE_DATA/Process Measurements.jmp");

Column(dt, 1) << Set Name("Process:USL=8:LSL=1.0");


colnames = dt << getcolumnnames(numeric, string);
colnames = Filter Each({name}, colnames, !Is Missing(Regex(Lowercase(name), "^(process).*")));

Eval(
	Eval Expr(
		nw = New Window("reacher",
			H List Box(
				V List Box(
					dist = dt << Distribution(
						Continuous Distribution(
							Column(Eval(colnames[1])),
							Process Capability(0)
						),
						Histograms Only
					),
					biv = Bivariate(Y(Eval(colnames[1])), X(Eval(colnames[1])))
				),
				cs = dt << Column Switcher(
					Expr(
						Name Expr(As Column(dt, colnames[1]))
					),
					colnames
				)
			)
		)
	)
);

cs << Link Platform(dist);
cs << Link Platform(biv);