775341_zh-TW

liliconcom

互動式/動態過濾或選擇選單

我有一個名為 dt 的表。我採用某些列的唯一值，並建立以下選單，使最終使用者能夠根據列的值過濾 dt 表並取得其中的子集。

但是，採用其列的唯一值是有風險的，因為您最終可能會選擇表中不存在的屬性組合。

有什麼方法可以使此選單具有互動性或動態性，以便在最終用戶做出某些選擇時縮小可用選擇的範圍？

一般來說，有什麼方法可以解決由於初始資料集不包含屬性唯一值的所有組合而導致最終出現空表的問題嗎？

自動化和腳本編寫基礎資料分析與建模回覆：互動式/動態過濾或選擇選單

您可以嘗試使用條件資料過濾器，但它可能會擾亂您的佈局/需要一些額外的工作才能使其看起來相似。

回覆：互動式/動態過濾或選擇選單

這是一個簡單的例子。我建議使引用更加穩健，並可能使用本地資料過濾器而不是全域資料過濾器。您還應該對其進行參數化（包裝、說明…）

Names Default To Here(1);

dt = Open("$SAMPLE_DATA/Animals.jmp");

nw = New Window("",
	V List Box(align("center"),
		Text Box("Animals Study Evaluation", << Set Base Font("Title")),
		Text Box("Add-in version 1.0", << Set Base Font("Heading")),
		Text Box("Documentation report: xxxxxx", << Set Base Font("Heading")),
		Panel Box("Study Selections",
			Button Box("Start Over", f << Clear);
			f = dt << Data Filter(
				Conditional,
				Show Controls(0),
				Show Modes(0),
				Show Histograms and Bars(0),
				Add Filter(
					columns(:season, :species, :subject),
					Where(:season == "fall"), // force conditional filter order
					Where(:species = "COYOTE"),
					Where(:subject= "1"),
					Display(:season, N Items(4)),
					Display(:species, N Items(2), "List Display"),
					Display(:subject, N Items(3), "List Display")
				)
			)
		)
	)
);

Window("")["Data Filter",BorderBox(6)] << Sib Prepend(
	V List Box(
		Text Box("Selection of Seasons", << Set Font Size(12), << Set Font Style("Bold Italic")),
		Text Box("Please select which seasons to use for the analysis. Multiple seasons can be selected by holding 'ctrl' down while pressing multiple seasons.", << Set Wrap(400))
	)
);
Window("")["Data Filter",BorderBox(6)] << Sib Append(Spacer Box(Size(0, 20)));


Window("")["Data Filter",BorderBox(7)] << Sib Prepend(
	V List Box(
		Text Box("Selection of Species", << Set Font Size(12), << Set Font Style("Bold Italic")),
		Text Box("Please select which Species to use for the analysis. Multiple Species can be selected by holding 'ctrl' down while pressing multiple Species.", << Set Wrap(400))
	)
);
Window("")["Data Filter",BorderBox(7)] << Sib Append(Spacer Box(Size(0, 20)));

Window("")["Data Filter",BorderBox(8)] << Sib Prepend(
	V List Box(
		Text Box("Selection of Subjects", << Set Font Size(12), << Set Font Style("Bold Italic")),
		Text Box("Please select which Subjects to use for the analysis. Multiple Subjects can be selected by holding 'ctrl' down while pressing multiple Subjects.", << Set Wrap(400))
	)
);

Window("")["Data Filter",BorderBox(3)] << Visibility("Collapse");
Window("")["Data Filter",CheckBoxBox(1)] << Visibility("Collapse");
Window("")["Data Filter",BorderBox(1)] << Visibility("Collapse");
nw[Outline Box(1)] << Set Title("");


// To force the order of conditional filtering
// https://community.jmp.com/t5/JMP-Wish-List/Option-to-make-Conditional-Data-Filter-work-from-top-to-bottom/idi-p/746949
f << (Filter Column(:subject) << Clear Selection);
f << (Filter Column(:species) << Clear Selection);
f << (Filter Column(:season) << Clear Selection);

JMP 在某些地方也使用類似的東西（例如樣本索引），但他們也可能可以獲得一些比我們更好的實作。

回覆：互動式/動態過濾或選擇選單

兩個資料過濾條件之間是否可以使用「或」語句？條件資料過濾器使用“and”語句並動態過濾掉資料。但如果我的條件如下：

Condition_of_column1 和（Condition2_of_column2 或 Condition3_of_column3）

回覆：互動式/動態過濾或選擇選單

使用條件資料過濾器時可能無法實現