777173_it-IT

liliconcom

Come creare uno script che generi un diagramma di Pareto con filtri di data

Ciao a tutti,

Spero che tu stia bene.Sto affrontando un problema durante la creazione di uno script per generare un diagramma di Pareto da una tabella che desidero filtrare per date (data1 e data2).

Come primo passo,Ho chiamato il mio tavolo usando:

dt2 = Open( "/D:/Project JMP/Tables/Table NOK PY.jmp", invisible );

Prossimo :

dt2_top5 = dt2 << Summary(
	Group( :Date, :Ref Produit, :ProductName, :Baie, :ICT_FCT, :CodeError),
	Freq( "Aucun(e)" ),
	Weight( "Aucun(e)" ),
	output table name( "Table2 Top 5" ),
	invisible
);

// Subset of data for Pareto plot filtered by Date
dt_pareto_subset = dt2_top5 << Select Where( Num( Char( :Date ) ) >= Num( date1 ) & Num( Char( :Date ) ) < Num( date2 ) );
dt_pareto_subset = dt2_top5 << Subset(
	Selected Rows(1),
	Columns(:CodeError),
	output table name("Pareto Subset"),
	invisible
);

e ho creato la trama di Pareto nella mia finestra:

Border Box(Left(25), Top(50), Bottom(200),
	V List Box(
		// Add the Pareto plot here
		paretoPlot = dt_pareto_subset << Pareto Plot(
			Y( :CodeError ),
			Freq( "Freq" ),
			Show Percents( 1 ),
			Show Cumulative Line( 1 )
		),
	)	
)

ma dopo aver lanciato il mio script ho ricevuto questo errore:

È previsto l'oggetto script durante l'accesso o la valutazione di "Invia", dt_pareto_subset << /*###*/
Grafico di Pareto (
Y(:ErroreCodice),

Freq("Frequenza"),

Mostra percentuali(1),

Mostra linea cumulativa(1)

)/*###*/

Ho un piccolo frammento di codice che genera un diagramma di Pareto. Attualmente devo selezionare manualmente la tabella dati ogni volta e non posso applicare un filtro data:

Pareto Plot(
	Cause( :CodeError ),
	SendToReport(
		Dispatch( {"Plots"}, "Pareto Report", FrameBox, {Frame Size( 1555, 725 )} )
	)
);

Grazie a tutti per il vostro aiuto,

Distinti saluti,
Sì

finestreRe: Come creare uno script che generi un grafico di Pareto con filtri di data

Hai il sottoinsieme che ti aspetti in dt_pareto_subset?

Re: Come creare uno script che generi un diagramma di Pareto con filtri di data

sì e mi aspetto che dt_pareto_subset contenga solo le righe da dt2_top5 dove il valore nella colonna :Date è compreso tra date1 e date2

Re: Come creare uno script che generi un diagramma di Pareto con filtri di data

Il messaggio di errore indica che la variabile dt_pareto_subset non ha un oggetto scriptabile (in questo caso una tabella dati). Potrebbero esserci molte cause diverse per questo ed è del tutto supposto che funzioni senza vedere i tuoi dati o lo script completo.

Re: Come creare uno script che generi un diagramma di Pareto con filtri di data

Names Default To Here( 1 );

TOP5 = New Namespace(
    "TOP5"
);

TOP5:get_dates = Function({},
    ////
);

TOP5:calculate_nok_percentages = Function({dt},
    /////
);

// Define the Do function
TOP5:Do = Function ({nb_date1, nb_date2},
    //Ouverture de la table de données
    dt = Open( "/D:/Project JMP/Tables/TableData PY.jmp", invisible );
    dt2 = Open( "/D:/Project JMP/Tables/Table NOK PY.jmp", invisible );


    {percent_nok_ict, percent_nok_fct} = TOP5:calculate_nok_percentages(dt);

    current_month = Format(Today(), "Format Pattern", "<MONTH>", << Use Locale(0));

    date1 = Date Increment(Today(), "day", nb_date1, "start");
    date2 = Date Increment(Today(), "day", nb_date2, "start");

    dt_top5 = dt << Summary(
        Group( :Date, :Nom de fichier, :Ref Produit, :ProductName, :Baie, :ICT_FCT, :Result, :CodeError),
        Freq( "Aucun(e)" ),
        Weight( "Aucun(e)" ),
        output table name( "Table Top 5" ),
        invisible
    );

    dt2_top5 = dt2 << Summary(
		Group( :Date, :Ref Produit, :ProductName, :Baie, :ICT_FCT, :CodeError),
		Freq( "Aucun(e)" ),
		Weight( "Aucun(e)" ),
		output table name( "Table2 Top 5" ),
		invisible
	);

	// Subset of data for Pareto plot filtered by Date
	dt_pareto_subset = dt2_top5 << Select Where( Num( Char( :Date ) ) >= Num( date1 ) & Num( Char( :Date ) ) < Num( date2 ) );
	dt_pareto_subset = dt2_top5 << Subset(
		Selected Rows(1),
		Columns(:CodeError),
		output table name("Pareto Subset"),
		invisible
	);


    /*
    //
    //
    //

    Here i have the logic of production repport.
    it's fine it works 
    
    //
    //
    //
    */


    //Création de la fenetre du top 5
    window = new Window ("TOP5",
        V List Box(
            pb = Picture Box( Open( "D:\Project JMP\Images\logo.png", png ) ),
            Border Box( Top(50),
                V List Box(
                    tb1 = Text Box("Production results report of "||Format( date2, "yyyy-mm-dd" )),
                    tb1 << Set Base Font( "Title" ),
                    tb1 << Set Font Scale (3),
                    tb1 << Justify Text("Center"),
                    tb1 << Set Width(2770),
                    tb1 << Background Color(RGB Color(225, 225, 225)),
                    
                    tb2 = Text Box ("SVI, PY"),
                    tb2 << Justify Text("Center") << Set Font Size(25),
                    tb2 << Set Width(2770),
                    tb2 << Background Color(RGB Color(240, 240, 240)),
                )
            ),
            V List Box (
                Border Box (Top (100), Bottom(100), Left (25),
                    H List Box(
                        // TOP 5 ICT
                        V List Box(
                            tb3 = Text Box( "Top 5 NOK results for ICT"),
                            tb3 << Set Base Font( "Title" ),
                            tb3 << Set Font Scale (2),
                            H List Box(
                                // column bay
                                
                                // column product ref
                                
                                // column test number
                                
                                //column %nok
                                
                                // column product name
                            )
                        ),	
                        V List Box(
							//nok percent for this month
						),
                    )
                ),
                Border Box(Left(25), Top(50), Bottom(200),
                    //TOP 5 FCT
                    V List Box(
                        tb4 = Text Box( "Top 5 NOK results for FCT"),
                        tb4 << Set Base Font( "Title" ),
                        tb4 << Set Font Scale (2),
                        H List Box(
                                // column bay
                                
                                // column product ref
                                
                                // column test number
                                
                                //column %nok
                                
                                // column product name
                            )
                        )
                        V List Box(
							//nok percent for this month
						),
                    )
                ),
                
                Border Box(Left(25), Top(50), Bottom(200),
					V List Box(
						// Add the Pareto plot here
						paretoPlot = dt_pareto_subset << Pareto Plot(
							Y( :CodeError ),
							Freq( "Freq" ),
							Show Percents( 1 ),
							Show Cumulative Line( 1 )
						),
					)	
				)
            )
        )
    );

    window << Maximize Window (1);
    //Enregistrement du fichier image .png et du fichier texte .txt
    window << Save Picture ("D:\Project JMP\Rapports de Production Quotidiens\Rapport du "||Format( date2, "yyyy-mm-dd" )||".png", "png");
    window << Save Text ("D:\Project JMP\Rapports de Production Quotidiens\Rapport du "||Format( date2, "yyyy-mm-dd" )||".txt");
);</MONTH>

Re: Come creare uno script che generi un diagramma di Pareto con filtri di data

Funziona come previsto se crei la trama dopo aver creato il sottoinsieme? Quindi non inserirlo nella nuova finestra

Names Default To Here(1);
dt = Open("$SAMPLE_DATA/Time Series/Steel Shipments.jmp");

dt << New Column("Errors", Character, Nominal, Formula(
	Match(Floor(:Steel Shipments / 1000),
		4, "1000",
		5, "2000",
		6, "3000",
		7, "4000",
		8, "5000"
	)
));

rows_of_interest = dt << Get Rows Where(02Feb1985<= :Date <= 09Jan1990);

dt_subset = dt << Subset(Rows(rows_of_interest), Selected Columns(0), Output Table("Subset"));

paretoplot = dt_subset << Pareto Plot(Cause(:Errors));

Re: Come creare uno script che generi un diagramma di Pareto con filtri di data

Ciao,

ho provato il metodo nel tuo script, mi dà il grafico di Pareto ma senza filtro dati. Ad esempio, il pareto per oggi deve essere 2024-07-29 <= :Date < 2024-07-30.

Quindi ho usato queste funzioni:

// Function to get today's and yesterday's date
GetTodayAndYesterday = Function({},
    today = Today();
    yesterday = Date Increment(today, "day", -1, "start");
    evallist({Format(yesterday, "yyyy-mm-dd"), Format(today, "yyyy-mm-dd")});
);

	dt = Open( "/D:/Project JMP/Tables/DB.jmp", invisible );

    {yesterday, today} = GetTodayAndYesterday();

     dt_top5 = dt << Summary(
		     Group( :Date, :Ref Produit, :Baie, :ICT_FCT, :Result, :CodeError),
		     Freq( "Aucun(e)" ),
		     Weight( "Aucun(e)" ),
		     output table name( "Table Top 5" ),
		     invisible
	     );

    // Create a subset of data for the Pareto Plot filtered by the date range
    rows_of_interest = dt_top5 << Get Rows Where( Num( Char( :Date ) ) >= Num( yesterday ) & Num( Char( :Date ) ) <= Num( today ) );
    dt_pareto_subset = dt_top5 << Subset(Rows(rows_of_interest), Selected Columns(0), Output Table("Pareto Subset"), invisible);

    // Generate the Pareto Plot
    paretoplot = dt_pareto_subset << Pareto Plot(Cause(:CodeError));	

Ho allegato un campione del mio database come riferimento.

Re: Come creare uno script che generi un diagramma di Pareto con filtri di data

Vuoi avere un filtro dei dati nel tuo diagramma di Pareto o vuoi semplicemente filtrare i dati? Sembra che tu voglia solo creare un sottoinsieme dai tuoi dati e NON avere un filtro.

Re: Come creare uno script che generi un diagramma di Pareto con filtri di data

Devo filtrare i dati con Date utilizzando un sottoinsieme per creare un grafico di Pareto per i risultati di produzione di ieri perché ogni mattina generi un report sui risultati di produzione giornalieri

Re: Come creare uno script che generi un diagramma di Pareto con filtri di data

Non dovrebbe essere necessaria la conversione da num e char a num.

Forse qualcosa del genere?

Names Default To Here(1);

dt = Open("$DOWNLOADS/DB.jmp");

yday = Date Increment(Today(), "day", -1, "start");
tday = Date Increment(Today(), "day", 0, "start");


dt_top5 = dt << Summary(
	Group(:Date, :Ref Produit, :Baie, :ICT_FCT, :Result, :CodeError),
	Freq("Aucun(e)"),
	Weight("Aucun(e)"),
	output table name("Table Top 5")
);

rows_of_interest = dt_top5 << Get Rows Where(yday <= :Date <= tday);
show(rows_of_interest);

dt_pareto_subset = dt_top5 << Subset(
	Rows(rows_of_interest),
	Selected Columns(0),
	Output Table("Pareto Subset")
);

pp = dt_pareto_subset << Pareto Plot(Cause(:CodeError), Freq(:N Rows));

Potresti anche creare paretoplot dalla tua tabella iniziale (il filtraggio può richiedere un po' di lavoro)

dt << Pareto Plot(
	Cause(:CodeError),
	Local Data Filter(
		Add Filter(
			columns(:Date),
			Where(:Date == 3805056000),
			Display(:Date, N Items(4))
		)
	)
);