774900_zh-TW

liliconcom

一份 ANOM 報告按列分組，因此包含多份摘要報告。如何將每份摘要報告提取到資料表中？

自動化和腳本macOS回覆：有一個按列分組的 ANOM 報告，因此有多個摘要報告。如何將每個摘要報告提取到數據表中？

您提供的映像中的腳本是否存在某些特定問題？看起來它將訪問表格框，然後利用 << Make Into Data Table 來建立表格。

您也可以考慮僅訪問第一個表格框並使用<< Make Combined Data Table代替。

回覆：有一個按列分組的 ANOM 報告，因此有多個摘要報告。如何將每個摘要報告提取到數據表中？

感謝賈莫的回复

我有一個按列分組的單向報告，因此應該顯示多個報告。

運行腳本會如預期顯示按列分組。但是，儲存到資料表的報表僅顯示 1 個單向報表。

可以儲存按組腳本語法嗎？以及它是如何實施的

回覆：有一個按列分組的 ANOM 報告，因此有多個摘要報告。如何將每個摘要報告提取到數據表中？

請使用 JSL 程式碼區塊以文字形式共享您的程式碼，而不是圖像。

仍然不確定出了什麼問題（可能是因為我只看到了部分程式碼）。您是否已驗證 rpt 變數是否具有您認為的內容？您從哪裡獲得表格框的數量？您使用的是哪個 JMP 版本？您是否使用 LLM 來協助您完成 JSL？

但這是我認為你正在嘗試做的兩個例子

Names Default To Here(1); 

dt = Open("$SAMPLE_DATA/Big Class.jmp");
Column(dt, "age") << Set Data Type("Character");

ow = dt << Oneway(
	Y(:height),
	X(:age),
	ANOM(1, Show Summary Report(1), Point Options("Show Needles")),
	By(:sex)
);

dt_res = Report(ow[1])[Outline Box("Analysis of Means Summary"), Table Box(1)] << Make Combined Data Table;


// Or by looping
dt_res2 = Empty();
For Each({cur_ow}, ow,
	cur_group = Word(-1, Report(cur_ow) << Get Title, "=");
	dt_group = Report(cur_ow)[Outline Box("Analysis of Means Summary"), Table Box(1)] << Make Into Data Table;
	dt_group << New Column("Column", Character, Nominal, Set Each Value(cur_group));
	If(Is Empty(dt_res2),
		dt_res2 = dt_group;
	,
		dt_res2 << Concatenate(
			dt_group,
			"Append to first table"
		);
		Close(dt_group, no save);
	);
);