777716_ja-JP

liliconcom

JMP の KM プロットのリスク テーブル?

https://community.jmp.com/t5/Discussions/Displaying-at-risk-tables-under-kaplan-meier/mp/55338/highlight/true#M31302によると、KM プロットの下にリスク テーブルを生成する方法を教えてください。コメントのスクリプトに従おうとしましたが、解決できませんでした。

dt = Current Data Table ();
minT = 0;
maxT = 25;
stepT = 1;

Summarize( lv = by( :group) );
obj = Survival(
	Y( :time ),
	Censor( :"reject"n ),
	Grouping( :group ),
	Failure Plot( 0 ),
	SendToReport(
		Dispatch(
			{"Survival Plot"},
			"1",
			ScaleBox,
			{Min( 0 ), Max( 25 ), Inc( 1 ), Minor Ticks( 1 )}
		),
		Dispatch(
			{"Survival Plot"},
			"time",
			TextEditBox,
			{Set Text( "Times(years)" )}
		)
	)
) << report;
obj[List Box( 2 )] << append( Table Box( String Col Box( "No at Risk | Year", lv ) ) );
Tab1 = (obj[lv[1]][Table Box( 1 )] << get);
Tab2 = (obj[lv[2]][Table Box( 1 )] << get);
For( T = minT, T <= maxT, T += stepT,
	lp = Max( Loc( Matrix( Tab1 [years] ) <= T ) );
	AR1 = Tab1["At Risk"][lp];
	lp = Max( Loc( Matrix( Tab2 [years]) <= T ) );
	AR2 = Tab2["At Risk"][lp];
	obj[List Box( 2 )][Table Box( 1 )] << append( Number Col Box( Char( T ), {AR1, AR2} ) );
);

出力は添付画像の通りです。スクリプトを修正していただけますか?

ありがとう

データの探索と視覚化Re: JMP の KM プロットのリスク テーブル?

コードをもう少しパラメータ化しようとしましたが、minT、maxT、stepT、ycol、グループ化を変更してテーブルを使用すると、目的の動作が実現されますか？

Names Default To Here(1);

dt = Open("$SAMPLE_DATA/Rats.jmp");

minT = 100;
maxT = 350;
stepT = 50;
ycol = "days";
grouping = "Group";

Summarize(dt, groups = by(Eval(grouping)));

obj = dt << Survival(
	Y(Eval(ycol)),
	Censor(:Censor),
	Grouping(Eval(grouping)),
	Show Points(1),
	SendToReport(
		Dispatch({"Survival Plot"}, "1", ScaleBox,
			{Min(minT), Max(maxT), Inc(stepT), Minor Ticks(1)}
		),

	)
);

rep = Report(obj);

rep[List Box(2)] << append(tb = Table Box(String Col Box("No at Risk ("||ycol||")", groups)));
rep[List Box(2)] << Append(Spacer Box(Size(0,20)));

tabs = {};
For Each({group}, groups,
	Insert Into(tabs, Eval List({rep[OutlineBox(group), Table Box(1)] << get}));
);


For(T = minT, T <= maxT, T += stepT,
	
	ARs = {};
	For Each({tab}, tabs,
		lp = Max(Loc(Matrix(tab[ycol]) <= T));
		Insert Into(ARS, tab["At Risk"][lp])
	);
		
	tb << append(Number Col Box(Char(T), ARs));
);

編集: 小さな修正

Re: JMP の KM プロットのリスク テーブル?

こんにちは、Jarmoさん。ご協力ありがとうございます。うまくいきました!

宜しくお願い致します、ティーラチャイ

Re: JMP の KM プロットのリスク テーブル?

生存者レポートで基本的に使用できるスクリプトもあります。ほとんどの場合に機能するかもしれませんが、この JMP プラットフォームや分析にあまり詳しくないので、機能するかどうかはわかりません。また、計算を変更したため、正確ではない可能性があります。

まず、生存者レポートを開いておく必要があります

スクリプトを実行すると、いくつかのことを尋ねられます

それらを入力してOKを押してください

既存のレポートにテーブルが追加されます

スクリプトは以下（添付も）です。計算はチェックされていないため、自己責任で使用してください。

もっと見る...

/*""" Add risk table to Survival platform

Author: jthi
Creation Date: 2024-07-31
Creation JMP Version: JMP Pro 18.0.1

Description: Based on
	https://community.jmp.com/t5/Discussions/Displaying-at-risk-tables-under-kaplan-meier/m-p/305898/highlight/true#M56162

Todo:
    * Show steps to user before pressing OK
    * Remove modal window
    * Turn into add-in / proper script
    * Add instructions / title to UI
    * Add utility modal
	
"""*/

Names Default To Here(1);

ask_steps = function({}, {Default Local},
	nw = New Window("Fill in Time to Event Steps", << Type("Modal Dialog"), << Return Result,
		H List Box(
			Panel Box("Fill in steps",
				Lineup Box(N Col(2),
					Text Box("Min Time"),
					neb_min = Number Edit Box(.),
					Text Box("Max Time"),
					neb_max = Number Edit Box(.),
					Text Box("Step Time"),
					neb_step = Number Edit Box(.),
					Text Box("Interpolate last"),
					cb_interpolate = Check Box({""}, << Set All(1))
				)
			),
			Spacer Box(Size(20, 0)),
			Panel Box("Actions",
				Button Box("OK"),
				Button Box("Cancel")
			)
		)
		, << Set Window Icon("Survival")
	);
	
	If(nw["Button"] != 1,
		Throw("Cancelled");
	);
	
	min_t = nw["neb_min"];
	max_t = nw["neb_max"];
	step_t = nw["neb_step"];

	If(Any(Is Missing(min_t), Is Missing(max_t), Is Missing(step_t)),
		Throw("Steps not filled in");
	);
	
	interpolate_last = N Items(nw["cb_interpolate"]);

	return(Eval List({min_t, max_t, step_t, interpolate_last}));
);

add_risk_table = function({platform_ref, min_t, max_t, step_t, interpolate_last}, {Default Local},

	rep = Report(platform_ref);
	dt = platform_ref << Get Data Table;
	
	ycol = ((rep << XPath("//TextBox[text()='Time to event: ']"))[1] << sib) << get text;
	grouping_col = ((rep << XPath("//TextBox[text()='Grouped by ']"))[1] << sib) << get text;
	Summarize(dt, groups = by(Eval(grouping_col)));

	steps = min_t::max_t::step_t;
	vals = steps;
	
	For Each({group}, groups,
		m_tb = rep[OutlineBox(group), Table Box(1)] << get as matrix;
		
		times = m_tb[0, 1];
		atrisk = m_tb[0, N Cols(m_tb)];
		cur_steps = Step(steps, times, atrisk); // Last one isn't assumed in this
		
		If(interpolate_last,
			If(times[N Rows(times), 1] < max_t & Is Missing(cur_steps[N Cols(cur_steps)]),
				cur_steps[N Cols(cur_steps)] = atrisk[N Rows(times), 1];
			);			
		);
		vals = vals |/ cur_steps;
	);


	pb = Panel Box("Risk Table", tb_results = Table Box(
		String Col Box(Eval Insert("No at Risk (^ycol^)"), groups),
	));


	For(i = 1, i <= N Cols(vals), i++,
		cur_vals = vals[0, i];
		
		title = Char(Remove From(cur_vals, 1)[1]);
		
		tb_results << Append(Number Col Box(title, cur_vals));
	);

	rep[List Box(2)] << Append(pb);
	rep[List Box(2)] << Append(Spacer Box(Size(0, 10)));
);



cur_rep = Current Report();
If(Is Empty(cur_rep),
	Throw("No reports open");
);

ob_ref = cur_rep << XPath("//OutlineBox[@helpKey='Surv']");

If(N Items(ob_ref) == 0,
	Throw("No Surv platform found");
);

Try(
	{min_t, max_t, step_t, interpolate_last} = ask_steps();

	platform_ref = ob_ref[1] << get scriptable object;

	add_risk_table(platform_ref, min_t, max_t, step_t, interpolate_last);
,
	Throw("Other issues: " || char(exception_msg));
);


Write();

Re: JMP の KM プロットのリスク テーブル?

このスクリプトをありがとうございます。本当に気に入っています。以下の設定 (「グループ化」と「基準」を指定) を使用して一度に複数の生存曲線を生成すると、リスク テーブルは最初のプロットにのみ追加されます。すべてのプロットに追加する方法はありますか?

Re: JMP の KM プロットのリスク テーブル?

可能ではありますが、スクリプトの修正が必要になります。このバージョンが機能するかどうか試してみてください:

もっと見る...

Names Default To Here(1);

ask_steps = function({}, {Default Local},
	nw = New Window("Fill in Time to Event Steps", << Type("Modal Dialog"), << Return Result,
		H List Box(
			Panel Box("Fill in steps",
				Lineup Box(N Col(2),
					Text Box("Min Time"),
					neb_min = Number Edit Box(.),
					Text Box("Max Time"),
					neb_max = Number Edit Box(.),
					Text Box("Step Time"),
					neb_step = Number Edit Box(.),
					Text Box("Interpolate last"),
					cb_interpolate = Check Box({""}, << Set All(1))
				)
			),
			Spacer Box(Size(20, 0)),
			Panel Box("Actions",
				Button Box("OK"),
				Button Box("Cancel")
			)
		)
		, << Set Window Icon("Survival")
	);
	
	If(nw["Button"] != 1,
		Throw("Cancelled");
	);
	
	min_t = nw["neb_min"];
	max_t = nw["neb_max"];
	step_t = nw["neb_step"];

	If(Any(Is Missing(min_t), Is Missing(max_t), Is Missing(step_t)),
		Throw("Steps not filled in");
	);
	
	interpolate_last = N Items(nw["cb_interpolate"]);

	return(Eval List({min_t, max_t, step_t, interpolate_last}));
);

add_risk_table = function({platform_ref, min_t, max_t, step_t, interpolate_last}, {Default Local},

	rep = Report(platform_ref);
	dt = platform_ref << Get Data Table;
	
	ycol = ((rep << XPath("//TextBox[text()='Time to event: ']"))[1] << sib) << get text;
	grouping_col = ((rep << XPath("//TextBox[text()='Grouped by ']"))[1] << sib) << get text;
	Summarize(dt, groups = by(Eval(grouping_col)));

	steps = min_t::max_t::step_t;
	vals = steps;
	
	For Each({group}, groups,
		m_tb = rep[OutlineBox(group), Table Box(1)] << get as matrix;
		
		times = m_tb[0, 1];
		atrisk = m_tb[0, N Cols(m_tb)];
		cur_steps = Step(steps, times, atrisk); // Last one isn't assumed in this
		
		If(interpolate_last,
			If(times[N Rows(times), 1] < max_t & Is Missing(cur_steps[N Cols(cur_steps)]),
				cur_steps[N Cols(cur_steps)] = atrisk[N Rows(times), 1];
			);			
		);
		vals = vals |/ cur_steps;
	);


	pb = Panel Box("Risk Table", tb_results = Table Box(
		String Col Box(Eval Insert("No at Risk (^ycol^)"), groups),
	));


	For(i = 1, i <= N Cols(vals), i++,
		cur_vals = vals[0, i];
		
		title = Char(Remove From(cur_vals, 1)[1]);
		
		tb_results << Append(Number Col Box(title, cur_vals));
	);

	rep[List Box(2)] << Append(pb);
	rep[List Box(2)] << Append(Spacer Box(Size(0, 10)));
);



cur_rep = Current Report();
If(Is Empty(cur_rep),
	Throw("No reports open");
);

ob_refs = cur_rep << XPath("//OutlineBox[@helpKey='Surv']");

If(N Items(ob_refs) == 0,
	Throw("No Surv platform found");
);

Try(
	{min_t, max_t, step_t, interpolate_last} = ask_steps();
	
	For Each({ob_ref}, ob_refs,
		platform_ref = ob_ref << get scriptable object;

		add_risk_table(platform_ref, min_t, max_t, step_t, interpolate_last);		
	);

,
	Throw("Other issues: " || char(exception_msg));
);


Write();

スクリプトの最後に行った変更はわずかで、基本的にはループごとに 1 つ追加しただけです (変数名を 1 つ変更しました)。

Re: JMP の KM プロットのリスク テーブル?

早速の返信ありがとうございます。このメッセージは届いているのでしょうか?

Re: JMP の KM プロットのリスク テーブル?

100行目にsが1つ欠けています

問題を修正するために以前の投稿を編集しました

Re: JMP の KM プロットのリスク テーブル?

再度ありがとうございます！動作するようになりました！

出力の品質管理を行うために、参照図 (以下の JMP と参照を参照) を作り直したところ、いくつかの詳細に気付きました。左から、時間 = 0 では、リスクのある数値 40 は正しいのですが、後続のタイムポイントは 1 増えています。例外は、実際の数値が 0 の場合で、スクリプトはこれを正確にリストします。最後に、最後のタイムポイントには 1 がありますが、これは存在しないはずです。Excel でこれを修正することはできますが、スクリプトで修正できればすばらしいと思います。

Re: JMP の KM プロットのリスク テーブル?

どの計算が間違っているのかわかりません。私のスクリプト内にある場合は、おそらくここのどこかで修正できるでしょう。

結果がどうなるかを知るには、正しい回答を含むサンプル データセットが必要になります (ただし、私のスクリプトの補間オプションは正しく機能していないようです)。

Re: JMP の KM プロットのリスク テーブル?

「誇張された」リスク数値について追記します。VP肺がんデータセットでスクリプト（ありがとうございます！）を使用したところ、標準グループのリスク数値が400、テストグループのリスク数値が200、400、600、800と、それぞれ1つずつ追加されました。

データ テーブルを見ると、正確な時点の値 (標準の場合は 200 - 最初のピンクの行) には正しいリスク数値が表示されますが、400、600、800 など、正確に一致しない場合は、現在のスクリプトによって、指定された時点より前の数値が取り込まれます。スクリプトでこれらのケースを修正できれば素晴らしいと思います。

Re: JMP の KM プロットのリスク テーブル?

以前の値ではない場合は何を表示すればよいでしょうか?