776503_es-ES

liliconcom

Actualizar cuadro de lista de columnas

Vea el guión a continuación. Está pensado para usarse en una ventana de diálogo.

Lo que hace este script es establecer los elementos mínimos de Col List Box() en 0 o 1. Al hacer esto, la marca de agua dentro del cuadro de lista de columnas debe cambiar de opcional a obligatorio . Hará esto, pero solo después de mover el mouse sobre el cuadro de lista de columnas (ver video en pantalla).

¿Hay alguna manera de realizar esa actualización sin tener que mover el cursor del mouse sobre el cuadro de lista Col?

Este vídeo está siendo procesado actualmente. Inténtelo de nuevo en unos minutos.

(ver en Mis vídeos)

Names Default To Here( 1 );

dlg = New Window( "Col List Box Min Item Refresh Issue",
	H List Box(
		Panel Box( "Select Columns", clb1 = Col List Box( all, max selected( 1 ) ) ),
		Panel Box( "Cast Column",
			V List Box(
				H List Box(
					Button Box( "Choose Column", clbvar << append( clb1 << get selected ) ),
					clbvar = Col List Box( maxitems( 1 ), nlines( 1 ) )
				),
				cb = Check Box(
					"required",
					If( cb << get,
						clbvar << set min items( 1 ),
						clbvar << set min items( 0 )
					)
				)
			)
		),
		V List Box(
			Button Box( "Ok",
				Print( clbvar << get items );
				dlg << close window;
			),
			Button Box( "Remove", clbvar << remove selected ),
			Button Box( "Cancel", dlg << close window )
		)
		
	)
);

La personalización en masaRe: Actualizar cuadro de lista de columnas

Agregue un mensaje << Remostrar a su secuencia de comandos de casilla de verificación.

Names Default To Here( 1 );

dlg = New Window( "Col List Box Min Item Refresh Issue",
	H List Box(
		Panel Box( "Select Columns", clb1 = Col List Box( all, max selected( 1 ) ) ),
		Panel Box( "Cast Column",
			V List Box(
				H List Box(
					Button Box( "Choose Column", clbvar << append( clb1 << get selected ) ),
					clbvar = Col List Box( maxitems( 1 ), nlines( 1 ) )
				),
				cb = Check Box(
					"required",
					If( cb << get,
						clbvar << set min items( 1 ),
						clbvar << set min items( 0 )
					);
//Update the Col List Box
					clbvar << Reshow;
				)
			)
		),
		V List Box(
			Button Box( "Ok",
				Print( clbvar << get items );
				dlg << close window;
			),
			Button Box( "Remove", clbvar << remove selected ),
			Button Box( "Cancel", dlg << close window )
		)
		
	)
);