774900_de-DE

liliconcom

Ein ANOM-Bericht ist nach einer Spalte gruppiert und enthält daher mehrere Zusammenfassungsberichte. Wie extrahiere ich jeden Zusammenfassungsbericht in eine Datentabelle?

Automatisierung und SkriptingmacOSBetreff: Habe einen ANOM-Bericht, der nach einer Spalte gruppiert ist und daher mehrere Zusammenfassungsberichte enthält. Wie extrahiere ich jeden Zusammenfassungsbericht in eine Datentabelle?

Gibt es ein bestimmtes Problem mit dem Skript in dem von Ihnen bereitgestellten Bild? Es sieht so aus, als würde es auf Tabellenfelder zugreifen und dann << In Datentabelle umwandeln verwenden, um Tabellen zu erstellen.

Sie können auch nur auf das erste Tabellenfeld zugreifen und stattdessen << Kombinierte Datentabelle erstellen verwenden.

Betreff: Habe einen ANOM-Bericht, der nach einer Spalte gruppiert ist und daher mehrere Zusammenfassungsberichte enthält. Wie extrahiere ich jeden Zusammenfassungsbericht in eine Datentabelle?

danke für die Antwort, Jarmo

Ich habe einen Einwegbericht, der nach einer Spalte gruppiert ist und daher mehrere Berichte anzeigen sollte.

Beim Ausführen des Skripts wird die Gruppierung nach Spalte wie vorgesehen angezeigt. Der in der Datentabelle gespeicherte Bericht zeigt jedoch nur einen Einwegbericht.

Könnte die gruppenweise Speicherung der Skriptsyntax hierfür funktionieren? Und wie wird sie implementiert?

Betreff: Habe einen ANOM-Bericht, der nach einer Spalte gruppiert ist und daher mehrere Zusammenfassungsberichte enthält. Wie extrahiere ich jeden Zusammenfassungsbericht in eine Datentabelle?

Bitte teilen Sie Ihren Code als Text mithilfe eines JSL-Codeblocks und nicht als Bilder.

Ich bin mir immer noch nicht sicher, was schief läuft (vielleicht liegt es daran, dass ich nur Teile des Codes sehe). Haben Sie überprüft, ob die Variable rpt das hat, was Sie denken? Woher bekommen Sie die Anzahl der Tabellenfelder? Welche JMP-Version verwenden Sie? Verwenden Sie LLM zur Unterstützung Ihres JSL?

Aber hier sind zwei Beispiele dafür, was Sie meiner Meinung nach versuchen

Names Default To Here(1); 

dt = Open("$SAMPLE_DATA/Big Class.jmp");
Column(dt, "age") << Set Data Type("Character");

ow = dt << Oneway(
	Y(:height),
	X(:age),
	ANOM(1, Show Summary Report(1), Point Options("Show Needles")),
	By(:sex)
);

dt_res = Report(ow[1])[Outline Box("Analysis of Means Summary"), Table Box(1)] << Make Combined Data Table;


// Or by looping
dt_res2 = Empty();
For Each({cur_ow}, ow,
	cur_group = Word(-1, Report(cur_ow) << Get Title, "=");
	dt_group = Report(cur_ow)[Outline Box("Analysis of Means Summary"), Table Box(1)] << Make Into Data Table;
	dt_group << New Column("Column", Character, Nominal, Set Each Value(cur_group));
	If(Is Empty(dt_res2),
		dt_res2 = dt_group;
	,
		dt_res2 << Concatenate(
			dt_group,
			"Append to first table"
		);
		Close(dt_group, no save);
	);
);