776503_zh-TW

liliconcom

刷新列列錶框

請參閱下面的腳本。這是為了在對話方塊視窗中使用。

此腳本的作用是將Col List Box() 的最小項目設為0或 1。它會執行此操作，但只有在我將滑鼠移到列列錶框上之後（請參閱螢幕影片）。

有沒有一種方法可以進行刷新/更新，而無需將滑鼠遊標移到列列錶框上？

該影片目前正在處理中。請在幾分鐘後再試一次。

（在我的影片中查看）

Names Default To Here( 1 );

dlg = New Window( "Col List Box Min Item Refresh Issue",
	H List Box(
		Panel Box( "Select Columns", clb1 = Col List Box( all, max selected( 1 ) ) ),
		Panel Box( "Cast Column",
			V List Box(
				H List Box(
					Button Box( "Choose Column", clbvar << append( clb1 << get selected ) ),
					clbvar = Col List Box( maxitems( 1 ), nlines( 1 ) )
				),
				cb = Check Box(
					"required",
					If( cb << get,
						clbvar << set min items( 1 ),
						clbvar << set min items( 0 )
					)
				)
			)
		),
		V List Box(
			Button Box( "Ok",
				Print( clbvar << get items );
				dlg << close window;
			),
			Button Box( "Remove", clbvar << remove selected ),
			Button Box( "Cancel", dlg << close window )
		)
		
	)
);

大規模客製化回覆：刷新列列錶框

將 << Reshow 訊息新增到您的複選框腳本中。

Names Default To Here( 1 );

dlg = New Window( "Col List Box Min Item Refresh Issue",
	H List Box(
		Panel Box( "Select Columns", clb1 = Col List Box( all, max selected( 1 ) ) ),
		Panel Box( "Cast Column",
			V List Box(
				H List Box(
					Button Box( "Choose Column", clbvar << append( clb1 << get selected ) ),
					clbvar = Col List Box( maxitems( 1 ), nlines( 1 ) )
				),
				cb = Check Box(
					"required",
					If( cb << get,
						clbvar << set min items( 1 ),
						clbvar << set min items( 0 )
					);
//Update the Col List Box
					clbvar << Reshow;
				)
			)
		),
		V List Box(
			Button Box( "Ok",
				Print( clbvar << get items );
				dlg << close window;
			),
			Button Box( "Remove", clbvar << remove selected ),
			Button Box( "Cancel", dlg << close window )
		)
		
	)
);